Re: [elpa] externals/debbugs b8c84dbe4b: Improve needed advice

Re: [elpa] externals/debbugs b8c84dbe4b: Improve needed advice

[Stefan Monnier]

Hi Michael,

> +(defvar debbugs-compat-url-http-attempt-keepalives nil
> +  "Temporary storage for `'.")
> +(defun debbugs-compat-add-debbugs-advice ()
> +  (with-no-warnings
> +    (setq debbugs-compat-url-http-attempt-keepalives
> +          url-http-attempt-keepalives))
> +  (advice-add
> +   'url-http-create-request :around
> +   (lambda (orig-fun)
> +     "Set `url-http-attempt-keepalives' to nil."
> +     (with-no-warnings (setq url-http-attempt-keepalives nil))
> +     (funcall orig-fun))
> +   '(name debbugs-advice)))
> +
> +(defun debbugs-compat-remove-debbugs-advice ()
> +  (advice-remove 'url-http-create-request 'debbugs-advice)
> +  (with-no-warnings
> +    (setq url-http-attempt-keepalives
> +          debbugs-compat-url-http-attempt-keepalives)))
[...]
> +(defun debbugs-soap-invoke (operation-name &rest parameters)
> +  "Invoke the SOAP connection.
> +OPERATION-NAME and PARAMETERS are as described in `soap-invoke'."
> +  (debbugs-compat-add-debbugs-advice)
> +  (prog1
> +      (apply #'soap-invoke operation-name parameters)
> +    (debbugs-compat-remove-debbugs-advice)))

I wonder you're doing it this way instead of the "more obvious":

    (defun debbugs-soap-invoke (operation-name &rest parameters)
      "Invoke the SOAP connection.
    OPERATION-NAME and PARAMETERS are as described in `soap-invoke'."
      (let ((url-http-attempt-keepalives nil))
        (apply #'soap-invoke operation-name parameters)))


- Stefan

Re: [elpa] externals/debbugs b8c84dbe4b: Improve needed advice

[Michael Albinus]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

> Hi Michael,

Hi Stefan,

>> +(defun debbugs-soap-invoke (operation-name &rest parameters)
>> +  "Invoke the SOAP connection.
>> +OPERATION-NAME and PARAMETERS are as described in `soap-invoke'."
>> +  (debbugs-compat-add-debbugs-advice)
>> +  (prog1
>> +      (apply #'soap-invoke operation-name parameters)
>> +    (debbugs-compat-remove-debbugs-advice)))
>
> I wonder you're doing it this way instead of the "more obvious":
>
>     (defun debbugs-soap-invoke (operation-name &rest parameters)
>       "Invoke the SOAP connection.
>     OPERATION-NAME and PARAMETERS are as described in `soap-invoke'."
>       (let ((url-http-attempt-keepalives nil))
>         (apply #'soap-invoke operation-name parameters)))

Because it doesn't work?

soap-invoke-internal binds url-http-attempt-keepalives to t, which is a
problem in a threaded function. See comment in debbugs-compat.el. See
also bug#73199 for the resulting error.

> - Stefan

Best regards, Michael.

Re: [elpa] externals/debbugs b8c84dbe4b: Improve needed advice

[Stefan Monnier]

>> I wonder you're doing it this way instead of the "more obvious":
>>
>>     (defun debbugs-soap-invoke (operation-name &rest parameters)
>>       "Invoke the SOAP connection.
>>     OPERATION-NAME and PARAMETERS are as described in `soap-invoke'."
>>       (let ((url-http-attempt-keepalives nil))
>>         (apply #'soap-invoke operation-name parameters)))
>
> Because it doesn't work?

🙂

> soap-invoke-internal binds url-http-attempt-keepalives to t, which is a
> problem in a threaded function. See comment in debbugs-compat.el. See
> also bug#73199 for the resulting error.

Hmm... IIUC the problem fundamentally is in `url-http.el`, right?


        Stefan

Re: [elpa] externals/debbugs b8c84dbe4b: Improve needed advice

[Michael Albinus]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

Hi Stefan,

>> soap-invoke-internal binds url-http-attempt-keepalives to t, which is a
>> problem in a threaded function. See comment in debbugs-compat.el. See
>> also bug#73199 for the resulting error.
>
> Hmm... IIUC the problem fundamentally is in `url-http.el`, right?

Yes. In bug#73199 I've focused on soap-client.el, because a general
solution in url-http.el seems to be expensive. But if it is possible in
url-http.el, it might be preferable.

>         Stefan

Best regards, Michael.