;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Oleg Pykhalov <go.wigust@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services sound)
  #:use-module (gnu services base)
  #:use-module (gnu services configuration)
  #:use-module (gnu services shepherd)
  #:use-module (gnu services)
  #:use-module (gnu system shadow)
  #:use-module (guix gexp)
  #:use-module (guix packages)
  #:use-module (guix records)
  #:use-module (guix store)
  #:use-module (gnu packages linux)
  #:use-module (gnu packages pulseaudio)
  #:use-module (ice-9 match)
  #:export (alsa-configuration
            alsa-service-type
            pulseaudio-configuration
            pulseaudio-service-type))

;;; Commentary:
;;;
;;; Sound services.
;;;
;;; Code:


;;;
;;; ALSA
;;;

(define-record-type* <alsa-configuration>
  alsa-configuration make-alsa-configuration alsa-configuration?
  (alsa-plugins alsa-configuration-alsa-plugins ;<package>
                (default alsa-plugins))
  (pulseaudio?   alsa-configuration-pulseaudio? ;boolean
                 (default #t))
  (extra-options alsa-configuration-extra-options ;string
                 (default "")))

(define alsa-config-file
  ;; Return the ALSA configuration file.
  (match-lambda
    (($ <alsa-configuration> alsa-plugins pulseaudio? extra-options)
     (apply mixed-text-file "asound.conf"
            `("# Generated by 'alsa-service'.\n\n"
              ,@(if pulseaudio?
                    `("# Use PulseAudio by default
pcm_type.pulse {
  lib \"" ,#~(string-append #$alsa-plugins:pulseaudio
                            "/lib/alsa-lib/libasound_module_pcm_pulse.so") "\"
}

ctl_type.pulse {
  lib \"" ,#~(string-append #$alsa-plugins:pulseaudio
                            "/lib/alsa-lib/libasound_module_ctl_pulse.so") "\"
}

pcm.!default {
  type pulse
  fallback \"sysdefault\"
  hint {
    show on
    description \"Default ALSA Output (currently PulseAudio Sound Server)\"
  }
}

ctl.!default {
  type pulse
  fallback \"sysdefault\"
}\n\n")
                    '())
              ,extra-options)))))

(define (alsa-etc-service config)
  (list `("asound.conf" ,(alsa-config-file config))))

(define alsa-service-type
  (service-type
   (name 'alsa)
   (extensions
    (list (service-extension etc-service-type alsa-etc-service)))
   (default-value (alsa-configuration))
   (description "Configure low-level Linux sound support, ALSA.")))


;;;
;;; PulseAudio
;;;

(define-record-type* <pulseaudio-configuration>
  pulseaudio-configuration make-pulseaudio-configuration
  pulseaudio-configuration?
  (package pulseaudio-package (default pulseaudio))
  (client-conf pulseaudio-client-conf (default '()))
  (daemon-conf pulseaudio-daemon-conf (default '((flat-volumes no))))
  (default-script pulseaudio-default-script (default #f))
  (system-script pulseaudio-system-script (default #f)))

(define (pulseaudio-conf-entry arg)
  (match arg
    ((key value)
     (format #f "~a = ~a~%" key value))
    ((? string? _)
     (string-append arg "\n"))))

(define pulseaudio-etc-service
  (match-lambda
    (($ <pulseaudio-configuration> package client-conf daemon-conf
                                   default-script system-script)
     (let ((default.pa (if default-script
                           (apply mixed-text-file "default.pa"
                                  default-script)
                           (file-append package "/etc/pulse/default.pa"))))
       `(("pulse"
          ,(file-union
            "pulse"
            `(("client.conf"
               ,(apply mixed-text-file "client.conf"
                       (map pulseaudio-conf-entry client-conf)))
              ("daemon.conf"
               ,(apply mixed-text-file "daemon.conf"
                       "default-script-file = " default.pa "\n"
                       (map pulseaudio-conf-entry daemon-conf)))
              ("default.pa" ,default.pa)
              ("system.pa"
               ,(if default-script
                    (apply mixed-text-file "system.pa"
                           system-script)
                    (file-append package "/etc/pulse/system.pa")))))))))))

(define pulseaudio-service-type
  (service-type
   (name 'pulseaudio)
   (extensions
    (list (service-extension etc-service-type pulseaudio-etc-service)))
   (default-value (pulseaudio-configuration))
   (description "Configure PulseAudio.")))

;;; sound.scm ends here