Re: [Emacs-diffs] master 52cc9a5: Reimplement inline functions in ERC with define-inline.

Re: [Emacs-diffs] master 52cc9a5: Reimplement inline functions in ERC with define-inline.

[Stefan Monnier]

>     Reimplement inline functions in ERC with define-inline.

Yay, someone dared to use define-inline even though I haven't managed to
document it yet!
Thanks.

> -(defsubst erc-dcc-unquote-filename (filename)
> -  (erc-replace-regexp-in-string "\\\\\\\\" "\\"
> -                                (erc-replace-regexp-in-string "\\\\\"" "\"" filename t t) t t))
> +(define-inline erc-dcc-unquote-filename (filename)
> +  (inline-quote
> +   (erc-replace-regexp-in-string "\\\\\\\\" "\\"
> +                                 (erc-replace-regexp-in-string "\\\\\"" "\"" ,filename t t) t t)))

Is it worth the trouble to inline this function at all?
I find it hard to believe that the extra function call overhead would
ever be noticeable compared to the time to do the two regexp replacements.

> -(defsubst erc-nickserv-alist-sender (network &optional entry)
> -  (nth 1 (or entry (assoc network erc-nickserv-alist))))
> +(define-inline erc-nickserv-alist-sender (network &optional entry)
> +  (inline-quote (nth 1 (or ,entry (assoc ,network erc-nickserv-alist)))))

When inlined, `entry` will be evaluated before `network`.
Worse yet: `network` won't be evaluated at all if `entry` is non-nil.
So it won't behave the same when inlined than when non-inlined, which
I'd consider as a bug.

AFAICT, `entry` is never passed anyway, so you could just remove it.

> -(defsubst erc-get-server-user (nick)
> +(define-inline erc-get-server-user (nick)
>    "Find the USER corresponding to NICK in the current server's
>  `erc-server-users' hash table."
> -  (erc-with-server-buffer
> -    (gethash (erc-downcase nick) erc-server-users)))
> +  (inline-quote (erc-with-server-buffer
> +		  (gethash (erc-downcase ,nick) erc-server-users))))

This will evaluate `nick` in another buffer than the caller's
current-buffer, so if the argument refers to buffer-local variables the
result may be different when inlined than it would be when not inlined.


        Stefan

Re: [Emacs-diffs] master 52cc9a5: Reimplement inline functions in ERC with define-inline.

[Eli Zaretskii]

> From: Stefan Monnier <monnier@iro.umontreal.ca>
> Date: Sat, 18 Nov 2017 09:53:44 -0500
> Cc: Vibhav Pant <vibhavp@gmail.com>
> 
> >     Reimplement inline functions in ERC with define-inline.
> 
> Yay, someone dared to use define-inline even though I haven't managed to
> document it yet!

It's documented in the ELisp manual, although I guess what's there can
be improved.

Re: [Emacs-diffs] master 52cc9a5: Reimplement inline functions in ERC with define-inline.

[Vibhav Pant]

On Sat, Nov 18, 2017 at 8:23 PM, Stefan Monnier
<monnier@iro.umontreal.ca> wrote:
> Yay, someone dared to use define-inline even though I haven't managed to
> document it yet!

The existing documentation in inline.el is quite easy to understand. I have also
used it in other packages.

> > -(defsubst erc-nickserv-alist-sender (network &optional entry)
> > -  (nth 1 (or entry (assoc network erc-nickserv-alist))))
> > +(define-inline erc-nickserv-alist-sender (network &optional entry)
> > +  (inline-quote (nth 1 (or ,entry (assoc ,network erc-nickserv-alist)))))
>
> When inlined, `entry` will be evaluated before `network`.
> Worse yet: `network` won't be evaluated at all if `entry` is non-nil.
> So it won't behave the same when inlined than when non-inlined, which
> I'd consider as a bug.

I've pushed a fix by using `inline-letevals` to enforce the correct
evaluation order.

> > -(defsubst erc-get-server-user (nick)
> > +(define-inline erc-get-server-user (nick)
> >    "Find the USER corresponding to NICK in the current server's
> >  `erc-server-users' hash table."
> > -  (erc-with-server-buffer
> > -    (gethash (erc-downcase nick) erc-server-users)))
> > +  (inline-quote (erc-with-server-buffer
> > +               (gethash (erc-downcase ,nick) erc-server-users))))
>
> This will evaluate `nick` in another buffer than the caller's
> current-buffer, so if the argument refers to buffer-local variables the
> result may be different when inlined than it would be when not inlined.

I'm not entirely sure on how to fix this. Would reverting to defsubst/defun be
the only solution?

Thanks,
Vibhav

-- 
Vibhav Pant
vibhavp@gmail.com

Re: [Emacs-diffs] master 52cc9a5: Reimplement inline functions in ERC with define-inline.

[Stefan Monnier]

>> > -(defsubst erc-get-server-user (nick)
>> > +(define-inline erc-get-server-user (nick)
>> >    "Find the USER corresponding to NICK in the current server's
>> >  `erc-server-users' hash table."
>> > -  (erc-with-server-buffer
>> > -    (gethash (erc-downcase nick) erc-server-users)))
>> > +  (inline-quote (erc-with-server-buffer
>> > +               (gethash (erc-downcase ,nick) erc-server-users))))
>> This will evaluate `nick` in another buffer than the caller's
>> current-buffer, so if the argument refers to buffer-local variables the
>> result may be different when inlined than it would be when not inlined.
> I'm not entirely sure on how to fix this. Would reverting to defsubst/defun be
> the only solution?

inline-letevals will do the trick (because you can put it outside of the
`erc-with-server-buffer`).


        Stefan