sml-mode indentation for structures

sml-mode indentation for structures

[Helmut Eller]

I'm using sml-mode version 6.5 from ELPA, but the indentation of
structures drives me nuts.  I would like to use a style like this:

structure Foo =
  struct
    fun foo x = x
  end

but by default sml-mode indents it like this:

structure Foo =
struct
fun foo x = x
end

Can somebody tell me how sml-mode indentation rules can be configured?

Helmut

Re: sml-mode indentation for structures

[Stefan Monnier]

> I'm using sml-mode version 6.5 from ELPA, but the indentation of
> structures drives me nuts.  I would like to use a style like this:

> structure Foo =
>   struct
>     fun foo x = x
>   end

> but by default sml-mode indents it like this:

> structure Foo =
> struct
> fun foo x = x
> end

> Can somebody tell me how sml-mode indentation rules can be configured?

I guess the "right" way to do that, would be:

   (defun my-sml-rules (orig kind token)
     (pcase (cons kind token)
       (`(:before . "d=")
        (if (smie-rule-parent-p "structure" "signature" "functor") 2
          (funcall orig kind token)))
       (`(:after . "struct") 2)
       (_ (funcall orig kind token))))

   (add-hook 'sml-mode-hook
             (lambda ()
               (add-function :around smie-indent-rules #'my-sml-rules)))

But since `add-function' is new in 24.4, you'll probably want something
more like:

   (defadvice sml-smie-rules (around my-sml-rules activate)
     (let ((i (pcase (cons (ad-get-arg 0) (ad-get-arg 1))
                (`(:before . "d=")
                 (if (smie-rule-parent-p "structure" "signature" "functor") 2))
                (`(:after . "struct") 2))))
       (if i
           (setq ad-return i)
         ad-do-it)))


-- Stefan "guaranteed 100% untested"

Re: sml-mode indentation for structures

[Helmut Eller]

On Mon, Oct 06 2014, Stefan Monnier wrote:

>> Can somebody tell me how sml-mode indentation rules can be configured?
>
> I guess the "right" way to do that, would be:
>
>    (defun my-sml-rules (orig kind token)
>      (pcase (cons kind token)
>        (`(:before . "d=")
>         (if (smie-rule-parent-p "structure" "signature" "functor") 2
>           (funcall orig kind token)))
>        (`(:after . "struct") 2)
>        (_ (funcall orig kind token))))
>
>    (add-hook 'sml-mode-hook
>              (lambda ()
>                (add-function :around smie-indent-rules #'my-sml-rules)))
>

Thanks!  That works very well.

> -- Stefan "guaranteed 100% untested"

I only had to replace smie-indent-rules with
(symbol-function 'sml-smie-rules).

Helmut

Re: sml-mode indentation for structures

[Stefan Monnier]

>> (add-function :around smie-indent-rules #'my-sml-rules)))
> I only had to replace smie-indent-rules with
> (symbol-function 'sml-smie-rules).

Oh, sorry, it should have been `smie-rules-function'.
Using (symbol-function 'sml-smie-rules) instead, ends up being more like
the `defadvice' case: it modifies the behavior of sml-mode globally
rather than only in the buffer where we run the code.


        Stefan

Re: sml-mode indentation for structures

[Helmut Eller]

On Mon, Oct 06 2014, Stefan Monnier wrote:

>>> (add-function :around smie-indent-rules #'my-sml-rules)))
>> I only had to replace smie-indent-rules with
>> (symbol-function 'sml-smie-rules).
>
> Oh, sorry, it should have been `smie-rules-function'.
> Using (symbol-function 'sml-smie-rules) instead, ends up being more like
> the `defadvice' case: it modifies the behavior of sml-mode globally
> rather than only in the buffer where we run the code.

I see.  Actually I run the code with eval-after-load; but, yes, using
sml-mode-hook feels cleaner.

Helmut

Re: sml-mode indentation for structures

[Helmut Eller]

On Mon, Oct 06 2014, Helmut Eller wrote:

> On Mon, Oct 06 2014, Stefan Monnier wrote:
>
>>>> (add-function :around smie-indent-rules #'my-sml-rules)))
>>> I only had to replace smie-indent-rules with
>>> (symbol-function 'sml-smie-rules).
>>
>> Oh, sorry, it should have been `smie-rules-function'.
>> Using (symbol-function 'sml-smie-rules) instead, ends up being more like
>> the `defadvice' case: it modifies the behavior of sml-mode globally
>> rather than only in the buffer where we run the code.
>
> I see.  Actually I run the code with eval-after-load; but, yes, using
> sml-mode-hook feels cleaner.

(add-function :around (local 'smie-indent-rules) #'my-sml-rules) seems
to be needed to make it work from sml-mode-hook.

Helmut

Re: sml-mode indentation for structures

[Stefan Monnier]

> (add-function :around (local 'smie-indent-rules) #'my-sml-rules) seems
> to be needed to make it work from sml-mode-hook.

Duh, yes,


        Stefan

Re: sml-mode indentation for structures

[Stefan Monnier]

>>>> (add-function :around smie-indent-rules #'my-sml-rules)))
>>> I only had to replace smie-indent-rules with
>>> (symbol-function 'sml-smie-rules).
>> Oh, sorry, it should have been `smie-rules-function'.
>> Using (symbol-function 'sml-smie-rules) instead, ends up being more like
>> the `defadvice' case: it modifies the behavior of sml-mode globally
>> rather than only in the buffer where we run the code.
> I see.  Actually I run the code with eval-after-load; but, yes, using
> sml-mode-hook feels cleaner.

BTW: (add-function <foo> (symbol-function <bar>) <toto>) is generally
better written as (advice-add <bar> <foo> <toto>).  The difference is
that advice-add will work even if <bar> is not yet defined (i.e. no
need for eval-after-load), and it will work if <bar> is autoloaded, and if
it's a macro, etc...


        Stefan