What's the difference between (defvar foo) and (declare (special foo)), with lexical-binding on?

What's the difference between (defvar foo) and (declare (special foo)), with lexical-binding on?

[Dmitry Gutov]

[-- Attachment #1: Type: text/plain, Size: 771 bytes --]

1. Save a.el and b.el to the same dir.

2. Open b.el, type M-x eval-buffer.

3. Evaluate (b-foo), see 4 in the echo area.

Note that the assertion in `b-bar' succeeds, and so while `a-a' is not 
globally bound, it's visible from `b-bar'.

If I replace the definition of b-bar with

```
(defvar a-a)

(defun b-bar ()
   (cl-assert (= a-a 4))
   (let ((a-a 5))
     (a-bar)))
```

or even with

```
(defun b-bar ()
   (defvar a-a)
   (cl-assert (= a-a 4))
   (let ((a-a 5))
     (a-bar)))
```

(which apparently doesn't make `a-a' globally defined in that file, ref. 
http://debbugs.gnu.org/18059)

then, as I'd expect, after M-x eval-buffer, (b-bar) evaluates to 5.

Why does this happen? Is (defvar foo) the recommended option to use with 
lexical-binding on?

-- Dmitry

[-- Attachment #2: a.el --]
[-- Type: text/x-emacs-lisp, Size: 118 bytes --]

(defvar a-a)

(defun a-foo (callback)
  (let ((a-a 4))
    (funcall callback)))

(defun a-bar ()
  a-a)

(provide 'a)

[-- Attachment #3: b.el --]
[-- Type: text/x-emacs-lisp, Size: 222 bytes --]

;;; -*- lexical-binding: t -*-

(let ((load-path '(".")))
  (require 'a))

(defun b-foo ()
  (a-foo #'b-bar))

(defun b-bar ()
  (declare (special a-a))
  (cl-assert (= a-a 4))
  (let ((a-a 5))
    (a-bar)))

(provide 'b)

Re: What's the difference between (defvar foo) and (declare (special foo)), with lexical-binding on?

[Stefan Monnier]

(declare (special foo))

is a hack defined in CL.  It predates lexical-binding and I don't
think anyone has tried to adapt it to lexical-binding, so I don't know
what it does in the case of lexical-binding.


        Stefan

Re: What's the difference between (defvar foo) and (declare (special foo)), with lexical-binding on?

[Dmitry]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

> (declare (special foo))
>
> is a hack defined in CL.  It predates lexical-binding and I don't
> think anyone has tried to adapt it to lexical-binding, so I don't know
> what it does in the case of lexical-binding.

Thanks! So, you would advise not to use it in lexical-binding code at
all?

I think the biggest problem with it is it sorta-works-but-not-exactly.

Re: What's the difference between (defvar foo) and (declare (special foo)), with lexical-binding on?

[Stefan Monnier]

> Thanks! So, you would advise not to use it in lexical-binding code at all?

I think so, yes.


        Stefan