built-in procedural logical operator

built-in procedural logical operator

[Alex Vong]

Hi everyone,

I am learning scheme, please bear with me if I am wrong.

I try to define a new function LIST-OF-STRING?

    (define (list-of-string? lst)
      (reduce and #f (map string? lst)))

and I get the error

    While compiling expression:
    ERROR: Syntax error:
    unknown location: source expression failed to match any pattern in form and

It seems it is because AND is implemented as a macro,
so I try to implement my own RECURSIVE-AND

    (define (recursive-and . arg-lst)
      (cond ((null? arg-lst) #t)
            ((not (car arg-lst)) #f)
            (else (apply recursive-and (cdr arg-lst)))))

and now

    (define (list-of-string? lst)
      (reduce recursive-and #f (map string? lst)))

works as intended.

Is it a leaking implementation detail that AND is implemented as a macro?
Do we have a built-in procedural logical operators so that we don't that error?
I know it is easy enough to define your own RECURSIVE-AND and RECURSIVE-OR,
I just want to know it is a bug or a feature?
Thanks!

Cheers,
Alex

Re: built-in procedural logical operator

[David Kastrup]

Alex Vong <alexvong1995@gmail.com> writes:

> Hi everyone,
>
> I am learning scheme, please bear with me if I am wrong.
>
> I try to define a new function LIST-OF-STRING?
>
>     (define (list-of-string? lst)
>       (reduce and #f (map string? lst)))
>
> and I get the error
>
>     While compiling expression:
>     ERROR: Syntax error:
>     unknown location: source expression failed to match any pattern in form and
>
> It seems it is because AND is implemented as a macro,
> so I try to implement my own RECURSIVE-AND
>
>     (define (recursive-and . arg-lst)
>       (cond ((null? arg-lst) #t)
>             ((not (car arg-lst)) #f)
>             (else (apply recursive-and (cdr arg-lst)))))
>
> and now
>
>     (define (list-of-string? lst)
>       (reduce recursive-and #f (map string? lst)))
>
> works as intended.
>
> Is it a leaking implementation detail that AND is implemented as a
> macro?

No.  It cannot be a function since it stops evaluation after the first
false argument

> Do we have a built-in procedural logical operators so that we don't
> that error?

From (srfi srfi-1):

(and ...) -> (every identity ...
(or ...) -> (any identity ...
(define (list-of-string? lst) (every string? lst))

Of course, this definition returns #t for '() while your definition
returns #f for '().  I'd argue the former is more correct.  But of
course you can just write
(define (list-of-string lst) (and (pair? lst) (every string? lst)))
if you want the latter.

-- 
David Kastrup

Re: built-in procedural logical operator

[Alex Vong]

2015-09-02 0:21 GMT+08:00, David Kastrup <dak@gnu.org>:
> From (srfi srfi-1):
>
> (and ...) -> (every identity ...
> (or ...) -> (any identity ...
> (define (list-of-string? lst) (every string? lst))
>
> Of course, this definition returns #t for '() while your definition
> returns #f for '().  I'd argue the former is more correct.  But of
> course you can just write
> (define (list-of-string lst) (and (pair? lst) (every string? lst)))
> if you want the latter.

Thanks, this is exactly what I need. I love the name "every" and
"any", they sound very appropriate.

Cheers,
Alex