Re: Can I disable yank's automatic "set mark"

[Stefan Monnier <monnier@iro.umontreal.ca>]

> Whenever I yank (ctrl-y) text into a buffer, the mark is automatically
> set.  Is there any way to disable this behavior?

Not directly, no.  Here's how I found out:

  C-h k C-y

told me that C-y is bound to `yank' defined in `simple.el'.
So I clicked on `simple.el' which brought me to the simple.el file where
it defines `yank'.  That definition starts with a longish text (that
same text you say in the *Help*), and then says:

  (interactive "*P")
  (setq yank-window-start (window-start))
  ;; If we don't get all the way thru, make last-command indicate that
  ;; for the following command.
  (setq this-command t)
  (push-mark (point))
  (insert-for-yank (current-kill (cond
				  ((listp arg) 0)
				  ((eq arg '-) -2)
				  (t (1- arg)))))
  (if (consp arg)
      ;; This is like exchange-point-and-mark, but doesn't activate the mark.
      ;; It is cleaner to avoid activation, even though the command
      ;; loop would deactivate the mark because we inserted text.
      (goto-char (prog1 (mark t)
		   (set-marker (mark-marker) (point) (current-buffer)))))
  ;; If we do get all the way thru, make this-command indicate that.
  (if (eq this-command t)
      (setq this-command 'yank))
  nil)

While you may not understand all of the code, you'll probaly notice
that it says "(push-mark (point))" and that it says so without any
intervening "if" or other conditional which means that it sets the mark
without any way not to do it.

So if you want to change it you have 2 solutions:
create a new command `my-yank' which copies all the above code except
for the push-mark call, or create a new command which calls `yank' and
then undoes that push-mark, e.g.

(defun my-yank ()
  "Put your description here."
  (interactive)
  (yank)
  (pop-mark))


        Stefan