bug#23409: unable to load free firmware

[Leo Famulari <leo@famulari.name>]

On Sat, Apr 30, 2016 at 04:06:58PM -0500, Quilro Ordonez wrote:
> I am trying to lo use Broadcom wireless device on GuixSD. It is confirmed to
> work with free drivers and free firmware. It works correctly in Trisquel
> too.

I believe that these package definitions for b43-tools and
openfwwf-firmware, copied from http://termbin.com/i02e, are what are
being used:

(define-public b43-tools
  (let ((commit "8dce53297966b31b6c70a7a03c2433978dd9f288"))
    (package
      (name "b43-tools")
      (version (string-append "20160406." (string-take commit 8)))
      (source
       (origin
         (method git-fetch)
         (uri (git-reference
               (url "http://git.bues.ch/git/b43-tools.git")
               (commit commit)))
         (sha256
          (base32
           "08k7sdr9jagm43r2zv4h03j86klhkblpk73p12444a3vzg1gy1lv"))))
      (build-system gnu-build-system)
      (native-inputs
       `(("flex" ,flex)
         ("bison" ,bison)))
      (arguments
       `(#:modules ((srfi srfi-1)
                    (guix build gnu-build-system)
                    (guix build utils))
         #:tests? #f                    ;no tests
         #:phases (let ((subdirs '("assembler" "disassembler"))) ;TODO: fwcutter
                    (modify-phases %standard-phases
                      (delete 'configure)
                      (add-before 'build 'patch-/bin/true
                        (lambda _
                          (substitute* (find-files "." "Makefile")
                            (("/bin/true") ":"))
                          #t))
                      (replace 'build
                        (lambda _
                          (every (lambda (dir)
                                   (zero?
                                    (system* "make" "-C" dir "CC=gcc")))
                                 subdirs)))
                      (replace 'install
                        (lambda* (#:key outputs #:allow-other-keys)
                          (let ((out (assoc-ref outputs "out")))
                            (mkdir-p (string-append out "/bin"))
                            (every (lambda (dir)
                                     (zero?
                                      (system* "make" "-C" dir
                                               (string-append "PREFIX=" out)
                                               "install")))
                                   subdirs))))))))
      (home-page "")
      (synopsis "")
      (description "")
      (license gpl2))))

(define-public openfwwf-firmware
  (package
    (name "openfwwf-firmware")
    (version "5.2")
    (source
     (origin
       (method url-fetch)
       (uri (string-append "http://netweb.ing.unibs.it/~openfwwf/firmware/"
                           "openfwwf-" version ".tar.gz"))
       (sha256
        (base32
         ;; /gnu/store/ag7rf0kmb1wrnhwjfi3fgr1jcv1vg021-openfwwf-5.2.tar.gz
         "1p60gdi7w88s7qw82d3g9v7mk887mhvidf4l5q5hh09j10h37q4x"))))
    (build-system gnu-build-system)
    (native-inputs
     `(("b43-tools" ,b43-tools)))
    (arguments
     `(#:make-flags (list (string-append "PREFIX=" (assoc-ref %outputs 
"out") "/b43-open"))
       #:tests? #f                      ;no tests
       #:phases (modify-phases %standard-phases
                  (delete 'configure))))
    (home-page "http://netweb.ing.unibs.it/~openfwwf/")
    (synopsis "")
    (description "")
    (license gpl2)))