* Texlive
@ 2013-02-03 16:56 Andreas Enge
2013-02-03 18:30 ` Texlive Ludovic Courtès
0 siblings, 1 reply; 9+ messages in thread
From: Andreas Enge @ 2013-02-03 16:56 UTC (permalink / raw)
To: bug-guix
[-- Attachment #1.1: Type: text/plain, Size: 1301 bytes --]
Hello,
the idea of having two packages, one containing the data and invisible to
the user, and one containing the binaries and depending on the data did not
work: The binaries need to create an index of the data that is stored in
the data directory, but a package has no write rights in another one, which
is coherent with the functional approach of guix.
So I ended up creating one package with two outputs, "out" and "share"; the
user just installs the main package and has no reason to touch the "share"
part (which would not do any harm, either: installing it would create
100000 unused symlinks in the user profile...). Just in case you wonder,
the "out" part contains the man and info pages in a subdirectory named
"share", while the "share" part contains three subdirectories not named
"share". The file is attached, and nitpicking is welcome. (Caveat: As said
before, there are 1.5GB to download, and about 3GB to install, plus the
same during unpacking.)
Concerning the license, there is not only one, see
http://www.tug.org/texlive/copying.html .
But everything is FSF and Debian free. How about adding a license "mixed"
or "fsf-free"? Or do you have a good suggestion?
Andreas
PS: So that I can fully drop my Debian packages, now we only need X.org to
enable xdvi ;-)
[-- Attachment #1.2: Type: text/html, Size: 3766 bytes --]
[-- Attachment #2: texlive.scm --]
[-- Type: text/x-scheme, Size: 8848 bytes --]
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu packages texlive)
;; #:use-module (guix licenses)
#:use-module (guix packages)
#:use-module (guix download)
#:use-module (guix build-system gnu)
#:use-module (gnu packages)
#:use-module (gnu packages compression)
#:use-module (gnu packages freetype)
#:use-module (gnu packages ghostscript)
#:use-module (gnu packages icu4c)
#:use-module (gnu packages libpng)
#:use-module (gnu packages pdf)
#:use-module (gnu packages perl)
#:use-module (gnu packages pkg-config)
#:use-module (gnu packages python)
#:use-module (gnu packages zip))
(define texlive-extra-src
(origin
(method url-fetch)
(uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-extra.tar.xz")
(sha256 (base32
"0cb8fnv4x281gy5ka779f00ssdmdpjj4x3pkh9j9vq45hrwg3522"))))
(define texlive-texmf-src
(origin
(method url-fetch)
(uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-texmf.tar.xz")
(sha256 (base32
"1fn1dg9k7pnh8a80j23zfkbrfnqyc4c2w4ss30dpkqj490nxsywq"))))
(define-public texlive
(package
(name "texlive")
(version "2012")
(source (origin
(method url-fetch)
(uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-source.tar.xz")
(sha256 (base32
"10bcrdfsqnc6y3gqcb8ndnjy07i5kz63as39irbq4gmcbmyn2rln"))))
(build-system gnu-build-system)
(inputs `(("texlive-extra-src" ,texlive-extra-src)
("texlive-texmf-src" ,texlive-texmf-src)
("fontconfig" ,fontconfig)
("freetype" ,freetype)
("icu4c" ,icu4c)
("ghostscript" ,ghostscript)
("libpng" ,libpng)
("perl" ,perl)
("poppler" ,poppler)
("pkg-config" ,pkg-config)
;; FIXME: Add interpreters csh, fontforge and ruby,
;; once they are available.
("python" ,python)
("teckit" ,teckit)
("t1lib" ,t1lib)
("zlib" ,zlib)
("zziplib" ,zziplib)))
(outputs '("share" "out"))
(arguments
`(#:out-of-source? #t
#:configure-flags
'("--disable-native-texlive-build"
"--without-x" ; FIXME: Drop as soon as X is available.
"--with-system-freetype2"
;; "--with-system-gd"
;; "--with-system-graphite"
"--with-system-icu"
"--with-system-libgs"
"--with-system-libpng"
"--with-system-poppler"
"--with-system-t1lib"
"--with-system-teckit"
"--with-system-xpdf"
"--with-system-zlib"
"--with-system-zziplib")
#:phases
(alist-replace
'configure
(lambda* (#:key outputs #:allow-other-keys #:rest args)
(let ((configure (assoc-ref %standard-phases 'configure))
(share (assoc-ref outputs "share")))
(substitute* "utils/psutils/Makefile.in"
(("/usr/bin/env perl") (which "perl")))
;; Correct targets for symbolic links of binaries.
(substitute* '("texk/texlive/linked_scripts/Makefile.in"
"texk/texlive/linked_scripts/Makefile.in"
"texk/tetex/Makefile.in"
"texk/tex4htk/Makefile.in"
"utils/psutils/Makefile.in"
"utils/chktex/Makefile.in"
"utils/mtx/Makefile.in"
"utils/pmx/Makefile.in"
"utils/ps2eps/Makefile.in")
(("\\$\\$REL/") (string-append share "/")))
(apply configure args)))
(alist-cons-after 'install 'postinst
(lambda* (#:key inputs outputs #:allow-other-keys #:rest args)
(let ((texlive-extra (assoc-ref inputs "texlive-extra-src"))
(texlive-texmf (assoc-ref inputs "texlive-texmf-src"))
(out (assoc-ref outputs "out"))
(share (assoc-ref outputs "share"))
(unpack (assoc-ref %standard-phases 'unpack))
(patch-source-shebangs
(assoc-ref %standard-phases 'patch-source-shebangs)))
;; Create symbolic links for the latex variants and their
;; man pages.
(let ((bin (string-append out "/bin/"))
(man (string-append out "/share/man/man1/")))
(symlink (string-append bin "pdftex")
(string-append bin "latex"))
(symlink (string-append bin "pdftex")
(string-append bin "pdflatex"))
(symlink (string-append bin "xetex")
(string-append bin "xelatex"))
(symlink (string-append bin "luatex")
(string-append bin "lualatex"))
(symlink (string-append man "luatex.1")
(string-append man "lualatex.1")))
;; Create the output directory for the shared data
;; tlpkg, texmf and texmf-dist.
(mkdir share)
;; Unpack texlive-extra and install tlpkg.
(mkdir "texlive-extra")
(chdir "texlive-extra")
(apply unpack (list #:source texlive-extra))
(apply patch-source-shebangs (list #:source texlive-extra))
(system* "mv" "tlpkg" share)
(chdir "../..")
;; Unpack and install texlive-texmf.
(mkdir "texlive-texmf")
(chdir "texlive-texmf")
(apply unpack (list #:source texlive-texmf))
(apply patch-source-shebangs (list #:source texlive-texmf))
;; Register "share" for kpathsea in texmf.cnf.
(substitute* "texmf/web2c/texmf.cnf"
(("TEXMFROOT = \\$SELFAUTOPARENT")
(string-append "TEXMFROOT = " share)))
(system* "mv" "texmf" share)
(system* "mv" "texmf-dist" share)
(chdir "../..")
;; Delete (most of) texmf and texmf-dist for "out", since they
;; are now in "share" from texlive-texmf; the purpose of this
;; procedure is to avoid installing them in the user profile.
;; But texmf.cnf must be placed in "out", since kpsewhich does
;; not know about "share" until it has found this file.
(system* "rm" "-r" (string-append out "/share/texmf"))
(system* "rm" "-r" (string-append out "/share/texmf-dist"))
(mkdir (string-append out "/share/texmf"))
(mkdir (string-append out "/share/texmf/web2c"))
(copy-file (string-append share "/texmf/web2c/texmf.cnf")
(string-append out "/share/texmf/web2c/texmf.cnf"))))
(alist-cons-after 'patch-shebangs 'texconfig
(lambda* (#:key outputs #:allow-other-keys)
(let ((out (assoc-ref outputs "out")))
;; Configure the texlive system; inspired from
;; http://slackbuilds.org/repository/13.37/office/texlive/
(display (string-append (getcwd) "\n"))
(display (string-append out "\n"))
(setenv "PATH" (string-append (getenv "PATH") ":" out "/bin"))
(display (string-append (getenv "PATH") "\n"))
(system* "updmap-sys" "--nohash" "--syncwithtrees")
(system* "mktexlsr")
(system* "fmtutil-sys" "--all")))
%standard-phases)))))
(synopsis "Tex Live, a package of the TeX typesetting system")
(description
"TeX Live provides a comprehensive TeX document production system.
It includes all the major TeX-related programs, macro packages, and fonts
that are free software, including support for many languages around the
world.")
(license "other")
(home-page "http://www.tug.org/texlive/")))
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-03 16:56 Texlive Andreas Enge
@ 2013-02-03 18:30 ` Ludovic Courtès
2013-02-05 17:04 ` Texlive Andreas Enge
2013-02-05 19:30 ` Texlive Andreas Enge
0 siblings, 2 replies; 9+ messages in thread
From: Ludovic Courtès @ 2013-02-03 18:30 UTC (permalink / raw)
To: Andreas Enge; +Cc: bug-guix
Andreas Enge <andreas@enge.fr> skribis:
> the idea of having two packages, one containing the data and invisible to
> the user, and one containing the binaries and depending on the data did not
> work: The binaries need to create an index of the data that is stored in
> the data directory, but a package has no write rights in another one, which
> is coherent with the functional approach of guix.
OK. So the catalogs are built once for all during the build, right?
> So I ended up creating one package with two outputs, "out" and "share"; the
> user just installs the main package and has no reason to touch the "share"
> part (which would not do any harm, either: installing it would create
> 100000 unused symlinks in the user profile...). Just in case you wonder,
> the "out" part contains the man and info pages in a subdirectory named
> "share", while the "share" part contains three subdirectories not named
> "share".
Perhaps “data” would be a (slightly) more descriptive name?
Looks like your approach works fine, but maybe we could still ask Karl
Berry to see what he thinks?
> The file is attached, and nitpicking is welcome. (Caveat: As said
> before, there are 1.5GB to download, and about 3GB to install, plus
> the same during unpacking.)
I’ll try once I have real network access. :-)
> Concerning the license, there is not only one, see
> http://www.tug.org/texlive/copying.html .
> But everything is FSF and Debian free. How about adding a license "mixed"
> or "fsf-free"? Or do you have a good suggestion?
Yes, or we could just export the ‘license’ constructor from (guix
licenses). That would allow us to make a custom <license> objects when
needed, like here.
> PS: So that I can fully drop my Debian packages, now we only need X.org to
> enable xdvi ;-)
And the good thing is that now that you’ve done TeX Live and netpbm,
you’ll find that Xorg is really piece of cake. :-)
Some nitpicking, since you asked: ;-)
> (define-public texlive
> (package
> (name "texlive")
> (version "2012")
Should be 20120701 no?
> (alist-cons-after 'install 'postinst
> (lambda* (#:key inputs outputs #:allow-other-keys #:rest args)
Could you maybe move 'install to the next line, aligned with the ‘a’ of
‘alist-cons-after’? (Otherwise Emacs/Paredit will mess up with the
indentation since it would do it like that.)
> ;; Create symbolic links for the latex variants and their
> ;; man pages.
> (let ((bin (string-append out "/bin/"))
> (man (string-append out "/share/man/man1/")))
> (symlink (string-append bin "pdftex")
> (string-append bin "latex"))
> (symlink (string-append bin "pdftex")
> (string-append bin "pdflatex"))
> (symlink (string-append bin "xetex")
> (string-append bin "xelatex"))
> (symlink (string-append bin "luatex")
> (string-append bin "lualatex"))
> (symlink (string-append man "luatex.1")
> (string-append man "lualatex.1")))
Rather:
(with-directory-excursion bin
(for-each symlink
'("pdftex" "pdftex" "xetex" "luatex" "luatex.1")
'("latex" "pdflatex" "xelatex" "lualatex" "lualatex.1")))
> (mkdir "texlive-extra")
> (chdir "texlive-extra")
> (apply unpack (list #:source texlive-extra))
> (apply patch-source-shebangs (list #:source texlive-extra))
> (system* "mv" "tlpkg" share)
> (chdir "../..")
When you have paired ‘cd foo’ and ‘cd ..’, you can instead use
‘with-directory-excursion’, as shown above.
> (system* "mv" "texmf" share)
> (system* "mv" "texmf-dist" share)
> (chdir "../..")
Likewise.
> ;; Configure the texlive system; inspired from
> ;; http://slackbuilds.org/repository/13.37/office/texlive/
> (display (string-append (getcwd) "\n"))
> (display (string-append out "\n"))
> (setenv "PATH" (string-append (getenv "PATH") ":" out "/bin"))
> (display (string-append (getenv "PATH") "\n"))
Looks like the ‘display’ calls are debugging output that could be
removed?
If you want to keep them, write it like:
(format #t "PATH set to `~a'~%" (getenv "PATH"))
Other than that, impressive work, Sir!
Ludo’.
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-03 18:30 ` Texlive Ludovic Courtès
@ 2013-02-05 17:04 ` Andreas Enge
2013-02-05 17:11 ` Texlive Andreas Enge
2013-02-05 21:03 ` Texlive Ludovic Courtès
2013-02-05 19:30 ` Texlive Andreas Enge
1 sibling, 2 replies; 9+ messages in thread
From: Andreas Enge @ 2013-02-05 17:04 UTC (permalink / raw)
To: Ludovic Courtès; +Cc: bug-guix
[-- Attachment #1: Type: text/plain, Size: 2794 bytes --]
Am Sonntag, 3. Februar 2013 schrieb Ludovic Courtès:
> OK. So the catalogs are built once for all during the build, right?
Yes, over the full content of the texlive distribution.
> Perhaps “data” would be a (slightly) more descriptive name?
Okay, why not; I used "share" because normally the subdirectories end up in
"share".
> Looks like your approach works fine, but maybe we could still ask Karl
> Berry to see what he thinks?
This would be an opportunity to ask him a few questions, so why not.
> > But everything is FSF and Debian free. How about adding a license
> > "mixed" or "fsf-free"? Or do you have a good suggestion?
> Yes, or we could just export the ‘license’ constructor from (guix
> licenses). That would allow us to make a custom <license> objects when
> needed, like here.
Or we could leave it empty in some way; just call it "free"? It is clear
that we will only package free software; so a license field that can only
state "a collection of free licenses, for details, see the source" conveys
really no information at all. So I do not see what to construct here. My
suggestion:
(define fsf
(license "fsf"
"http://www.gnu.org/licenses/"
"A collection of free licenses according to the FSF, see the
source for details."))
> And the good thing is that now that you’ve done TeX Live and netpbm,
> you’ll find that Xorg is really piece of cake. :-)
After looking at it, my impression is that at least the build process
should be much easier (once the right order of installation determined).
> > (define-public texlive
> >
> > (package
> >
> > (name "texlive")
> > (version "2012")
> Should be 20120701 no?
There is one edition per year, commonly refered to as "TeX Live 20YY"; so
there is no reason to go into more datails.
> (with-directory-excursion bin
> (for-each symlink
> '("pdftex" "pdftex" "xetex" "luatex" "luatex.1")
> '("latex" "pdflatex" "xelatex" "lualatex" "lualatex.1")))
Very elegant, thanks for the suggestion! But actually, this manual symlink
phase has become superfluous by some directoty related configure flags I
just added.
> > (mkdir "texlive-extra")
> > (chdir "texlive-extra")
> > (apply unpack (list #:source texlive-extra))
> > (apply patch-source-shebangs (list #:source
> > texlive-extra)) (system* "mv" "tlpkg" share)
> > (chdir "../..")
>
> When you have paired ‘cd foo’ and ‘cd ..’, you can instead use
> ‘with-directory-excursion’, as shown above.
Okay. Here it is less useful, since "unpack" changes directories, so a
"chdir ".."" will remain in any case.
Andreas
[-- Attachment #2: Type: text/html, Size: 12681 bytes --]
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-05 17:04 ` Texlive Andreas Enge
@ 2013-02-05 17:11 ` Andreas Enge
2013-02-05 21:03 ` Texlive Ludovic Courtès
1 sibling, 0 replies; 9+ messages in thread
From: Andreas Enge @ 2013-02-05 17:11 UTC (permalink / raw)
To: bug-guix
[-- Attachment #1: Type: text/plain, Size: 614 bytes --]
Am Dienstag, 5. Februar 2013 schrieb Andreas Enge:
> Am Sonntag, 3. Februar 2013 schrieb Ludovic Courtès:
> > (with-directory-excursion bin
> > (for-each symlink
> > '("pdftex" "pdftex" "xetex" "luatex" "luatex.1")
> > '("latex" "pdflatex" "xelatex" "lualatex"
> > "lualatex.1")))
> Very elegant, thanks for the suggestion! But actually, this manual
> symlink phase has become superfluous by some directoty related
> configure flags I just added.
Sorry, I was mixing things up; my comment refers to another place, so this
is still useful.
Andreas
[-- Attachment #2: Type: text/html, Size: 3244 bytes --]
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-03 18:30 ` Texlive Ludovic Courtès
2013-02-05 17:04 ` Texlive Andreas Enge
@ 2013-02-05 19:30 ` Andreas Enge
2013-02-05 21:11 ` Texlive Ludovic Courtès
1 sibling, 1 reply; 9+ messages in thread
From: Andreas Enge @ 2013-02-05 19:30 UTC (permalink / raw)
To: Ludovic Courtès; +Cc: bug-guix
[-- Attachment #1.1: Type: text/plain, Size: 107 bytes --]
Hello,
attached what I think could be the final version, once the license question
is decided.
Andreas
[-- Attachment #1.2: Type: text/html, Size: 1478 bytes --]
[-- Attachment #2: texlive.scm --]
[-- Type: text/x-scheme, Size: 7986 bytes --]
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu packages texlive)
#:use-module ((guix licenses)
#:renamer (symbol-prefix-proc 'license:))
#:use-module (guix packages)
#:use-module (guix download)
#:use-module (guix build-system gnu)
#:use-module (gnu packages)
#:use-module (gnu packages compression)
#:use-module (gnu packages freetype)
#:use-module (gnu packages ghostscript)
#:use-module (gnu packages icu4c)
#:use-module (gnu packages libpng)
#:use-module (gnu packages pdf)
#:use-module (gnu packages perl)
#:use-module (gnu packages pkg-config)
#:use-module (gnu packages python)
#:use-module (gnu packages zip))
(define texlive-extra-src
(origin
(method url-fetch)
(uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-extra.tar.xz")
(sha256 (base32
"0cb8fnv4x281gy5ka779f00ssdmdpjj4x3pkh9j9vq45hrwg3522"))))
(define texlive-texmf-src
(origin
(method url-fetch)
(uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-texmf.tar.xz")
(sha256 (base32
"1fn1dg9k7pnh8a80j23zfkbrfnqyc4c2w4ss30dpkqj490nxsywq"))))
(define-public texlive
(package
(name "texlive")
(version "2012")
(source (origin
(method url-fetch)
(uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-source.tar.xz")
(sha256 (base32
"10bcrdfsqnc6y3gqcb8ndnjy07i5kz63as39irbq4gmcbmyn2rln"))))
(build-system gnu-build-system)
(inputs `(("texlive-extra-src" ,texlive-extra-src)
("texlive-texmf-src" ,texlive-texmf-src)
("fontconfig" ,fontconfig)
("freetype" ,freetype)
("icu4c" ,icu4c)
("ghostscript" ,ghostscript)
("libpng" ,libpng)
("perl" ,perl)
("poppler" ,poppler)
("pkg-config" ,pkg-config)
;; FIXME: Add interpreters csh, fontforge and ruby,
;; once they are available.
("python" ,python)
("teckit" ,teckit)
("t1lib" ,t1lib)
("zlib" ,zlib)
("zziplib" ,zziplib)))
(outputs '("out" "data"))
(arguments
`(#:out-of-source? #t
#:configure-flags
`("--disable-native-texlive-build"
;; Although the texmf and texmf-dist data is taken from
;; texlive-texmf, setting datarootdir is still useful:
;; "make install" creates symbolic links to scripts in this place.
,(string-append "--datarootdir=" (assoc-ref %outputs "data"))
,(string-append "--infodir=" (assoc-ref %outputs "out") "/share/info")
,(string-append "--mandir=" (assoc-ref %outputs "out") "/share/man")
"--without-x" ; FIXME: Drop as soon as X is available.
"--with-system-freetype2"
;; "--with-system-gd"
;; "--with-system-graphite"
"--with-system-icu"
"--with-system-libgs"
"--with-system-libpng"
"--with-system-poppler"
"--with-system-t1lib"
"--with-system-teckit"
"--with-system-xpdf"
"--with-system-zlib"
"--with-system-zziplib")
#:phases
(alist-replace
'configure
(lambda* (#:key outputs #:allow-other-keys #:rest args)
(let ((configure (assoc-ref %standard-phases 'configure)))
(substitute* "utils/psutils/Makefile.in"
(("/usr/bin/env perl") (which "perl")))
(apply configure args)))
(alist-cons-after
'install 'postinst
(lambda* (#:key inputs outputs #:allow-other-keys #:rest args)
(let ((texlive-extra (assoc-ref inputs "texlive-extra-src"))
(texlive-texmf (assoc-ref inputs "texlive-texmf-src"))
(out (assoc-ref outputs "out"))
(data (assoc-ref outputs "data"))
(unpack (assoc-ref %standard-phases 'unpack))
(patch-source-shebangs
(assoc-ref %standard-phases 'patch-source-shebangs)))
;; Create symbolic links for the latex variants and their
;; man pages.
(with-directory-excursion (string-append out "/bin/")
(for-each symlink
'("pdftex" "pdftex" "xetex" "luatex")
'("latex" "pdflatex" "xelatex" "lualatex")))
(with-directory-excursion (string-append out "/share/man/man1/")
(symlink "luatex.1" "lualatex.1"))
;; Delete texmf and texmf-dist from "data", since they
;; will be reinstalled from texlive-texmf.
(system* "rm" "-r" (string-append data "/texmf"))
(system* "rm" "-r" (string-append data "/texmf-dist"))
;; Unpack texlive-extra and install tlpkg.
(mkdir "texlive-extra")
(with-directory-excursion "texlive-extra"
(apply unpack (list #:source texlive-extra))
(apply patch-source-shebangs (list #:source texlive-extra))
(system* "mv" "tlpkg" data)
(chdir ".."))
;; Unpack and install texlive-texmf.
(mkdir "texlive-texmf")
(with-directory-excursion "texlive-texmf"
(apply unpack (list #:source texlive-texmf))
(apply patch-source-shebangs (list #:source texlive-texmf))
;; Register "data" for kpathsea in texmf.cnf.
(substitute* "texmf/web2c/texmf.cnf"
(("TEXMFROOT = \\$SELFAUTOPARENT")
(string-append "TEXMFROOT = " data)))
(system* "mv" "texmf" data)
(system* "mv" "texmf-dist" data)
(chdir ".."))
;; texmf.cnf must also be placed in "out", since kpsewhich does
;; not know about "data" until it has found this file.
(mkdir (string-append out "/share/texmf"))
(mkdir (string-append out "/share/texmf/web2c"))
(copy-file (string-append data "/texmf/web2c/texmf.cnf")
(string-append out "/share/texmf/web2c/texmf.cnf"))))
(alist-cons-after 'patch-shebangs 'texconfig
(lambda* (#:key outputs #:allow-other-keys)
(let ((out (assoc-ref outputs "out")))
;; Configure the texlive system; inspired from
;; http://slackbuilds.org/repository/13.37/office/texlive/
(setenv "PATH" (string-append (getenv "PATH") ":" out "/bin"))
(system* "updmap-sys" "--nohash" "--syncwithtrees")
(system* "mktexlsr")
(system* "fmtutil-sys" "--all")))
%standard-phases)))))
(synopsis "Tex Live, a package of the TeX typesetting system")
(description
"TeX Live provides a comprehensive TeX document production system.
It includes all the major TeX-related programs, macro packages, and fonts
that are free software, including support for many languages around the
world.")
(license license:fsf)
(home-page "http://www.tug.org/texlive/")))
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-05 17:04 ` Texlive Andreas Enge
2013-02-05 17:11 ` Texlive Andreas Enge
@ 2013-02-05 21:03 ` Ludovic Courtès
2013-02-05 22:03 ` Texlive Andreas Enge
1 sibling, 1 reply; 9+ messages in thread
From: Ludovic Courtès @ 2013-02-05 21:03 UTC (permalink / raw)
To: Andreas Enge; +Cc: bug-guix
Andreas Enge <andreas@enge.fr> skribis:
> Am Sonntag, 3. Februar 2013 schrieb Ludovic Courtès:
[...]
>> Yes, or we could just export the ‘license’ constructor from (guix
>> licenses). That would allow us to make a custom <license> objects when
>> needed, like here.
>
> Or we could leave it empty in some way; just call it "free"? It is clear
> that we will only package free software; so a license field that can only
> state "a collection of free licenses, for details, see the source" conveys
> really no information at all. So I do not see what to construct here. My
> suggestion:
>
> (define fsf
> (license "fsf"
> "http://www.gnu.org/licenses/"
> "A collection of free licenses according to the FSF, see the
> source for details."))
Well, for licenses that we fail to classify, I think we should at least
provide a URL or file name to look at, along with an indication of
whether it’s copyleft.
Similar to ‘bsd-style’, what about adding:
(define (copyleft url #:optional (comment "")) ...)
(define (fsf-free url #:optional (comment "")) ...)
For TeX Live, we’d use
(fsf-free "http://tug.org/texlive/copying.html")
WDYT?
>> > (define-public texlive
>> >
>> > (package
>> >
>> > (name "texlive")
>> > (version "2012")
>> Should be 20120701 no?
>
> There is one edition per year, commonly refered to as "TeX Live 20YY"; so
> there is no reason to go into more datails.
OK (I was wondering because the tarball name contains additional digits.)
Thanks,
Ludo’.
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-05 19:30 ` Texlive Andreas Enge
@ 2013-02-05 21:11 ` Ludovic Courtès
0 siblings, 0 replies; 9+ messages in thread
From: Ludovic Courtès @ 2013-02-05 21:11 UTC (permalink / raw)
To: Andreas Enge; +Cc: bug-guix
Looks good to me!
Andreas Enge <andreas@enge.fr> skribis:
> (uri "ftp://tug.org/historic/systems/texlive/2012/texlive-20120701-source.tar.xz")
While looking for mirrors at
<http://tug.org/texlive/acquire-netinstall.html>, I noticed that mirrors
usually have a slightly older version–e.g.,
<http://osl.ugr.es/CTAN/systems/texlive/Source/texlive-20120628-source.tar.xz>.
Perhaps we should just stick to tug.org.
Ludo’.
^ permalink raw reply [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-05 21:03 ` Texlive Ludovic Courtès
@ 2013-02-05 22:03 ` Andreas Enge
2013-02-05 22:51 ` Texlive Ludovic Courtès
0 siblings, 1 reply; 9+ messages in thread
From: Andreas Enge @ 2013-02-05 22:03 UTC (permalink / raw)
To: Ludovic Courtès; +Cc: bug-guix
[-- Attachment #1.1: Type: text/plain, Size: 295 bytes --]
Am Dienstag, 5. Februar 2013 schrieb Ludovic Courtès:
> Similar to ‘bsd-style’, what about adding:
> (define (copyleft url #:optional (comment "")) ...)
> (define (fsf-free url #:optional (comment "")) ...)
Not sure if we need two of them. Is the attached patch okay?
Andreas
[-- Attachment #1.2: Type: text/html, Size: 1968 bytes --]
[-- Attachment #2: 0001-licenses-Add-new-meta-license-fsf-free.patch --]
[-- Type: text/x-patch, Size: 1227 bytes --]
From e3603d27c42d15e7c90f5130a83b15d5a11239aa Mon Sep 17 00:00:00 2001
From: Andreas Enge <andreas@enge.fr>
Date: Tue, 5 Feb 2013 23:01:14 +0100
Subject: [PATCH] licenses: Add new meta-license fsf-free.
* guix/licenses.scm (fsf-free): New record with constructor.
---
guix/licenses.scm | 10 +++++++++-
1 file changed, 9 insertions(+), 1 deletion(-)
diff --git a/guix/licenses.scm b/guix/licenses.scm
index c636cc5..1b149b5 100644
--- a/guix/licenses.scm
+++ b/guix/licenses.scm
@@ -39,7 +39,8 @@
qpl
vim
x11
- zlib))
+ zlib
+ fsf-free))
(define-record-type <license>
(license name uri comment)
@@ -234,4 +235,11 @@ which may be a file:// URI pointing the package's tree."
"http://www.gzip.org/zlib/zlib_license.html"
"https://www.gnu.org/licenses/license-list#ZLib"))
+(define* (fsf-free uri #:optional (comment ""))
+ "Return a license that does not fit any of the ones above or a collection
+of licenses, approved as free by the FSF. More details can be found at URI."
+ (license "FSF-free"
+ uri
+ comment))
+
;;; licenses.scm ends here
--
1.7.10.4
^ permalink raw reply related [flat|nested] 9+ messages in thread
* Re: Texlive
2013-02-05 22:03 ` Texlive Andreas Enge
@ 2013-02-05 22:51 ` Ludovic Courtès
0 siblings, 0 replies; 9+ messages in thread
From: Ludovic Courtès @ 2013-02-05 22:51 UTC (permalink / raw)
To: Andreas Enge; +Cc: bug-guix
Andreas Enge <andreas@enge.fr> skribis:
> Am Dienstag, 5. Februar 2013 schrieb Ludovic Courtès:
>> Similar to ‘bsd-style’, what about adding:
>> (define (copyleft url #:optional (comment "")) ...)
>> (define (fsf-free url #:optional (comment "")) ...)
>
> Not sure if we need two of them. Is the attached patch okay?
Yes, please apply.
Ludo’.
^ permalink raw reply [flat|nested] 9+ messages in thread
end of thread, other threads:[~2013-02-05 22:51 UTC | newest]
Thread overview: 9+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-02-03 16:56 Texlive Andreas Enge
2013-02-03 18:30 ` Texlive Ludovic Courtès
2013-02-05 17:04 ` Texlive Andreas Enge
2013-02-05 17:11 ` Texlive Andreas Enge
2013-02-05 21:03 ` Texlive Ludovic Courtès
2013-02-05 22:03 ` Texlive Andreas Enge
2013-02-05 22:51 ` Texlive Ludovic Courtès
2013-02-05 19:30 ` Texlive Andreas Enge
2013-02-05 21:11 ` Texlive Ludovic Courtès
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).