Re: Faking local dynamic function bindings

[Stefan Monnier <monnier@iro.umontreal.ca>]

> (defun foo (sexpr)
>   (eval
>    `(cl-macrolet ((contains (regexp)
>                             `(string-match ,regexp string)))
>       (sort (delq nil (mapcar #'(lambda (item)
>                                   (let ((string (assq item strings-alist)))
>                                     (when ,sexpr)
>                                     string))
>                               items-alist))
>             'string<))))

IIUC, sexpr is only known very late (like much later than when you
byte-compile this file).  If that's the case, there's no avoiding `eval'.
But you can move the eval closer to sexpr:

(defun foo (sexpr)
  (sort (delq nil (mapcar #'(lambda (item)
                              (let ((string (assq item strings-alist)))
                                (when (eval
                                        `(cl-macrolet ((contains (regexp)
                                                        `(string-match ,regexp ,string)))
                                           ,sexpr))
                                  string))
                          items-alist))
        #'string<)))

And of course, you don't need `contains' to be a macro:
            
(defun foo (sexpr)
  (sort (delq nil (mapcar #'(lambda (item)
                              (let ((string (assq item strings-alist)))
                                (when (eval
                                        `(cl-flet ((contains (regexp)
                                                     (string-match regexp ,string)))
                                           ,sexpr))
                                  string))
                          items-alist))
        #'string<)))


-- Stefan