automatically change input method based on context

automatically change input method based on context

[Charles A. Roelli]

Hi,

I'd like Emacs to switch input method automatically based on the
font-lock face property of point.  As an example, if point is in a
comment, Emacs should run `(set-input-method "french-prefix")', and then
when point leaves the comment, `(set-input-method nil)' should run
again.  I managed to do it with a timer (not really elegant), but it
seems like this is something that would be possible with
`cursor-sensor-mode'.

My idea is to:
1. Add a `cursor-sensor-functions' property to all the text that is
   fontified as a comment (and somehow keep this dynamically updated).
2. Use this function in `cursor-sensor-functions' to handle changing the
   input method:

   (defun motion-set-input-method (window oldpos dir)
     (pcase dir
       ('entered (set-input-method "french-prefix"))
       ('left (set-input-method nil))))

But I don't know how to go about (1).  Any advice?

Cheers,
Charles

Re: automatically change input method based on context

[Stefan Monnier]

> 1. Add a `cursor-sensor-functions' property to all the text that is
>    fontified as a comment (and somehow keep this dynamically updated).
[...]
> But I don't know how to go about (1).  Any advice?

Yes: an after-advice.  On `font-lock-fontify-syntactically-region`.

Something along the lines of

    (add-advice 'font-lock-fontify-syntactically-region :after
                #'my-font-lock-comment-to-cursor-sensor)
    (defun my-font-lock-comment-to-cursor-sensor (start end &rest _)
      (save-excursion
        (goto-char start)
        (while (< (point) end)
          (if (not (eq (get-text-property (point) 'face)
                       'font-lock-comment-face))
              (goto-char (or (text-property-any (point) end 'face
                                                'font-lock-comment-face)
                             end))
            (let ((s (point)))
              (goto-char (or (text-property-not-all (point) end 'face
                                                    'font-lock-comment-face)
                             end))
              (put-text-property s (point) 'cursor-sensor-functions
                                 #'my-cursor-sensor-fun))))))
                  

-- Stefan

Re: automatically change input method based on context

[Charles A. Roelli]

Hi Stefan,

Thanks for your help.

Here's a full example should anyone be interested:

   (defun my-font-lock-comment-to-cursor-sensor (start end &rest _)
     (save-excursion
       (goto-char start)
       (while (< (point) end)
         (if (not (eq (get-text-property (point) 'face)
                      'font-lock-comment-face))
             (goto-char (or (text-property-any (point) end 'face
                                               'font-lock-comment-face)
                            end))
           (let ((s (point)))
             (goto-char (or (text-property-not-all (point) end 'face
                                                   'font-lock-comment-face)
                            end))
             (put-text-property s (point) 'cursor-sensor-functions
                                '(motion-set-input-method)))))))

   (defun motion-set-input-method (_window _oldpos dir)
     (pcase dir
       ('entered (set-input-method "french-prefix"))
       ('left (set-input-method nil))))

   (cursor-sensor-mode 1)

   (advice-add 'font-lock-fontify-syntactically-region :after
               #'my-font-lock-comment-to-cursor-sensor)

Cheers,
Charles

Re: automatically change input method based on context

[Phillip Lord]

You might want to take a look at my package:

https://github.com/phillord/tmmofl

It does pretty what you want -- it runs a function when point enters
into text with a particular highlighting, and another when you move
out. I use it to turn auto-fill-mode on in comments and off everywhere
else.

It uses post-command-hook to do it's stuff.

Let me know how you get on!

charles@aurox.ch (Charles A. Roelli) writes:

> Hi,
>
> I'd like Emacs to switch input method automatically based on the
> font-lock face property of point.  As an example, if point is in a
> comment, Emacs should run `(set-input-method "french-prefix")', and then
> when point leaves the comment, `(set-input-method nil)' should run
> again.  I managed to do it with a timer (not really elegant), but it
> seems like this is something that would be possible with
> `cursor-sensor-mode'.
>
> My idea is to:
> 1. Add a `cursor-sensor-functions' property to all the text that is
>    fontified as a comment (and somehow keep this dynamically updated).
> 2. Use this function in `cursor-sensor-functions' to handle changing the
>    input method:
>
>    (defun motion-set-input-method (window oldpos dir)
>      (pcase dir
>        ('entered (set-input-method "french-prefix"))
>        ('left (set-input-method nil))))
>
> But I don't know how to go about (1).  Any advice?
>
> Cheers,
> Charles

Re: automatically change input method based on context

[Charles A. Roelli]

Hi Phillip,

thanks for your tip, I will look into trying this too.

Cheers,
Charles