Assistance Writing Test for Org Agenda Custom Bulk Function

Assistance Writing Test for Org Agenda Custom Bulk Function

[Kevin Foley]

I'm trying write a test for a recently merged patch[1].

The patch adds the ability for users to specify a function to collect
args to be passed to a custom bulk function.

I'm trying to mock the argument collecting function and the custom bulk
function and then test that the arguments returned from the former are
passed to the latter.  I'd also like to test the argument function is
only called once while the bulk function is called multiple times.

Here is an example of what I'm trying to do:

(org-test-with-temp-text-in-file
    "* TODO a\n*TODO b"
  (let ((org-agenda-files `(,(buffer-file-name))))
    (org-todo-list)
    (org-agenda-bulk-mark-all)

    ;; Fails without these
    ;; (defvar f-called-cnt)
    ;; (defvar arg-f-call-cnt)
    ;; (defvar f-called-args)

    (let ((f-called-cnt 0)
          (arg-f-call-cnt 0)
          (f-called-args nil))
      (cl-letf (((symbol-function 'read-char-exclusive)
                 (lambda () ?P))
                (org-agenda-bulk-custom-functions
                 '((?P (lambda (&rest args)
                         (message "test" args)
                         (setq f-called-cnt (1+ f-called-cnt)
                               f-called-args args))
                       (lambda ()
                         (setq arg-f-call-cnt (1+ arg-f-call-cnt))
                         '(1 2 3))))))
        (org-agenda-bulk-action)
        (org-test-agenda--kill-all-agendas)

        (should (= f-called-cnt 2))
        (should (= arg-f-call-cnt 1))
        (should (equal f-called-args '(1 2 3)))))))

However, this fails with the error void-variable unless I first define
the variables for storing the call counts/arguments.  I understand that
defvar makes the variables dynamically bound, however I'm struggling to
understand why that's needed here.  I've read the manual entries on
variable binding but I seem to be missing something.

Can someone help me understand what's going on here?  Also, is there a
better way to approach this?

[1] https://code.orgmode.org/bzg/org-mode/commit/885ee086dde4ec2a9e303ff101e55d55c4b2363f

Re: Assistance Writing Test for Org Agenda Custom Bulk Function

[Kyle Meyer]

Kevin Foley writes:

> I'm trying to mock the argument collecting function and the custom bulk
> function and then test that the arguments returned from the former are
> passed to the latter.  I'd also like to test the argument function is
> only called once while the bulk function is called multiple times.
>
> Here is an example of what I'm trying to do:
>
> (org-test-with-temp-text-in-file
>     "* TODO a\n*TODO b"

Unrelated note: there's a missing a space between the second "*" and
"TODO".

[...]
>     (let ((f-called-cnt 0)
>           (arg-f-call-cnt 0)
>           (f-called-args nil))
>       (cl-letf (((symbol-function 'read-char-exclusive)
>                  (lambda () ?P))
>                 (org-agenda-bulk-custom-functions
>                  '((?P (lambda (&rest args)
>                          (message "test" args)
>                          (setq f-called-cnt (1+ f-called-cnt)
>                                f-called-args args))
>                        (lambda ()
>                          (setq arg-f-call-cnt (1+ arg-f-call-cnt))
>                          '(1 2 3))))))
>         (org-agenda-bulk-action)
>         (org-test-agenda--kill-all-agendas)
>
>         (should (= f-called-cnt 2))
>         (should (= arg-f-call-cnt 1))
>         (should (equal f-called-args '(1 2 3)))))))
>
> However, this fails with the error void-variable unless I first define
> the variables for storing the call counts/arguments.  I understand that
> defvar makes the variables dynamically bound, however I'm struggling to
> understand why that's needed here.  I've read the manual entries on
> variable binding but I seem to be missing something.
>
> Can someone help me understand what's going on here?

Perhaps you're not capturing the environment due to your quoting:

  ;; -*- lexical-binding: t; -*-

  (let ((x 0))
    '(t (lambda () x)))  ;; => (y (lambda nil x))
  
  (let ((x 0))
    (list t (lambda () x)))  ;; => (t (closure ((x . 0) t) nil x))

So try something like

  (org-agenda-bulk-custom-functions
   `((?P ,(lambda (&rest args)
            (message "test" args)
            (setq f-called-cnt (1+ f-called-cnt)
                  f-called-args args))
         ,(lambda ()
            (setq arg-f-call-cnt (1+ arg-f-call-cnt))
            '(1 2 3)))))

or

  (org-agenda-bulk-custom-functions
   (list
    (list ?P
          (lambda (&rest args)
            (message "test" args)
            (setq f-called-cnt (1+ f-called-cnt)
                  f-called-args args))
          (lambda ()
            (setq arg-f-call-cnt (1+ arg-f-call-cnt))
            '(1 2 3)))))

Re: Assistance Writing Test for Org Agenda Custom Bulk Function

[Kevin Foley]

Kyle Meyer <kyle@kyleam.com> writes:

> Unrelated note: there's a missing a space between the second "*" and
> "TODO".

Good catch, thank you.

> Perhaps you're not capturing the environment due to your quoting:
>
>   ;; -*- lexical-binding: t; -*-
>
>   (let ((x 0))
>     '(t (lambda () x)))  ;; => (y (lambda nil x))
>   
>   (let ((x 0))
>     (list t (lambda () x)))  ;; => (t (closure ((x . 0) t) nil x))
>
> So try something like
>
>   (org-agenda-bulk-custom-functions
>    `((?P ,(lambda (&rest args)
>             (message "test" args)
>             (setq f-called-cnt (1+ f-called-cnt)
>                   f-called-args args))
>          ,(lambda ()
>             (setq arg-f-call-cnt (1+ arg-f-call-cnt))
>             '(1 2 3)))))

This was exactly it, thank you.  I'll hopefully have this in a patch
shortly.

Kevin