GNU Prolog: configure: error: cannot run /bin/sh ./config.sub

GNU Prolog: configure: error: cannot run /bin/sh ./config.sub

[Nikita Karetnikov]

[-- Attachment #1.1: Type: text/plain, Size: 439 bytes --]

Hi,

The attached recipe fails with the following error:

patch-shebang: ./src/config.sub: changing `/bin/sh' to `/nix/store/4mg8b8vvmava68y64qmm70gqfnhhjzmx-bash-4.2/bin/sh'

[...]

configure: error: cannot run /bin/sh ./config.sub

However, these commands don't raise any errors.

# cd /tmp/nix-build-gprolog-1.4.2.drv-11
# source environment-variables
# cd */src
# ./configure && make && make check

[...]

All tests succeeded

Nikita


[-- Attachment #1.2: gprolog.scm --]
[-- Type: text/plain, Size: 2838 bytes --]

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages gprolog)
  #:use-module (guix licenses)
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix build-system gnu))

(define-public gprolog
  (package
    (name "gprolog")
    (version "1.4.2")
    (source
     (origin
      (method url-fetch)
      (uri (string-append "http://www.gprolog.org/gprolog-"
                          version ".tar.gz"))
      (sha256
       (base32
        "0y25c2gwz41i6g28qyfjklrmanzgk0c8cr4jn2s7s8qgd9dnm1fm"))))
    (build-system gnu-build-system)
    (arguments `(#:phases (alist-replace
                           'configure
                           (lambda _
                             (zero? (system "cd src && ./configure")))
                           %standard-phases)))
    (home-page
     "http://www.gnu.org/software/gprolog/")
    (synopsis
     "GNU Prolog, a free Prolog compiler with constraint solving over
finite domains")
    (description
     "GNU Prolog is a free Prolog compiler with constraint solving over
finite domains developed by Daniel Diaz.

GNU Prolog accepts Prolog+constraint programs and produces native
binaries (like gcc does from a C source).  The obtained executable is
then stand-alone.  The size of this executable can be quite small since
GNU Prolog can avoid to link the code of most unused built-in
predicates.  The performances of GNU Prolog are very
encouraging (comparable to commercial systems).

Beside the native-code compilation, GNU Prolog offers a classical
interactive interpreter (top-level) with a debugger.

The Prolog part conforms to the ISO standard for Prolog with many
extensions very useful in practice (global variables, OS interface,
sockets,...).

GNU Prolog also includes an efficient constraint solver over Finite
Domains (FD).  This opens contraint logic programming to the user
combining the power of constraint programming to the declarativity of
logic programming.")
    (license '(gpl2+ lgpl3+))))

[-- Attachment #2: Type: application/pgp-signature, Size: 835 bytes --]

Re: GNU Prolog: configure: error: cannot run /bin/sh ./config.sub

[Andreas Enge]

[-- Attachment #1: Type: text/plain, Size: 707 bytes --]

Am Mittwoch, 30. Januar 2013 schrieb Nikita Karetnikov:
> The attached recipe fails with the following error:
> 
> patch-shebang: ./src/config.sub: changing `/bin/sh' to
> `/nix/store/4mg8b8vvmava68y64qmm70gqfnhhjzmx-bash-4.2/bin/sh'
> 
> [...]
> 
> configure: error: cannot run /bin/sh ./config.sub

My suspicion is that the patch-shebang in src/config.sub does not solve the 
problem, but that in some Makefile, there is an explicit call "/bin/sh 
./config.sub". Maybe you can do a "grep" on the Makefiles to verify.

If this is the problem, you need to pach them out "manually" in your build 
recipe (maybe from Makefile after, or Makefile.am before configuring), see, 
for instance, icu4c.scm.

Andreas

[-- Attachment #2: Type: text/html, Size: 3398 bytes --]

Re: GNU Prolog: configure: error: cannot run /bin/sh ./config.sub

[Ludovic Courtès]

Nikita Karetnikov <nikita@karetnikov.org> skribis:

> The attached recipe fails with the following error:
>
> patch-shebang: ./src/config.sub: changing `/bin/sh' to `/nix/store/4mg8b8vvmava68y64qmm70gqfnhhjzmx-bash-4.2/bin/sh'
>
> [...]
>
> configure: error: cannot run /bin/sh ./config.sub

It may be that config.{guess,sub} is an old version, and has a
hard-coded /bin/sh.

Can you check whether there’s a /bin/sh needing to be patched in
config.guess?

HTH,
Ludo’.

[PATCH] gnu: Add GNU Prolog. (was: GNU Prolog: configure: error: cannot run /bin/sh ./config.sub)

[Nikita Karetnikov]

[-- Attachment #1.1: Type: text/plain, Size: 347 bytes --]

> My suspicion is that the patch-shebang in src/config.sub does not solve
> the problem, but that in some Makefile, there is an explicit call
> "/bin/sh ./config.sub".  Maybe you can do a "grep" on the Makefiles to
> verify.

Yep, I missed a couple of faulty shells.

This patch works, but I'd like to simplify it a bit.  Is it possible?

Nikita


[-- Attachment #1.2: 0001-gnu-Add-GNU-Prolog.patch --]
[-- Type: text/x-diff, Size: 5324 bytes --]

From 906e8bd6fe66e330e090ee6c2176a2d5bebdd7fd Mon Sep 17 00:00:00 2001
From: Nikita Karetnikov <nikita@karetnikov.org>
Date: Thu, 31 Jan 2013 04:01:32 +0000
Subject: [PATCH] gnu: Add GNU Prolog.

* gnu/packages/gprolog.scm: New file.
* Makefile.am (MODULES): Add it.
---
 Makefile.am              |    1 +
 gnu/packages/gprolog.scm |   94 ++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+), 0 deletions(-)
 create mode 100644 gnu/packages/gprolog.scm

diff --git a/Makefile.am b/Makefile.am
index cbccd28..907e885 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -78,6 +78,7 @@ MODULES =					\
   gnu/packages/gnupg.scm			\
   gnu/packages/gnutls.scm			\
   gnu/packages/gperf.scm			\
+  gnu/packages/gprolog.scm			\
   gnu/packages/groff.scm			\
   gnu/packages/gsasl.scm			\
   gnu/packages/guile.scm			\
diff --git a/gnu/packages/gprolog.scm b/gnu/packages/gprolog.scm
new file mode 100644
index 0000000..5bd5dba
--- /dev/null
+++ b/gnu/packages/gprolog.scm
@@ -0,0 +1,94 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages gprolog)
+  #:use-module (guix licenses)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system gnu))
+
+(define-public gprolog
+  (package
+    (name "gprolog")
+    (version "1.4.2")
+    (source
+     (origin
+      (method url-fetch)
+      (uri (string-append "http://www.gprolog.org/gprolog-"
+                          version ".tar.gz"))
+      (sha256
+       (base32
+        "0y25c2gwz41i6g28qyfjklrmanzgk0c8cr4jn2s7s8qgd9dnm1fm"))))
+    (build-system gnu-build-system)
+    (arguments `(#:phases (alist-cons-before
+                           'configure 'fix-sh
+                           (lambda _
+                             (substitute* "./src/configure"
+                               (("-/bin/sh")
+                                (string-append "-" (which "sh"))))
+                             (substitute* "./src/configure"
+                               (("= /bin/sh")
+                                (string-append "= " (which "sh")))))
+                           (alist-replace
+                            'configure
+                            (lambda* (#:key outputs #:allow-other-keys)
+                              (let ((out (assoc-ref outputs "out")))
+                                (zero? (system
+                                  (string-append "cd src && ./configure "
+                                                 "--prefix=" out)))))
+                            (alist-replace
+                             'build
+                             (lambda _
+                               (zero? (system "cd src && make")))
+                             (alist-replace
+                              'check
+                              (lambda _
+                                (zero? (system "cd src && make check")))
+                             (alist-replace
+                              'install
+                              (lambda _
+                                (zero? (system "cd src && make install")))
+                            %standard-phases)))))))
+    (home-page
+     "http://www.gnu.org/software/gprolog/")
+    (synopsis
+     "GNU Prolog, a free Prolog compiler with constraint solving over
+finite domains")
+    (description
+     "GNU Prolog is a free Prolog compiler with constraint solving over
+finite domains developed by Daniel Diaz.
+
+GNU Prolog accepts Prolog+constraint programs and produces native
+binaries (like gcc does from a C source).  The obtained executable is
+then stand-alone.  The size of this executable can be quite small since
+GNU Prolog can avoid to link the code of most unused built-in
+predicates.  The performances of GNU Prolog are very
+encouraging (comparable to commercial systems).
+
+Beside the native-code compilation, GNU Prolog offers a classical
+interactive interpreter (top-level) with a debugger.
+
+The Prolog part conforms to the ISO standard for Prolog with many
+extensions very useful in practice (e.g., global variables, OS
+interface, sockets).
+
+GNU Prolog also includes an efficient constraint solver over Finite
+Domains (FD).  This opens contraint logic programming to the user
+combining the power of constraint programming to the declarativity of
+logic programming.")
+    (license '(gpl2+ lgpl3+))))
\ No newline at end of file
-- 
1.7.5.4


[-- Attachment #2: Type: application/pgp-signature, Size: 835 bytes --]

Re: [PATCH] gnu: Add GNU Prolog.

[Ludovic Courtès]

Hi,

Nikita Karetnikov <nikita@karetnikov.org> skribis:

> +    (arguments `(#:phases (alist-cons-before
> +                           'configure 'fix-sh
> +                           (lambda _
> +                             (substitute* "./src/configure"
> +                               (("-/bin/sh")
> +                                (string-append "-" (which "sh"))))
> +                             (substitute* "./src/configure"
> +                               (("= /bin/sh")
> +                                (string-append "= " (which "sh")))))

‘substitute*’ can have several clauses, so you can write:

  (substitute* "src/configure"
    (("-/bin/sh") (string-append "-" (which "sh")))
    (("= /bin/sh") (string-append "= " (which "sh"))))

> +                           (alist-replace
> +                            'configure
> +                            (lambda* (#:key outputs #:allow-other-keys)
> +                              (let ((out (assoc-ref outputs "out")))
> +                                (zero? (system
> +                                  (string-append "cd src && ./configure "
> +                                                 "--prefix=" out)))))
> +                            (alist-replace
> +                             'build
> +                             (lambda _
> +                               (zero? (system "cd src && make")))
> +                             (alist-replace
> +                              'check
> +                              (lambda _
> +                                (zero? (system "cd src && make check")))
> +                             (alist-replace
> +                              'install
> +                              (lambda _
> +                                (zero? (system "cd src && make install")))
> +                            %standard-phases)))))))

Instead of repeating “cd src”, you can just add a phase before the
‘configure’ phase that does:

  (chdir "src")

> +    (license '(gpl2+ lgpl3+))))

This should be (list gpl2+ lgpl3+), to refer to the ‘license’ objects.

HTH,
Ludo’.

Re: [PATCH] gnu: Add GNU Prolog. (was: GNU Prolog: configure: error: cannot run /bin/sh ./config.sub)

[Andreas Enge]

[-- Attachment #1: Type: text/plain, Size: 765 bytes --]

Am Donnerstag, 31. Januar 2013 schrieb Nikita Karetnikov:
> This patch works, but I'd like to simplify it a bit.  Is it possible?

There is no need to repeat the phases that do not change in your patch. If 
you have a look at icu4c.scm, there is an example using "alist-replace" for 
the configure phase that changes; moreover, it just patches a file first 
and then calls the normal configure of %standard-phases:

       (alist-replace
        'configure
        (lambda* (#:key #:allow-other-keys #:rest args)
         (let ((configure (assoc-ref %standard-phases 'configure)))
           (substitute* "configure"
             (("`/bin/sh")
             (string-append "`" (which "bash"))))
           (apply configure args)))
       %standard-phases))

Andreas

[-- Attachment #2: Type: text/html, Size: 3597 bytes --]

Re: [PATCH] gnu: Add GNU Prolog.

[Nikita Karetnikov]

[-- Attachment #1.1: Type: text/plain, Size: 22 bytes --]

What about this one?


[-- Attachment #1.2: 0001-gnu-Add-GNU-Prolog.patch --]
[-- Type: text/x-diff, Size: 4145 bytes --]

From 31d58fb07a91fe7a37b55517647b222ec146fcf5 Mon Sep 17 00:00:00 2001
From: Nikita Karetnikov <nikita@karetnikov.org>
Date: Fri, 1 Feb 2013 16:11:29 +0000
Subject: [PATCH] gnu: Add GNU Prolog.

* gnu/packages/gprolog.scm: New file.
* Makefile.am (MODULES): Add it.
---
 Makefile.am              |    1 +
 gnu/packages/gprolog.scm |   72 ++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+), 0 deletions(-)
 create mode 100644 gnu/packages/gprolog.scm

diff --git a/Makefile.am b/Makefile.am
index 439b5ff..0d8105a 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -78,6 +78,7 @@ MODULES =					\
   gnu/packages/gnupg.scm			\
   gnu/packages/gnutls.scm			\
   gnu/packages/gperf.scm			\
+  gnu/packages/gprolog.scm			\
   gnu/packages/groff.scm			\
   gnu/packages/gsasl.scm			\
   gnu/packages/guile.scm			\
diff --git a/gnu/packages/gprolog.scm b/gnu/packages/gprolog.scm
new file mode 100644
index 0000000..ba84d9a
--- /dev/null
+++ b/gnu/packages/gprolog.scm
@@ -0,0 +1,72 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2013 Nikita Karetnikov <nikita@karetnikov.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages gprolog)
+  #:use-module (guix licenses)
+  #:use-module (guix packages)
+  #:use-module (guix download)
+  #:use-module (guix build-system gnu))
+
+(define-public gprolog
+  (package
+    (name "gprolog")
+    (version "1.4.2")
+    (source
+     (origin
+      (method url-fetch)
+      (uri (string-append "http://www.gprolog.org/gprolog-"
+                          version ".tar.gz"))
+      (sha256
+       (base32
+        "0y25c2gwz41i6g28qyfjklrmanzgk0c8cr4jn2s7s8qgd9dnm1fm"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:phases (alist-cons-before
+                 'configure 'change-dir-n-fix-shells
+                 (lambda _
+                   (chdir "src")
+                   (substitute* "configure"
+                     (("-/bin/sh")  (string-append "-"  (which "sh")))
+                     (("= /bin/sh") (string-append "= " (which "sh")))))
+                 %standard-phases)))
+    (home-page "https://www.gnu.org/software/gprolog/")
+    (synopsis
+     "GNU Prolog, a free Prolog compiler with constraint solving over
+finite domains")
+    (description
+     "GNU Prolog is a free Prolog compiler with constraint solving over
+finite domains developed by Daniel Diaz.
+
+GNU Prolog accepts Prolog+constraint programs and produces native
+binaries (like gcc does from a C source).  The obtained executable is
+then stand-alone.  The size of this executable can be quite small since
+GNU Prolog can avoid to link the code of most unused built-in
+predicates.  The performances of GNU Prolog are very
+encouraging (comparable to commercial systems).
+
+Beside the native-code compilation, GNU Prolog offers a classical
+interactive interpreter (top-level) with a debugger.
+
+The Prolog part conforms to the ISO standard for Prolog with many
+extensions very useful in practice (e.g., global variables, OS
+interface, sockets).
+
+GNU Prolog also includes an efficient constraint solver over finite domains.
+This opens contraint logic programming to the user combining the power of
+constraint programming to the declarativity of logic programming.")
+    (license (list gpl2+ lgpl3+))))
\ No newline at end of file
-- 
1.7.5.4


[-- Attachment #2: Type: application/pgp-signature, Size: 835 bytes --]

Re: [PATCH] gnu: Add GNU Prolog.

[Ludovic Courtès]

Nikita Karetnikov <nikita@karetnikov.org> skribis:

> From 31d58fb07a91fe7a37b55517647b222ec146fcf5 Mon Sep 17 00:00:00 2001
> From: Nikita Karetnikov <nikita@karetnikov.org>
> Date: Fri, 1 Feb 2013 16:11:29 +0000
> Subject: [PATCH] gnu: Add GNU Prolog.
>
> * gnu/packages/gprolog.scm: New file.
> * Makefile.am (MODULES): Add it.

Looks good to me, please push.

Ludo’.