* guile-cairo - autotool chain patches - prerelease
@ 2016-08-18 8:50 David Pirotte
0 siblings, 0 replies; only message in thread
From: David Pirotte @ 2016-08-18 8:50 UTC (permalink / raw)
To: guile-user, guile-gnome
[-- Attachment #1.1.1: Type: text/plain, Size: 1096 bytes --]
Hi Guilers,
Attached, a series of admin patches for guile-cairo, now using guile's m4 macros and
other improvements. 'make distcheck' pass here, both using 2.0.12 and 2.1.3.
I also uploaded a pre release, guile-cairo-1.10.0, here:
http://download.savannah.gnu.org/releases/grip/guile-cairo/
guile-cairo-1.10.0.tar.gz
guile-cairo-1.10.0.tar.gz.sig [1]
[ Downloads will redirect to your nearest mirror site.
[ Files on mirrors may be subject to a replication delay of up to 24 hours.
[ In case of problems use
[ http://download-mirror.savannah.gnu.org/releases/
Cheers,
David
[1]
Use a .sig file to verify that the corresponding file (without the .sig suffix) is
intact. First, be sure to download both the .sig file and the corresponding
tarball. Then, run a command like this:
gpg --verify guile-cairo-1.10.0.tar.gz.sig
If that command fails because you don't have the required public key, then run this
command to import it:
gpg --keyserver keys.gnupg.net --recv-keys A3057AD7
and rerun the 'gpg --verify' command.
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.2: 0001-Avoiding-multiple-GUILE-definitions.patch --]
[-- Type: text/x-patch, Size: 1466 bytes --]
From a0b4eb2db65c24ec7c7b9b1b4db0e934b6f3baa9 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 22:35:55 -0300
Subject: [PATCH 01/11] Avoiding multiple GUILE definitions
* am/guile.mk: New file, within which we move the definition of GUILE
previously in both Makefile.am and doc/Makefile.am.
---
am/guile.mk | 22 ++++++++++++++++++++++
1 file changed, 22 insertions(+)
create mode 100644 am/guile.mk
diff --git a/am/guile.mk b/am/guile.mk
new file mode 100644
index 0000000..e49e86f
--- /dev/null
+++ b/am/guile.mk
@@ -0,0 +1,22 @@
+
+####
+#### Copyright (C) 2016 David Pirotte
+
+#### This file is part of GNU Guile-Cairo
+
+#### This program is free software; you can redistribute it and/or
+#### modify it under the terms of the GNU Lesser General Public
+#### License as published by the Free Software Foundation; either
+#### version 3 of the License, or (at your option) any later version.
+
+#### This program is distributed in the hope that it will be useful,
+#### but WITHOUT ANY WARRANTY; without even the implied warranty of
+#### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+#### Lesser General Public License for more details.
+
+#### You should have received a copy of the GNU Lesser General Public
+#### License along with this program; if not, see
+#### <http://www.gnu.org/licenses/>.
+####
+
+GUILE = $(top_builddir)/env guile
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.3: 0002-Prepare-to-use-GUile-s-autoconf-support-macros.patch --]
[-- Type: text/x-patch, Size: 17310 bytes --]
From ece685fa5731827ee01925d839387d534c9ab3cb Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 22:44:36 -0300
Subject: [PATCH 02/11] Prepare to use GUile's autoconf support macros
* m4/guile.m4: New file. Note that we don't want to rely on the same
file installed by guile, because, if the user grab guile-cairo before
to install guile itself, or guile has just not been installed or
removed, despite the user sware to god it's there :), then guile-cairo
configure script would fail with an error, instead of nicely reporting
that Guile is missing.
---
m4/guile.m4 | 413 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 413 insertions(+)
create mode 100644 m4/guile.m4
diff --git a/m4/guile.m4 b/m4/guile.m4
new file mode 100644
index 0000000..d173930
--- /dev/null
+++ b/m4/guile.m4
@@ -0,0 +1,413 @@
+## Autoconf macros for working with Guile.
+##
+## Copyright (C) 1998,2001, 2006, 2010, 2012, 2013 - 2015 Free
+## Software Foundation, Inc.
+##
+## This library is free software; you can redistribute it and/or
+## modify it under the terms of the GNU Lesser General Public License
+## as published by the Free Software Foundation; either version 3 of
+## the License, or (at your option) any later version.
+##
+## This library is distributed in the hope that it will be useful,
+## but WITHOUT ANY WARRANTY; without even the implied warranty of
+## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+## Lesser General Public License for more details.
+##
+## You should have received a copy of the GNU Lesser General Public
+## License along with this library; if not, write to the Free Software
+## Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
+## 02110-1301 USA
+
+# serial 10
+
+## Index
+## -----
+##
+## GUILE_PKG -- find Guile development files
+## GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
+## GUILE_FLAGS -- set flags for compiling and linking with Guile
+## GUILE_SITE_DIR -- find path to Guile "site" directory
+## GUILE_GLOBAL_SITE_DIR -- find path to Guile "global site" directory
+## GUILE_SITE_CCACHE_DIR -- find path to Guile "site-ccache" directory
+## GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
+## GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
+## GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
+## GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
+## GUILE_MODULE_EXPORTS -- check if a module exports a variable
+## GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
+
+## Code
+## ----
+
+## NOTE: Comments preceding an AC_DEFUN (starting from "Usage:") are massaged
+## into doc/ref/autoconf-macros.texi (see Makefile.am in that directory).
+
+# GUILE_PKG -- find Guile development files
+#
+# Usage: GUILE_PKG([VERSIONS])
+#
+# This macro runs the @code{pkg-config} tool to find development files
+# for an available version of Guile.
+#
+# By default, this macro will search for the latest stable version of
+# Guile (e.g. 2.0), falling back to the previous stable version
+# (e.g. 1.8) if it is available. If no guile-@var{VERSION}.pc file is
+# found, an error is signalled. The found version is stored in
+# @var{GUILE_EFFECTIVE_VERSION}.
+#
+# If @code{GUILE_PROGS} was already invoked, this macro ensures that the
+# development files have the same effective version as the Guile
+# program.
+#
+# @var{GUILE_EFFECTIVE_VERSION} is marked for substitution, as by
+# @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_PKG],
+ [PKG_PROG_PKG_CONFIG
+ _guile_versions_to_search="m4_default([$1], [2.2 2.0])"
+ if test -n "$GUILE_EFFECTIVE_VERSION"; then
+ _guile_tmp=""
+ for v in $_guile_versions_to_search; do
+ if test "$v" = "$GUILE_EFFECTIVE_VERSION"; then
+ _guile_tmp=$v
+ fi
+ done
+ if test -z "$_guile_tmp"; then
+ AC_MSG_FAILURE([searching for guile development files for versions $_guile_versions_to_search, but previously found $GUILE version $GUILE_EFFECTIVE_VERSION])
+ fi
+ _guile_versions_to_search=$GUILE_EFFECTIVE_VERSION
+ fi
+ GUILE_EFFECTIVE_VERSION=""
+ _guile_errors=""
+ for v in $_guile_versions_to_search; do
+ if test -z "$GUILE_EFFECTIVE_VERSION"; then
+ AC_MSG_NOTICE([checking for guile $v])
+ PKG_CHECK_EXISTS([guile-$v], [GUILE_EFFECTIVE_VERSION=$v], [])
+ fi
+ done
+
+ if test -z "$GUILE_EFFECTIVE_VERSION"; then
+ AC_MSG_ERROR([
+No Guile development packages were found.
+
+Please verify that you have Guile installed. If you installed Guile
+from a binary distribution, please verify that you have also installed
+the development packages. If you installed it yourself, you might need
+to adjust your PKG_CONFIG_PATH; see the pkg-config man page for more.
+])
+ fi
+ AC_MSG_NOTICE([found guile $GUILE_EFFECTIVE_VERSION])
+ AC_SUBST([GUILE_EFFECTIVE_VERSION])
+ ])
+
+# GUILE_FLAGS -- set flags for compiling and linking with Guile
+#
+# Usage: GUILE_FLAGS
+#
+# This macro runs the @code{pkg-config} tool to find out how to compile
+# and link programs against Guile. It sets four variables:
+# @var{GUILE_CFLAGS}, @var{GUILE_LDFLAGS}, @var{GUILE_LIBS}, and
+# @var{GUILE_LTLIBS}.
+#
+# @var{GUILE_CFLAGS}: flags to pass to a C or C++ compiler to build code that
+# uses Guile header files. This is almost always just one or more @code{-I}
+# flags.
+#
+# @var{GUILE_LDFLAGS}: flags to pass to the compiler to link a program
+# against Guile. This includes @code{-lguile-@var{VERSION}} for the
+# Guile library itself, and may also include one or more @code{-L} flag
+# to tell the compiler where to find the libraries. But it does not
+# include flags that influence the program's runtime search path for
+# libraries, and will therefore lead to a program that fails to start,
+# unless all necessary libraries are installed in a standard location
+# such as @file{/usr/lib}.
+#
+# @var{GUILE_LIBS} and @var{GUILE_LTLIBS}: flags to pass to the compiler or to
+# libtool, respectively, to link a program against Guile. It includes flags
+# that augment the program's runtime search path for libraries, so that shared
+# libraries will be found at the location where they were during linking, even
+# in non-standard locations. @var{GUILE_LIBS} is to be used when linking the
+# program directly with the compiler, whereas @var{GUILE_LTLIBS} is to be used
+# when linking the program is done through libtool.
+#
+# The variables are marked for substitution, as by @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_FLAGS],
+ [AC_REQUIRE([GUILE_PKG])
+ PKG_CHECK_MODULES(GUILE, [guile-$GUILE_EFFECTIVE_VERSION])
+
+ dnl GUILE_CFLAGS and GUILE_LIBS are already defined and AC_SUBST'd by
+ dnl PKG_CHECK_MODULES. But GUILE_LIBS to pkg-config is GUILE_LDFLAGS
+ dnl to us.
+
+ GUILE_LDFLAGS=$GUILE_LIBS
+
+ dnl Determine the platform dependent parameters needed to use rpath.
+ dnl AC_LIB_LINKFLAGS_FROM_LIBS is defined in gnulib/m4/lib-link.m4 and needs
+ dnl the file gnulib/build-aux/config.rpath.
+ AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LIBS], [$GUILE_LDFLAGS], [])
+ GUILE_LIBS="$GUILE_LDFLAGS $GUILE_LIBS"
+ AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LTLIBS], [$GUILE_LDFLAGS], [yes])
+ GUILE_LTLIBS="$GUILE_LDFLAGS $GUILE_LTLIBS"
+
+ AC_SUBST([GUILE_EFFECTIVE_VERSION])
+ AC_SUBST([GUILE_CFLAGS])
+ AC_SUBST([GUILE_LDFLAGS])
+ AC_SUBST([GUILE_LIBS])
+ AC_SUBST([GUILE_LTLIBS])
+ ])
+
+# GUILE_PREFIX_DIR -- find path to Guile "prefix" directory
+#
+# Usage: GUILE_PREFIX_DIR
+#
+# This looks for Guile's "prefix" directory and sets var
+# @var{GUILE_PREFIX} to the path. Note that the var name is different
+# from the macro name.
+#
+# The variable is marked for substitution, as by @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_PREFIX_DIR],
+ [AC_REQUIRE([GUILE_PKG])
+ AC_MSG_CHECKING(for Guile prefix directory)
+ GUILE_PREFIX=`$PKG_CONFIG --print-errors --variable=prefix guile-$GUILE_EFFECTIVE_VERSION`
+ AC_MSG_RESULT($GUILE_PREFIX)
+ if test "$GUILE_PREFIX" = ""; then
+ AC_MSG_FAILURE(prefix not found)
+ fi
+ AC_SUBST(GUILE_PREFIX)
+ ])
+
+# GUILE_SITE_DIR -- find path to Guile "site" directory
+#
+# Usage: GUILE_SITE_DIR
+#
+# This looks for Guile's "site" directory, usually something like
+# PREFIX/share/guile/site/2.x, and sets var @var{GUILE_SITE} to the
+# path. Note that the var name is different from the macro name.
+#
+# The variable is marked for substitution, as by @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_SITE_DIR],
+ [AC_REQUIRE([GUILE_PKG])
+ AC_MSG_CHECKING(for Guile site directory)
+ GUILE_SITE=`$PKG_CONFIG --print-errors --variable=sitedir guile-$GUILE_EFFECTIVE_VERSION`
+ AC_MSG_RESULT($GUILE_SITE)
+ if test "$GUILE_SITE" = ""; then
+ AC_MSG_FAILURE(sitedir not found)
+ fi
+ AC_SUBST(GUILE_SITE)
+ ])
+
+# GUILE_GLOBAL_SITE_DIR -- find path to Guile global site directory
+#
+# Usage: GUILE_GLOBAL_SITE_DIR
+#
+# This looks for Guile's global site directory, usually something like
+# PREFIX/share/guile/site, and sets var @var{GUILE_GLOBAL_SITE} to the
+# path. Note that the var name is different from the macro name.
+#
+# The variable is marked for substitution, as by @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_GLOBAL_SITE_DIR],
+ [AC_REQUIRE([GUILE_PROGS])
+ AC_MSG_CHECKING(for Guile global site directory)
+ GUILE_GLOBAL_SITE=`$GUILE -c "(display (%global-site-dir))"`
+ AC_MSG_RESULT($GUILE_GLOBAL_SITE)
+ if test "$GUILE_GLOBAL_SITE" = ""; then
+ AC_MSG_FAILURE(global site dir not found)
+ fi
+ AC_SUBST(GUILE_GLOBAL_SITE)
+ ])
+
+# GUILE_SITE_CCACHE_DIR -- find path to Guile "site-ccache" directory
+#
+# Usage: GUILE_SITE_CCACHE_DIR
+#
+# This looks for Guile's "site-ccache" directory, usually something
+# like PREFIX/lib/guile/GUILE_EFFECTIVE_VERSION/site-ccache, and sets
+# var @var{GUILE_SITE_CCACHE} to the path. Note that the var name is
+# different from the macro name.
+#
+# The variable is marked for substitution, as by @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_SITE_CCACHE_DIR],
+ [AC_REQUIRE([GUILE_PKG])
+ AC_MSG_CHECKING(for Guile site-ccache directory)
+ _guile_lib=`$PKG_CONFIG --print-errors --variable=libdir guile-$GUILE_EFFECTIVE_VERSION`
+ AC_MSG_RESULT($_guile_lib)
+ if test "$_guile_lib" = ""; then
+ AC_MSG_FAILURE(libdir not found)
+ fi
+ GUILE_SITE_CCACHE=$_guile_lib/guile/$GUILE_EFFECTIVE_VERSION/site-ccache
+ AC_SUBST(GUILE_SITE_CCACHE)
+ ])
+
+# GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
+#
+# Usage: GUILE_PROGS([VERSION])
+#
+# This macro looks for programs @code{guile} and @code{guild}, setting
+# variables @var{GUILE} and @var{GUILD} to their paths, respectively.
+# If @code{guile} is not found, signal an error.
+#
+# By default, this macro will search for the latest stable version of
+# Guile (e.g. 2.0). x.y or x.y.z versions can be specified. If an older
+# version is found, the macro will signal an error.
+#
+# The effective version of the found @code{guile} is set to
+# @var{GUILE_EFFECTIVE_VERSION}. This macro ensures that the effective
+# version is compatible with the result of a previous invocation of
+# @code{GUILE_FLAGS}, if any.
+#
+# As a legacy interface, it also looks for @code{guile-config} and
+# @code{guile-tools}, setting @var{GUILE_CONFIG} and @var{GUILE_TOOLS}.
+#
+# The variables are marked for substitution, as by @code{AC_SUBST}.
+#
+AC_DEFUN([GUILE_PROGS],
+ [AC_PATH_PROG(GUILE,guile)
+ _guile_required_version="m4_default([$1], [$GUILE_EFFECTIVE_VERSION])"
+ if test -z "$_guile_required_version"; then
+ _guile_required_version=2.0
+ fi
+ if test "$GUILE" = "" ; then
+ AC_MSG_ERROR([guile required but not found])
+ fi
+ AC_SUBST(GUILE)
+
+ _guile_effective_version=`$GUILE -c "(display (effective-version))"`
+ if test -z "$GUILE_EFFECTIVE_VERSION"; then
+ GUILE_EFFECTIVE_VERSION=$_guile_effective_version
+ elif test "$GUILE_EFFECTIVE_VERSION" != "$_guile_effective_version"; then
+ AC_MSG_ERROR([found development files for Guile $GUILE_EFFECTIVE_VERSION, but $GUILE has effective version $_guile_effective_version])
+ fi
+
+ _guile_major_version=`$GUILE -c "(display (major-version))"`
+ _guile_minor_version=`$GUILE -c "(display (minor-version))"`
+ _guile_micro_version=`$GUILE -c "(display (micro-version))"`
+ _guile_prog_version="$_guile_major_version.$_guile_minor_version.$_guile_micro_version"
+
+ AC_MSG_CHECKING([for Guile version >= $_guile_required_version])
+ _major_version=`echo $_guile_required_version | cut -d . -f 1`
+ _minor_version=`echo $_guile_required_version | cut -d . -f 2`
+ _micro_version=`echo $_guile_required_version | cut -d . -f 3`
+ if test "$_guile_major_version" -gt "$_major_version"; then
+ true
+ elif test "$_guile_major_version" -eq "$_major_version"; then
+ if test "$_guile_minor_version" -gt "$_minor_version"; then
+ true
+ elif test "$_guile_minor_version" -eq "$_minor_version"; then
+ if test -n "$_micro_version"; then
+ if test "$_guile_micro_version" -lt "$_micro_version"; then
+ AC_MSG_ERROR([Guile $_guile_required_version required, but $_guile_prog_version found])
+ fi
+ fi
+ elif test "$GUILE_EFFECTIVE_VERSION" = "$_major_version.$_minor_version" -a -z "$_micro_version"; then
+ # Allow prereleases that have the right effective version.
+ true
+ else
+ as_fn_error $? "Guile $_guile_required_version required, but $_guile_prog_version found" "$LINENO" 5
+ fi
+ else
+ AC_MSG_ERROR([Guile $_guile_required_version required, but $_guile_prog_version found])
+ fi
+ AC_MSG_RESULT([$_guile_prog_version])
+
+ AC_PATH_PROG(GUILD,guild)
+ AC_SUBST(GUILD)
+
+ AC_PATH_PROG(GUILE_CONFIG,guile-config)
+ AC_SUBST(GUILE_CONFIG)
+ if test -n "$GUILD"; then
+ GUILE_TOOLS=$GUILD
+ else
+ AC_PATH_PROG(GUILE_TOOLS,guile-tools)
+ fi
+ AC_SUBST(GUILE_TOOLS)
+ ])
+
+# GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
+#
+# Usage: GUILE_CHECK_RETVAL(var,check)
+#
+# @var{var} is a shell variable name to be set to the return value.
+# @var{check} is a Guile Scheme expression, evaluated with "$GUILE -c", and
+# returning either 0 or non-#f to indicate the check passed.
+# Non-0 number or #f indicates failure.
+# Avoid using the character "#" since that confuses autoconf.
+#
+AC_DEFUN([GUILE_CHECK],
+ [AC_REQUIRE([GUILE_PROGS])
+ $GUILE -c "$2" > /dev/null 2>&1
+ $1=$?
+ ])
+
+# GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
+#
+# Usage: GUILE_MODULE_CHECK(var,module,featuretest,description)
+#
+# @var{var} is a shell variable name to be set to "yes" or "no".
+# @var{module} is a list of symbols, like: (ice-9 common-list).
+# @var{featuretest} is an expression acceptable to GUILE_CHECK, q.v.
+# @var{description} is a present-tense verb phrase (passed to AC_MSG_CHECKING).
+#
+AC_DEFUN([GUILE_MODULE_CHECK],
+ [AC_MSG_CHECKING([if $2 $4])
+ GUILE_CHECK($1,(use-modules $2) (exit ((lambda () $3))))
+ if test "$$1" = "0" ; then $1=yes ; else $1=no ; fi
+ AC_MSG_RESULT($$1)
+ ])
+
+# GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
+#
+# Usage: GUILE_MODULE_AVAILABLE(var,module)
+#
+# @var{var} is a shell variable name to be set to "yes" or "no".
+# @var{module} is a list of symbols, like: (ice-9 common-list).
+#
+AC_DEFUN([GUILE_MODULE_AVAILABLE],
+ [GUILE_MODULE_CHECK($1,$2,0,is available)
+ ])
+
+# GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
+#
+# Usage: GUILE_MODULE_REQUIRED(symlist)
+#
+# @var{symlist} is a list of symbols, WITHOUT surrounding parens,
+# like: ice-9 common-list.
+#
+AC_DEFUN([GUILE_MODULE_REQUIRED],
+ [GUILE_MODULE_AVAILABLE(ac_guile_module_required, ($1))
+ if test "$ac_guile_module_required" = "no" ; then
+ AC_MSG_ERROR([required guile module not found: ($1)])
+ fi
+ ])
+
+# GUILE_MODULE_EXPORTS -- check if a module exports a variable
+#
+# Usage: GUILE_MODULE_EXPORTS(var,module,modvar)
+#
+# @var{var} is a shell variable to be set to "yes" or "no".
+# @var{module} is a list of symbols, like: (ice-9 common-list).
+# @var{modvar} is the Guile Scheme variable to check.
+#
+AC_DEFUN([GUILE_MODULE_EXPORTS],
+ [GUILE_MODULE_CHECK($1,$2,$3,exports `$3')
+ ])
+
+# GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
+#
+# Usage: GUILE_MODULE_REQUIRED_EXPORT(module,modvar)
+#
+# @var{module} is a list of symbols, like: (ice-9 common-list).
+# @var{modvar} is the Guile Scheme variable to check.
+#
+AC_DEFUN([GUILE_MODULE_REQUIRED_EXPORT],
+ [GUILE_MODULE_EXPORTS(guile_module_required_export,$1,$2)
+ if test "$guile_module_required_export" = "no" ; then
+ AC_MSG_ERROR([module $1 does not export $2; required])
+ fi
+ ])
+
+## guile.m4 ends here
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.4: 0003-Fixing-generate-docs.patch --]
[-- Type: text/x-patch, Size: 1303 bytes --]
From 616e3eadf124ed0183ecb73ac165c01172e96ec2 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 22:50:48 -0300
Subject: [PATCH 03/11] Fixing generate-docs
* doc/generate-docs.mk: Use am/guile.mk.
---
doc/generate-docs.mk | 3 ++-
1 file changed, 2 insertions(+), 1 deletion(-)
diff --git a/doc/generate-docs.mk b/doc/generate-docs.mk
index f7a770a..45936ee 100644
--- a/doc/generate-docs.mk
+++ b/doc/generate-docs.mk
@@ -19,6 +19,8 @@
# Makefile snippet
#
+include $(top_srcdir)/am/guile.mk
+
wrapset_module = "(gnome gw $(wrapset_stem)-spec)"
wrapset_name = "gnome-$(wrapset_stem)"
GTK_DOC_TO_TEXI_STUBS = '((@ (gnome gw support gtk-doc) gtk-doc->texi-stubs) (cdr (program-arguments)))'
@@ -29,7 +31,6 @@ GTK_DOC_DEFUN_GWRAP_ARGS = $(wrapset_module) $(wrapset_name)
GTK_DOC_DEFUN_METHOD = $(GTK_DOC_DEFUN_HEURISTICS_METHOD)
GTK_DOC_DEFUN_ARGS = $(GTK_DOC_DEFUN_HEURISTICS_ARGS)
GTK_DOC_TO_TEXI_DEFUNS = "(apply (@ (gnome gw support gtk-doc) gtk-doc->texi-defuns) (cadr (program-arguments)) '$(GTK_DOC_DEFUN_METHOD) '($(GTK_DOC_DEFUN_ARGS)) (cddr (program-arguments)))"
-GUILE = $(top_builddir)/dev-environ guile
generate-stubs:
$(GUILE) $(GUILE_FLAGS) -c $(GTK_DOC_TO_TEXI_STUBS) $(docbook_xml_files)
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.5: 0004-Fixing-a-texi-related-warning.patch --]
[-- Type: text/x-patch, Size: 1569 bytes --]
From 4710e8dcebbcdc8b748bd0ba06089081b3080f52 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 22:52:06 -0300
Subject: [PATCH 04/11] Fixing a texi related warning
* doc/defuns-cairo-paths.xml.texi: @end command must start on a new
line. Note that this file is actually generated, but reaally rarely,
and till we fix this in the generation, just to avoid two warning I
went ahead and manally fixed this, I just don't like warnings :).
---
doc/defuns-cairo-paths.xml.texi | 6 ++++--
1 file changed, 4 insertions(+), 2 deletions(-)
diff --git a/doc/defuns-cairo-paths.xml.texi b/doc/defuns-cairo-paths.xml.texi
index b72f789..680c4ed 100644
--- a/doc/defuns-cairo-paths.xml.texi
+++ b/doc/defuns-cairo-paths.xml.texi
@@ -17,7 +17,8 @@ If there is insufficient memory to copy the path. In this
@samp{CAIRO_STATUS_NO_MEMORY}.@item
If @var{cr} is already in an error state. In this case
@samp{path->status} will contain the same status that
- would be returned by @code{cairo-status}.@end enumerate
+ would be returned by @code{cairo-status}.
+@end enumerate
@table @var
@item cr
@@ -54,7 +55,8 @@ If there is insufficient memory to copy the path. In this
@samp{CAIRO_STATUS_NO_MEMORY}.@item
If @var{cr} is already in an error state. In this case
@samp{path->status} will contain the same status that
- would be returned by @code{cairo-status}.@end enumerate
+ would be returned by @code{cairo-status}.
+@end enumerate
@table @var
@item cr
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.6: 0005-Some-more-files-we-don-t-want-to-track.patch --]
[-- Type: text/x-patch, Size: 1326 bytes --]
From dcbd46aac71dd95219eae686bb6af7eb032f35e2 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 22:57:06 -0300
Subject: [PATCH 05/11] Some more files we don't want to track
* .gitignore: Some more files we don't want to track.
---
.gitignore | 22 ++++++++++++++++------
1 file changed, 16 insertions(+), 6 deletions(-)
diff --git a/.gitignore b/.gitignore
index 69cc11a..f02d32c 100644
--- a/.gitignore
+++ b/.gitignore
@@ -3,17 +3,28 @@ Makefile.in
/aclocal.m4
/autom4te.cache
/autoregen.sh
-/cairo/config.scm
+/build-aux/compile
/build-aux/config.guess
+/build-aux/config.rpath
+/build-aux/config.sub
+/build-aux/install-sh
+/build-aux/ltmain.sh
+/build-aux/missing
+/build-aux/texinfo.tex
+/m4/libtool.m4
+/m4/lt~obsolete.m4
+/m4/ltoptions.m4
+/m4/ltsugar.m4
+/m4/ltversion.m4
+/am/*~
+/cairo/config.scm
/config.h
/config.h.in
/config.log
/config.status
-/build-aux/config.sub
/configure
/build-aux/depcomp
/doc/guile-cairo.info
-/build-aux/texinfo.tex
/env
/guile-cairo.pc
/guile-cairo/.deps
@@ -21,9 +32,8 @@ Makefile.in
/guile-cairo/*.x
*.la
*.lo
-/build-aux/install-sh
/libtool
-/build-aux/ltmain.sh
-/build-aux/missing
/stamp-h1
/config.h.in~
+/doc/guile-cairo
+/doc/guile-cairo.html/
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.7: 0006-Fixing-Makefile.am.patch --]
[-- Type: text/x-patch, Size: 3601 bytes --]
From 7fc5ffc10560a87699b319a9c9d65941cf557343 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 22:59:04 -0300
Subject: [PATCH 06/11] Fixing Makefile.am
* Makefile.am: Adding to EXTRA_DIST, new 'distclean-local:' target,
removing the 'env:' target, configure.ac handles that now.
---
Makefile.am | 93 +++++++++++++++++++++++++++++++++++++++++++------------------
1 file changed, 66 insertions(+), 27 deletions(-)
diff --git a/Makefile.am b/Makefile.am
index c52d37f..af0de80 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,29 +1,31 @@
-# guile-cairo
-# Copyright (C) 2007,2011 Andy Wingo <wingo@pobox.com>
-#
-# This program is free software: you can redistribute it and/or modify
-# it under the terms of the GNU Lesser General Public License as
-# published by the Free Software Foundation, either version 3 of the
-# License, or (at your option) any later version.
-#
-# This program is distributed in the hope that it will be useful, but
-# WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
-# Lesser General Public License for more details.
-#
-# You should have received a copy of the GNU Lesser General Public
-# License along with this program. If not, see
-# <http://www.gnu.org/licenses/>.
-
-SUBDIRS = guile-cairo cairo examples tests doc
-
-env: Makefile env.in
- sed -e "s|@top_srcdir\@|$(shell cd $(top_srcdir) && pwd)|" \
- $(srcdir)/env.in > env
- chmod +x env
-
-BUILT_SOURCES = env
-CLEANFILES = env
+
+####
+#### Guile-Cairo
+#### Copyright (C) 2007, 2011 Andy Wingo <wingo@pobox.com>
+#### Copyright (C) 2016 David Pirotte <david at altosw dot be>
+
+#### This program is free software: you can redistribute it and/or
+#### modify it under the terms of the GNU Lesser General Public
+#### License as published by the Free Software Foundation, either
+#### version 3 of the License, or (at your option) any later version.
+
+#### This program is distributed in the hope that it will be useful,
+#### but WITHOUT ANY WARRANTY; without even the implied warranty of
+#### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+#### Lesser General Public License for more details.
+
+#### You should have received a copy of the GNU Lesser General Public
+#### License along with this program. If not, see
+#### <http://www.gnu.org/licenses/>.
+####
+
+
+SUBDIRS = \
+ guile-cairo \
+ cairo \
+ examples \
+ tests \
+ doc
scmdir=$(prefix)/share/guile/site
@@ -44,4 +46,41 @@ gen-ChangeLog:
mv $(distdir)/cl-t $(distdir)/ChangeLog; \
fi
-EXTRA_DIST = env.in autogen.sh HACKING COPYING.LESSER $(scm_DATA)
+EXTRA_DIST = \
+ AUTHORS \
+ ChangeLog \
+ ChangeLog.2007 \
+ COPYING \
+ COPYING.LESSER \
+ HACKING \
+ INSTALL \
+ NEWS \
+ README \
+ env.in \
+ guile-cairo.pc.in \
+ $(wildcard am/*) \
+ $(wildcard m4/*) \
+ $(scm_DATA)
+
+distclean-local:
+ rm -f Makefile.in
+ rm -f aclocal.m4
+ rm -rf autom4te.cache
+ rm -rf build-aux
+ rm -f configure
+ rm -f *~
+ rm -f guile-cairo-*.tar.gz
+ rm -f guile-cairo-*.tar.gz.sig
+ rm -rf doc/guile-caito
+ rm -rf doc/guile-caito.html
+ rm -f doc/*.info
+ rm -f doc/*.pdf
+ rm -f doc/*~
+ rm -f doc/*.aux doc/*.cp doc/*.cps doc/*.fn doc/*.fns doc/*.ky
+ rm -f doc/*.log doc/*.pg doc/*.toc doc/*.tp doc/*.vr doc/*.vrs
+ rm -f doc/Makefile.in
+ rm -f doc/stamp-vti
+ rm -f cairo/*~
+ rm -f guile-cairo/*~
+ rm -f examples/*~
+ rm -f tests/*~
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.8: 0007-Fixing-autogen.sh.patch --]
[-- Type: text/x-patch, Size: 1231 bytes --]
From 482f1bc7e739067eb2bf9df196d7ad79216034b7 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 23:06:48 -0300
Subject: [PATCH 07/11] Fixing autogen.sh
* autogen.sh: (a) Since we will use guile.m4 GUILE_FLAGS macro, among
others, we need to fool automake wrt build-aux/config.rpath: see the
comment on the top of this file for further details; (b) let's not
call ./configure, rather invite users to so.
---
autogen.sh | 15 ++++++++++++---
1 file changed, 12 insertions(+), 3 deletions(-)
diff --git a/autogen.sh b/autogen.sh
index 3e2eae3..d4a7c4a 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -1,6 +1,15 @@
#!/bin/sh
-set -e
+# configure.ac uses the guile.m4 GUILE_FLAGS macro, among others,
+# which needs build-aux/config.rpath which is not installed anymore by
+# modern version of automake, and without it, this script will raise
+# an error. For why it's needed, see the comments wtr in m4/guile.m4.
+if [ ! -d "build-aux" ]; then
+ mkdir build-aux
+fi
+touch build-aux/config.rpath
+
autoreconf -vif
-./configure "$@"
-echo "Now type 'make' to compile $package."
+
+echo
+echo "Now run ./configure --prefix=/your/prefix."
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.9: 0008-Fixing-the-doc-Makefile.am.patch --]
[-- Type: text/x-patch, Size: 1042 bytes --]
From 82a59db34b889dcc1e9d455ab1ebe914faf1a5cd Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 23:11:50 -0300
Subject: [PATCH 08/11] Fixing the doc Makefile.am
* doc/Makefile.am: (a) Include am/guile.mk; (b) Use 'clean-local:'
target, not 'clean:'.
---
doc/Makefile.am | 4 ++--
1 file changed, 2 insertions(+), 2 deletions(-)
diff --git a/doc/Makefile.am b/doc/Makefile.am
index 4fe1dae..0e330a0 100644
--- a/doc/Makefile.am
+++ b/doc/Makefile.am
@@ -35,14 +35,14 @@ clean-www:
find www -name 'index.html' -print \
| while read f; do rm -f "$$f"; done
-clean: clean-www
+clean-local: clean-www
guile-cairo-html:
makeinfo --html $(srcdir)/guile-cairo.texi
+include $(top_srcdir)/am/guile.mk
include generate-docs.mk
-GUILE = $(top_builddir)/env guile
cairo_docbook_xml_wildcard = ~/src/gnome2/cairo/doc/public/xml/cairo*.xml
docbook_xml_files = $(wildcard $(cairo_docbook_xml_wildcard))
GTK_DOC_DEFUN_HEURISTICS_METHOD = heuristics
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.10: 0009-Fixing-configure.ac.patch --]
[-- Type: text/x-patch, Size: 3458 bytes --]
From e81e1786839009a3d5c297fc32219be8bf5a2ffe Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 23:13:52 -0300
Subject: [PATCH 09/11] Fixing configure.ac
* configure.ac: (a) bumping prereq, automake and cairo deps; (b) bumping
guile-cairo version to 1.10.0; (c) use m4 macros subdir; (d) use
automake init options '1.14 gnu -Wno-portability -Wno-syntax
color-tests serial-tests foreign'; (e) display a copyright notice;
(f) use LT_INIT, not AC_PROG_LIBTOOL; (g) use guile's m4 macro to search
for guile development fles, flags, site directory; (h) let's handle
env.in here, not in the Makefile.am
---
configure.ac | 57 +++++++++++++++++++++++++++++++--------------------------
1 file changed, 31 insertions(+), 26 deletions(-)
diff --git a/configure.ac b/configure.ac
index df7a306..40ce637 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,6 +1,7 @@
define(GUILE_CAIRO_CONFIGURE_COPYRIGHT,[[
Copyright (C) 2007, 2011 Andy Wingo <wingo@pobox.com>
+Copyright (C) 2016 David Pirotte <david at altosw dot be>
This program is free software: you can redistribute it and/or modify
it under the terms of the GNU Lesser General Public License as
@@ -18,21 +19,25 @@ License along with this program. If not, see
]])
-AC_PREREQ(2.52)
-AC_INIT(HACKING)
+AC_PREREQ(2.69)
+AC_INIT([guile-cairo], [1.10.0])
+
AC_CONFIG_AUX_DIR([build-aux])
-AC_COPYRIGHT(GUILE_CAIRO_CONFIGURE_COPYRIGHT)
+AC_CONFIG_MACRO_DIR([m4])
+
AM_CONFIG_HEADER(config.h)
-AM_INIT_AUTOMAKE(guile-cairo, 1.9.91)
-AC_SUBST(VERSION,1.9.91)
+AM_INIT_AUTOMAKE([1.14 gnu -Wno-portability -Wno-syntax \
+ color-tests serial-tests foreign])
+AM_MAINTAINER_MODE([enable])
+AM_SILENT_RULES([yes])
-AC_DISABLE_STATIC
+AC_COPYRIGHT(GUILE_CAIRO_CONFIGURE_COPYRIGHT)
AC_ISC_POSIX
AC_PROG_CC
AC_STDC_HEADERS
-AC_PROG_LIBTOOL
+LT_INIT([disable-static])
if test "x$prefix" = xNONE; then
AC_MSG_ERROR([No explicit prefix given.
@@ -51,8 +56,11 @@ you run guile. (Which is a pain.)])
fi
WARN_CFLAGS=-Wall
-AC_ARG_ENABLE([Werror], AC_HELP_STRING([--disable-Werror],[Don't stop the build on errors]),
- [], WARN_CFLAGS="-Wall -Werror")
+AC_ARG_ENABLE(
+ [Werror],
+ AC_HELP_STRING([--disable-Werror],[Don't stop the build on errors]),
+ [],
+ [WARN_CFLAGS="-Wall -Werror"])
AC_SUBST(WARN_CFLAGS)
# Optimize the DSO symbol hash table -- see ulrich drepper's paper,
@@ -65,27 +73,24 @@ AC_SUBST(AM_LDFLAGS)
#
# Check for Guile
#
-GUILE_EFFECTIVE_VERSION=no
-all_versions="2.2 2.0 1.8"
-for v in $all_versions; do
- if test $GUILE_EFFECTIVE_VERSION = no; then
- AC_MSG_NOTICE([checking for Guile $v.x])
- PKG_CHECK_MODULES(GUILE, guile-$v, [GUILE_EFFECTIVE_VERSION=$v], [true])
- fi
-done
-
-AC_SUBST(GUILE_EFFECTIVE_VERSION)
-
-if test $GUILE_EFFECTIVE_VERSION = no; then
- AC_MSG_ERROR([Failed to find Guile. Is it installed?])
-else
- AC_MSG_NOTICE([found Guile $GUILE_EFFECTIVE_VERSION.x])
-fi
-PKG_CHECK_MODULES(CAIRO, cairo >= 1.2.0)
+GUILE_PKG([2.2 2.0])
+GUILE_PROGS([2.0.11])
+GUILE_FLAGS
+GUILE_SITE_DIR
+GUILE_GLOBAL_SITE_DIR
+GUILE_SITE_CCACHE_DIR
+
+
+#
+# Check for Cairo
+#
+
+PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0)
AC_SUBST(CAIRO_LIBS)
AC_SUBST(CAIRO_CFLAGS)
+AC_CONFIG_FILES([env], [chmod +x env])
AC_CONFIG_FILES(
Makefile
guile-cairo.pc
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.11: 0010-Fixing-make-distclean.patch --]
[-- Type: text/x-patch, Size: 1162 bytes --]
From 30fdf133a630643ac84d9338789d7e6747be1247 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Wed, 17 Aug 2016 23:34:51 -0300
Subject: [PATCH 10/11] Fixing make distclean
* Makefile.am: (a) Do not delete build-aux/gitlog-to-changelog;
(b) Fixing two tipos, guile-cairo, not guile-caito :).
---
Makefile.am | 13 ++++++++++---
1 file changed, 10 insertions(+), 3 deletions(-)
diff --git a/Makefile.am b/Makefile.am
index af0de80..e1b6146 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -66,13 +66,20 @@ distclean-local:
rm -f Makefile.in
rm -f aclocal.m4
rm -rf autom4te.cache
- rm -rf build-aux
+ rm -f build-aux/compile
+ rm -f build-aux/config.guess
+ rm -f build-aux/config.rpath
+ rm -f build-aux/config.sub
+ rm -f build-aux/install-sh
+ rm -f build-aux/ltmain.sh
+ rm -f build-aux/missing
+ rm -f build-aux/texinfo.tex
rm -f configure
rm -f *~
rm -f guile-cairo-*.tar.gz
rm -f guile-cairo-*.tar.gz.sig
- rm -rf doc/guile-caito
- rm -rf doc/guile-caito.html
+ rm -rf doc/guile-cairo
+ rm -rf doc/guile-cairo.html
rm -f doc/*.info
rm -f doc/*.pdf
rm -f doc/*~
--
2.8.1
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #1.1.12: 0011-One-more-make-distclean-fix.patch --]
[-- Type: text/x-patch, Size: 1148 bytes --]
From 7b2ecea3965c5fdffa8b92e78890b6b7365a8de5 Mon Sep 17 00:00:00 2001
From: David Pirotte <david@altosw.be>
Date: Thu, 18 Aug 2016 00:36:52 -0300
Subject: [PATCH 11/11] One more make distclean fix
* Makefile.am: 'distclean-local:' target to remove some more files.
---
Makefile.am | 12 ++++++++++++
1 file changed, 12 insertions(+)
diff --git a/Makefile.am b/Makefile.am
index e1b6146..b59ff2c 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -74,6 +74,13 @@ distclean-local:
rm -f build-aux/ltmain.sh
rm -f build-aux/missing
rm -f build-aux/texinfo.tex
+ rm -f build-aux/depcomp
+ rm -f m4/libtool.m4
+ rm -f m4/ltoptions.m4
+ rm -f m4/ltsugar.m4
+ rm -f m4/ltversion.m4
+ rm -f m4/lt~obsolete.m4
+ rm -f config.h.in
rm -f configure
rm -f *~
rm -f guile-cairo-*.tar.gz
@@ -88,6 +95,11 @@ distclean-local:
rm -f doc/Makefile.in
rm -f doc/stamp-vti
rm -f cairo/*~
+ rm -f cairo/Makefile.in
rm -f guile-cairo/*~
+ rm -f guile-cairo/Makefile.in
rm -f examples/*~
+ rm -f examples/Makefile.in
rm -f tests/*~
+ rm -f tests/Makefile.in
+ rm -f tests/unit-tests/Makefile.in
--
2.8.1
[-- Attachment #1.2: OpenPGP digital signature --]
[-- Type: application/pgp-signature, Size: 473 bytes --]
[-- Attachment #2: Type: text/plain, Size: 162 bytes --]
_______________________________________________
guile-gtk-general mailing list
guile-gtk-general@gnu.org
https://lists.gnu.org/mailman/listinfo/guile-gtk-general
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2016-08-18 8:50 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2016-08-18 8:50 guile-cairo - autotool chain patches - prerelease David Pirotte
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).