configuring guile packages [was: GNU Guile 2.9.8 Released [beta]]

[Matt Wette <matt.wette@gmail.com>]

On 1/3/20 6:53 AM, Matt Wette wrote:
>>  I am running into other issues, however, when there is a
>> guile in my path that appears before anything else, but a guile-2 
>> that appears from another directory.  I am working to add 
>> --with-guile to fix that.  I'm having problems checking against 
>> 2.0.14, for example.
I have been working on my configures.  I have separate guile-2.0.14, 
-2.2.4 and -2.9.8 installs.
To get everything to work I ended up with the following configure.ac and 
nyacc.m4.  Not beautiful
but it's working for 2.0.14, 2.2.X and 2.9.8.

===== snip from configure.ac =====
m4_include([./pkg.m4])
m4_include([./guile.m4])
m4_include([./nyacc.m4])

AC_ARG_WITH(guile, [    --with-guile            path to binary],
             ,with_guile=unspecified)

if test "_$with_guile" != "_unspecified"; then
   GUILE=$with_guile
   GUILE_EFFECTIVE_VERSION=`$GUILE -c "(display (effective-version))"`
   guile_libdir=`$GUILE -c "(display (assq-ref %guile-build-info 'libdir))"`
   PKG_CONFIG_LIBDIR=$guile_libdir/pkgconfig
   PKG_CONFIG=pkg-config
   export PKG_CONFIG_LIBDIR
else
   GUILE_PKG([3.2 3.0 2.9 2.2 2.0])
   GUILE_PROGS
fi

GUILE_SITE_DIR
GUILE_SITE_GO_DIR
GUILE_DATA_DIR

==========================

===== nyacc.m4 =====
dnl GUILE_SITE_GO_DIR
AC_DEFUN([GUILE_SITE_GO_DIR],
  [AC_MSG_CHECKING(for Guile site directory)
   GUILE_SITE_GO=`$GUILE -c '(display (%site-ccache-dir))'`
   AC_MSG_RESULT($GUILE_SITE_GO)
   if test "$GUILE_SITE_GO" = ""; then
      AC_MSG_FAILURE(sitedir not found)
   fi
   AC_SUBST(GUILE_SITE_GO)
  ])

dnl GUILE_DATA_DIR
AC_DEFUN([GUILE_DATA_DIR],
  [AC_MSG_CHECKING(for Guile data directory)
   GUILE_DATA=`$GUILE -c "(display (assq-ref %guile-build-info 'datadir))"`
   AC_MSG_RESULT($GUILE_DATA)
   if test "$GUILE_DATA" = ""; then
      AC_MSG_FAILURE(datadir not found)
   fi
   AC_SUBST(GUILE_DATA)
  ])
===================