Filename of buffer into kill-ring functionality

Filename of buffer into kill-ring functionality

[Marco Wahl]

Hello,

is there already a function in emacs that puts the
absolute filename belonging to a buffer into the
kill-ring?  Or is there even a keyboard-shortcut?


TIA
-- 
Marco Wahl
http://visenso.com

Re: Filename of buffer into kill-ring functionality

[Reiner Steib]

On Thu, Aug 31 2006, Marco Wahl wrote:

> is there already a function in emacs that puts the
> absolute filename belonging to a buffer into the
> kill-ring?  

I'm not aware of any predefined function for this.  You might use this
one:

(defun rs-kill-ring-save-buffer-file-name ()
  "Add `buffer-file-name' in the kill ring."
  (interactive)
  (if (not (stringp buffer-file-name))
      (error "Not visiting a file.")
    (kill-new buffer-file-name)
    ;; Give some visual feedback:
    (message "String \"%s\" saved to kill ring." buffer-file-name)
    buffer-file-name))

Bye, Reiner.
-- 
       ,,,
      (o o)
---ooO-(_)-Ooo---  |  PGP key available  |  http://rsteib.home.pages.de/

Re: Filename of buffer into kill-ring functionality

[Kevin Rodgers]

Reiner Steib wrote:
> On Thu, Aug 31 2006, Marco Wahl wrote:
> 
>> is there already a function in emacs that puts the
>> absolute filename belonging to a buffer into the
>> kill-ring?  
> 
> I'm not aware of any predefined function for this.  You might use this
> one:
> 
> (defun rs-kill-ring-save-buffer-file-name ()
>   "Add `buffer-file-name' in the kill ring."
>   (interactive)
>   (if (not (stringp buffer-file-name))
>       (error "Not visiting a file.")
>     (kill-new buffer-file-name)
>     ;; Give some visual feedback:
>     (message "String \"%s\" saved to kill ring." buffer-file-name)
>     buffer-file-name))

That can be easily generalized:

(defun kill-new-string-variable (variable)
   "Make the string value of VARIABLE the latest kill in the kill ring."
   (interactive (let ((current-buffer (current-buffer)))
		 (intern (completing-read "Variable: " obarray
					  (lambda (symbol)
					    (with-current-buffer current-buffer
					      (and (boundp symbol)
						   (stringp
						    (symbol-value symbol)))))
					  t))))
   ;; Let symbol-value and kill-new signal errors for unbound variables
   ;; and non-string values, respectively:
   (kill-new (symbol-value variable)))

(defun kill-new-buffer-file-name ()
   (kill-new-string-variable 'buffer-file-name))

-- 
Kevin

Re: Filename of buffer into kill-ring functionality

[Reiner Steib]

On Thu, Aug 31 2006, Kevin Rodgers wrote:

> (defun kill-new-string-variable (variable)
>   "Make the string value of VARIABLE the latest kill in the kill ring."
>   (interactive (let ((current-buffer (current-buffer)))
> 		 (intern (completing-read "Variable: " obarray
> 					  (lambda (symbol)
> 					    (with-current-buffer current-buffer
> 					      (and (boundp symbol)
> 						   (stringp
> 						    (symbol-value symbol)))))

Is there a reason why you use (boundp symbol) inside
(with-current-buffer ...)?  In other words: Is there any difference
between these variants?

(with-current-buffer current-buffer
  (and (boundp symbol)
       (stringp	(symbol-value symbol))))

(and (boundp symbol)
     (with-current-buffer current-buffer
       (stringp (symbol-value symbol))))

Bye, Reiner.
-- 
       ,,,
      (o o)
---ooO-(_)-Ooo---  |  PGP key available  |  http://rsteib.home.pages.de/

Re: Filename of buffer into kill-ring functionality

[Kevin Rodgers]

Reiner Steib wrote:
> On Thu, Aug 31 2006, Kevin Rodgers wrote:
> 
>> (defun kill-new-string-variable (variable)
>>   "Make the string value of VARIABLE the latest kill in the kill ring."
>>   (interactive (let ((current-buffer (current-buffer)))
>> 		 (intern (completing-read "Variable: " obarray
>> 					  (lambda (symbol)
>> 					    (with-current-buffer current-buffer
>> 					      (and (boundp symbol)
>> 						   (stringp
>> 						    (symbol-value symbol)))))
> 
> Is there a reason why you use (boundp symbol) inside
> (with-current-buffer ...)?  In other words: Is there any difference
> between these variants?
> 
> (with-current-buffer current-buffer
>   (and (boundp symbol)
>        (stringp	(symbol-value symbol))))
> 
> (and (boundp symbol)
>      (with-current-buffer current-buffer
>        (stringp (symbol-value symbol))))

The reason with-current-buffer is necessary at all is that the predicate
is run by completing-read with the minibuffer as the current buffer.  I
did it the first way when I first realized that, and it was simpler to
just wrap the entire body of the predicate.

Whether there's a difference between the two depends on whether a
variable with a buffer local value can be unbound globally (or in other
buffers, like the minibuffer).  I think that depends on how buffer local
bindings are implemented, and the first way is safer since it doesn't
depend on how that.

-- 
Kevin

Re: Filename of buffer into kill-ring functionality

[Marco Wahl]

Kevin Rodgers <ihs_4664@yahoo.com> writes:
> [...]
> (defun kill-new-string-variable (variable)
>    "Make the string value of VARIABLE the latest kill in the kill ring."
>    (interactive (let ((current-buffer (current-buffer)))
> 		 (intern (completing-read "Variable: " obarray
> 					  (lambda (symbol)
> 					    (with-current-buffer current-buffer
> 					      (and (boundp symbol)
> 						   (stringp
> 						    (symbol-value symbol)))))
> 					  t))))
>    ;; Let symbol-value and kill-new signal errors for unbound variables
>    ;; and non-string values, respectively:
>    (kill-new (symbol-value variable)))
> 
> (defun kill-new-buffer-file-name ()
>    (kill-new-string-variable 'buffer-file-name))

Thank you all!

Just a micro-remark for the not so lisp-experienced
user.  To be able to key-bind the latter function add
of '(interaction)' is needed:

(defun kill-new-buffer-file-name ()
  (interactive)
  (kill-new-string-variable 'buffer-file-name))


Best regards
-- 
Marco Wahl
http://visenso.com

Re: Filename of buffer into kill-ring functionality

[Eli Zaretskii]

> From: Marco Wahl <mw@visenso.de>
> Date: 31 Aug 2006 12:04:20 +0200
> 
> is there already a function in emacs that puts the
> absolute filename belonging to a buffer into the
> kill-ring?  Or is there even a keyboard-shortcut?

I use this trick:

   C-x C-f M-n C-a M-> M-w

You can create a keyboard macro from these, if you need to use it
frequently.