[Gnus] `From' according to `Envelope-to'.

[Gnus] `From' according to `Envelope-to'.

[Michael Cadilhac]

  As I've multiple  aliases for the same mailbox,  I receive mail sent
  to different addresses (mentioned in the `envelope-to' field of the
  received messages).

  In order to not  disturb the sender, I want - when  replying - to be
  warned like :

  ``Your default "from"  field is `michael.cadilhac@lrde.org', but the
  sender used `mc@lrde.epita.fr'. Change ?''

  I've been searching in the gnus sources for a while now, and I don't
  see  hooks   or  customization  rightly  situated   to  compare  the
  `envelope-to' field  of the original  message, and the  `from' field
  used (according to gnus-posting-styles). Have I missed something ?

  Thanks.

-- 
    Michael Cadilhac, a.k.a. Micha [mika] |
                    Epita/LRDE promo 2007 |  Please note that you should
  2 rue de la Convention | 08.70.65.13.14 |  s/-@t-/@/ my mail address.
94270 Le Kremlin Bicetre | 06.23.20.31.30 |

Re: [Gnus] `From' according to `Envelope-to'.

[Reiner Steib]

On Tue, Sep 06 2005, Michael Cadilhac wrote:

[ Crosspost & Followup-To: gnu.emacs.gnus ]

>   As I've multiple  aliases for the same mailbox,  I receive mail sent
>   to different addresses (mentioned in the `envelope-to' field of the
>   received messages).
>
>   In order to not  disturb the sender, I want - when  replying - to be
>   warned like :
>
>   ``Your default "from"  field is `michael.cadilhac@lrde.org', but the
>   sender used `mc@lrde.epita.fr'. Change ?''

I use the following code to check the "To" header.  After changing
(message-fetch-field "to") to (message-fetch-field "envelope-to") it
might do what you want.

You also need to set `rs-message-to-from-addresses' or
`gnus-ignored-from-addresses'.

--8<---------------cut here---------------start------------->8---
(defvar rs-message-to-from-addresses gnus-ignored-from-addresses
  "Regexp matching To headers.

When using entries like

  ((message-mail-p)
   (address (rs-message-to-from-address)))

or

  ((message-mail-p)
   (address (rs-message-to-from-address \"foo@example.invalid\")))

in `gnus-posting-styles', the address in the From header is taken
from the To header of the article you are replying to.")

;;;###autoload
(defun rs-message-to-from-address (&optional fallback)
  "Return a suitable address.

See `rs-message-to-from-addresses' for more."
  (let ((to (and (boundp 'gnus-article-buffer)
		 (gnus-buffer-live-p gnus-article-buffer)
		 ;; `gnus-buffer-live-p' already returns
		 ;; `gnus-article-buffer', but it's not documented.  So
		 ;; let's be careful.
		 gnus-article-buffer
		 (with-current-buffer gnus-article-buffer
		   (message-fetch-field "to")))))
    (cond ((and to
		(not (string-match "," to));; FIXME
		(string-match rs-message-to-from-addresses to))
	   (let ((from (cadr (mail-extract-address-components to))))
	     ;; gnus-extract-address-components fails for dit Outlook stuff!
	     (if (and (string-match rs-message-to-from-addresses from)
		      (string-match (concat "^"
					    (if (boundp 'gnus-button-valid-localpart-regexp)
						gnus-button-valid-localpart-regexp
					      "[a-z0-9-_+.]+")
					    "@" message-valid-fqdn-regexp "$")
				    from))
		 from
	       (if (y-or-n-p
		    (format "Address <%s> might be bogus.  Use anyway? "
			    from))
		   from))))
	  (fallback fallback)
	  (t user-mail-address))))
--8<---------------cut here---------------end--------------->8---

Bye, Reiner.
-- 
       ,,,
      (o o)
---ooO-(_)-Ooo---  |  PGP key available  |  http://rsteib.home.pages.de/