Re: Growable arrays?

[Daniel Hartwig <mandyke@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 512 bytes --]

On 11 June 2012 17:01, Daniel Hartwig <mandyke@gmail.com> wrote:
> For reference, attached is a growable vector I use in several
> projects, adapted to support the length operation similar to Lua (i.e.
> first unset numerical index).  There is no catching of exceptions
> here, every access to the data is through the dynvector procedures
> which check the index and vector size.

Always test before posting even small changes to existing code :-)

Updated attachment to actually run without problems

[-- Attachment #2: dynvector.scm --]
[-- Type: application/octet-stream, Size: 1915 bytes --]

(define-module (dynvector)
  #:use-module (srfi srfi-9)
  #:export (dynvector
            make-dynvector
            dynvector?
            dynvector-length
            dynvector-capacity
            dynvector-ref
            dynvector-set!
            dynvector-growth-factor))

(define-record-type dynvector-type
  (%make-dynvector data cached-length)
  dynvector?
  (data dynvector-data set-dynvector-data!)
  (cached-length dynvector-cached-length set-dynvector-cached-length!))

(define dynvector-growth-factor
  (make-fluid 2))

(define (dynvector . l)
  (%make-dynvector (apply vector l) #f))

(define (make-dynvector len . rest)
  (%make-dynvector (apply make-vector len rest) #f))

(define (%dynvector-length dynvector)
  (let iter ((k 0))
    (cond ((eq? k (dynvector-capacity dynvector)) k)
          ((eq? *unspecified* (dynvector-ref dynvector k)) k)
          (else (iter (1+ k))))))

;; index of the first unspecified value
(define (dynvector-length dynvector)
  (unless (dynvector-cached-length dynvector)
    (set-dynvector-cached-length! dynvector (%dynvector-length dynvector)))
  (dynvector-cached-length dynvector))

(define (dynvector-capacity dynvector)
 (vector-length (dynvector-data dynvector)))

(define (dynvector-ref dynvector k)
  (if (< k (dynvector-capacity dynvector))
      (vector-ref (dynvector-data dynvector) k)
      *unspecified*))

(define (dynvector-set! dynvector k obj)
  (while (<= (dynvector-capacity dynvector) k)
    (dynvector-grow! dynvector))
  (set-dynvector-cached-length! dynvector #f)
  (vector-set! (dynvector-data dynvector) k obj))

(define (dynvector-grow! dynvector)
  (let* ((vec1 (dynvector-data dynvector))
         (end1 (vector-length vec1))
         (vec2 (make-vector
                (* (fluid-ref dynvector-growth-factor) end1)
                *unspecified*)))
    (vector-move-left! vec1 0 end1 vec2 0)
    (set-dynvector-data! dynvector vec2)))