copy-line (& default keychord)

copy-line (& default keychord)

[Enda]

[-- Attachment #1: Type: text/plain, Size: 271 bytes --]

What happened to copy-line in Emacs (which would copy the line). In Vi, copying a line is yy, what is the shortest way of copying a line in Emacs (without writing a lisp function in .emacs)? Should there be a default keychord for copying a line?


Best wishes,

Enda

[-- Attachment #2: Type: text/html, Size: 527 bytes --]

copy-line

[Enda]

[-- Attachment #1: Type: text/plain, Size: 264 bytes --]

Usedn't there be a copy-line in Emacs (which would copy the line). In Vi, copying a line is yy, what is the shortest way of copying a line in Emacs (without writing a lisp function in .emacs)? Should there be a default keystroke for copying a line?




- Enda

[-- Attachment #2: Type: text/html, Size: 1052 bytes --]

Re: copy-line

[Bastien]

Enda <enda_k2@yahoo.com> writes:

> Usedn't there be a copy-line in Emacs (which would copy the line). In
> Vi, copying a line is yy, what is the shortest way of copying a line
> in Emacs (without writing a lisp function in .emacs)? Should there be
> a default keystroke for copying a line?

What about one of these two?

(defun kill-line-save (&optional arg)
  "Save the rest of the line as if killed, but don't kill it."
  (interactive "P")
  (let ((buffer-read-only t))
    (kill-line arg)
    (message "Line(s) copied to the kill ring")))

(defun copy-line (&optional arg)
  "Copy the current line."
  (interactive "P")
  (copy-region-as-kill
   (point-at-bol)
   (+ (if kill-whole-line 1 0) (point-at-eol arg))))

-- 
 Bastien

Re: copy-line

[Guido Van Hoecke]

On 24 July 2012 18:06, Enda <enda_k2@yahoo.com> wrote:
> Usedn't there be a copy-line in Emacs (which would copy the line). In Vi,
> copying a line is yy, what is the shortest way of copying a line in Emacs
> (without writing a lisp function in .emacs)? Should there be a default
> keystroke for copying a line?
>

You may want to look at
http://www.northbound-train.com/emacs/whole-line-or-region.el

Copies or kills with one keystroke, the default one :)

I found this via http://emacswiki.org/emacs/CopyingWholeLines
where you can find other suggestions.

I prefer the whole-line-or-region apprach.

HTH,


Guido

--
Good government never depends upon laws, but upon the personal qualities of
those who govern.  The machinery of government is always subordinate to the
will of those who administer that machinery.  The most important element of
government, therefore, is the method of choosing leaders.
		-- Frank Herbert, "Children of Dune"

http://vanhoecke.org ... and go2 places!

Re: copy-line

[rfflrccrd]

Comparing Vi/Vim to other editors is not fair ;-)

Vanilla Emacs has no way to copy text that has not been marked.  Thus, to copy a line, you have to mark it first.  The complete sequence is:

C-a C-Space C-e M-w

In alternative, you can kill a line and yank it back at once:

C-S-Backspace C-k

Unlike Vi, the line will be copied/killed without its new line.  I don't know whether such behaviour is customizable.

Cheers.

Re: copy-line

[Dan Espen]

rfflrccrd@gmail.com writes:

> Comparing Vi/Vim to other editors is not fair ;-)
>
> Vanilla Emacs has no way to copy text that has not been marked.  Thus, to copy a line, you have to mark it first.  The complete sequence is:
>
> C-a C-Space C-e M-w
>
> In alternative, you can kill a line and yank it back at once:
>
> C-S-Backspace C-k
>
> Unlike Vi, the line will be copied/killed without its new line.  I don't know whether such behaviour is customizable.

It certainly is customizable:

(define-key global-map [(kp-add)] '(lambda () (interactive)
				     (beginning-of-line)
				     (if (eobp) (error "End of buffer"))
				     (let ((beg (point)))
				       (forward-line 1)
				       (kill-region beg (point))))); KeyPad + Key

Kill a line, yank it back:

C-KP+ C-y


-- 
Dan Espen

Re: copy-line

[Raffaele Ricciardi]

's requirement is that for its was that you shouldn't ha.On 07/25/2012 
02:41 PM, Dan Espen wrote:> rfflrccrd@gmail.com writes:
 >
 >> Comparing Vi/Vim to other editors is not fair ;-)
 >>
 >> Vanilla Emacs has no way to copy text that has not been marked. 
Thus, to copy a line, you have to mark it first.  The complete sequence is:
 >>
 >> C-a C-Space C-e M-w
 >>
 >> In alternative, you can kill a line and yank it back at once:
 >>
 >> C-S-Backspace C-k
 >>
 >> Unlike Vi, the line will be copied/killed without its new line.  I 
don't know whether such behaviour is customizable.
 >
 > It certainly is customizable:
 >
 > (define-key global-map [(kp-add)] '(lambda () (interactive)
 > 				     (beginning-of-line)
 > 				     (if (eobp) (error "End of buffer"))
 > 				     (let ((beg (point)))
 > 				       (forward-line 1)
 > 				       (kill-region beg (point))))); KeyPad + Key
 >
 > Kill a line, yank it back:
 >
 > C-KP+ C-y
 >
 >

I meant: I don't know whether it is customizable via Customize, as the 
original poster asked for its .emacs to be left untouched.  Thank you 
for the tip, though :-)

Re: copy-line

[Raffaele Ricciardi]

there is nothing to be customizedOn 07/25/2012 04:02 PM, Raffaele 
Ricciardi wrote:> I meant: I don't know whether it is customizable via 
Customize, as the
 > original poster asked for its .emacs to be left untouched.  Thank you
 > for the tip, though :-)

Well, no customization is needed: to copy the whole line, including the 
newline:

C-a C-SPC C-n M-w

Cheers.

Re: copy-line

[Raffaele Ricciardi]

On 07/25/2012 01:31 PM, rfflrccrd@gmail.com wrote:
> In alternative, you can kill a line and yank it back at once:
>
> C-S-Backspace C-k

Errata corrige:

C-S-Backspace C-k C-y

Re: copy-line (& default keychord)

[Andreas Röhler]

Am 05.07.2012 21:08, schrieb Enda:
> What happened to copy-line in Emacs (which would copy the line). In Vi, copying a line is yy, what is the shortest way of copying a line in Emacs (without writing a lisp function in .emacs)? Should there be a default keychord for copying a line?
>
>
> Best wishes,
>
> Enda
>

you may try

https://launchpad.net/s-x-emacs-werkstatt/trunk/1.3/+download/S-X-Emacs-Werkstatt-1.3.tar.gz

it comes with ar-line-atpt, which should do what you want.

Also it delivers some hundred related commands, reducing the need for customizations/creations somehow

Andreas

copy-line

[Helmut Eller]

Hello,

is there a command (and standard key) to copy the current line?  The
command should duplicate the text of the current line and move point to
the copied line.  I think that vi has something like that, and
occasionally it would be quite useful.

I can write that myself but maybe Emacs has something already and I
don't know it?  It's also a bit hard to find a free key :-)

Helmut.

Re: copy-line

[Plamen Tanovski]

Helmut Eller <eller.helmut@gmail.com> writes:

> is there a command (and standard key) to copy the current line?  The
> command should duplicate the text of the current line and move point to
> the copied line.  I think that vi has something like that, and
> occasionally it would be quite useful.

Look at extraedit.el. It offers get-current-line and may be of interest
line-comment-and-duplicate.

best regards

Re: copy-line

[Joe Fineman]

Helmut Eller <eller.helmut@gmail.com> writes:

> is there a command (and standard key) to copy the current line?  The
> command should duplicate the text of the current line and move point
> to the copied line.  I think that vi has something like that, and
> occasionally it would be quite useful.
>
> I can write that myself but maybe Emacs has something already and I
> don't know it?  It's also a bit hard to find a free key :-)

I have been using the following kluge extensively for a long time.  I
mainly use it in tables, but it is also useful for duplicating a line
that contains no tabs:

(defun ditto ()
  "In a table, duplicate the entry above."
  (interactive)
  (let ((track-eol) (goal-column (current-column)))
    (skip-chars-backward "^\t\n")
    (setq newplace (point-marker))
    (previous-line 1)
    (setq oldplace (point-marker))
    (skip-chars-forward "^\t\n")
    (setq entry (buffer-substring oldplace (point)))
    (goto-char newplace)
    (skip-chars-forward "^\t\n")
    (delete-region newplace (point))
    (set-mark (point))
    (insert entry)
    )
  )
-- 
---  Joe Fineman    joe_f@verizon.net

||:  It could have been worse -- it could have been me.  :||

Re: copy-line

[Samuel Wales]

(defun alpha-open-line-entire (&optional arg)
  "Open a line above.  If there is a prefix argument of just C-u,
then repeat the line.  If there are two, repeat and comment.  If
there is a natural numeric argument, repeat that many lines."
  (interactive "*P")
  (if arg
      (progn
        (repeat-line (if (consp arg) 1 (prefix-numeric-value arg)))
        ;;put a commented line in front of the line
        (when (= (car arg) 16)
          (comment-region (point-at-bol) (point-at-eol))
          ;;this misplaces point, but cannot be fixed without
          ;;knowing whether ;;; or ;; or #.
          (next-line)
          '(back-to-indentation)))
    (progn
      (beginning-of-line)
      ;;2004-01-30 open-line just went awol, acting like yank
      ;;(open-line 1)
      (newline 1)
      (forward-line -1)
      (unless (bobp)
	;;(let ((indent-line-function 'alpha-indent-to-next-indentation))
	(indent-according-to-mode)))))


On Sat, Jan 31, 2009 at 11:26, Helmut Eller <eller.helmut@gmail.com> wrote:
> Hello,
>
> is there a command (and standard key) to copy the current line?  The
> command should duplicate the text of the current line and move point to
> the copied line.  I think that vi has something like that, and
> occasionally it would be quite useful.
>
> I can write that myself but maybe Emacs has something already and I
> don't know it?  It's also a bit hard to find a free key :-)
>
> Helmut.
>



-- 
For personal and corporate gain, myalgic encephalomyelitis denialists
are knowingly causing massive suffering and 25-years-early death by
grossly corrupting science.
http://www.meactionuk.org.uk/What_Is_ME_What_Is_CFS.htm

Re: copy-line

[Andy Stewart]

Hi,

Below are my code:

------------------------------> Code start <------------------------------
(defun duplicate-line-above (&optional reverse)
  "Duplicate current line above."
  (interactive)
  (let ((origianl-column (current-column))
        line-content)
    (setq line-content (buffer-substring (line-beginning-position) (line-end-position)))
    (beginning-of-line)
    (and reverse (forward-line +1))
    (newline +1)
    (forward-line -1)
    (insert line-content)
    (goto-column origianl-column)))

(defun duplicate-line-below ()
  "Duplicate current line below"
  (interactive)
  (duplicate-line-above t))

(defun duplicate-line-above-comment (&optional reverse)
  "Duplicate current line above, and comment current line."
  (interactive)
  (if reverse
      (duplicate-line-below)
    (duplicate-line-above))
  (save-excursion
    (if reverse
        (forward-line -1)
      (forward-line +1))
    (comment-or-uncomment-region+)))

(defun duplicate-line-below-comment ()
  "Duplicate current line below, and comment current line."
  (interactive)
  (duplicate-line-above-comment t))
------------------------------> Code end   <------------------------------

You can find those code at http://www.emacswiki.org/cgi-bin/emacs/lazycat-toolkit.el

Below are my keybing for those command:

------------------------------> keybinding start <------------------------------
("C-S-o" . duplicate-line-above)
("C-S-l" . duplicate-line-below)
("C-S-s-o" . duplicate-line-above-comment)
("C-S-s-l" . duplicate-line-below-comment)
------------------------------> keybinding end   <------------------------------

Enjoy!

  -- Andy


Helmut Eller <eller.helmut@gmail.com> writes:

> Hello,
>
> is there a command (and standard key) to copy the current line?  The
> command should duplicate the text of the current line and move point to
> the copied line.  I think that vi has something like that, and
> occasionally it would be quite useful.
>
> I can write that myself but maybe Emacs has something already and I
> don't know it?  It's also a bit hard to find a free key :-)
>
> Helmut.

Re: copy-line

[Helmut Eller]

Thanks to everyone who replied.
Apparently Emacs has no standard command to do that.
I'll use the code below and bind it to C-x ,

Helmut.

(defun copy-line ()
  "Copy the current line."
  (interactive)
  (let ((col (current-column))
        (beg (progn (beginning-of-line) (point)))
        (end (progn (end-of-line) (point))))
    (forward-line)
    (save-excursion (insert (buffer-substring beg end) "\n"))
    (move-to-column col)))

Re: copy-line

[Peter Dyballa]

Am 01.02.2009 um 09:41 schrieb Helmut Eller:

> I'll use the code below and bind it to C-x ,

C-a C-k C-_ puts the line in the kill-ring, C-y spits it out,  
anywhere ...

--
Mit friedvollen Grüßen

   Pete

Be careful of reading health books, you might die of a misprint.
				– Mark Twain

Re: copy-line

[Harald Hanche-Olsen]

+ Helmut Eller <eller.helmut@gmail.com>:

> is there a command (and standard key) to copy the current line?  The
> command should duplicate the text of the current line and move point
> to the copied line.

Lots of suggestions here, but what is wrong with C-a C-k C-k C-y C-y?

> I think that vi has something like that

You mean yyp perhaps? The exact analogy of the above, but shorter.

Once upon a time, I thought it was cute to write elisp functions to
implement marginal time savings like the one you ask for. But in the
end, it turns out I am not using them enough to justify the cost of
writing them in the first place, and I even end up forgetting about
having such shortcuts when I could have used them.

Spend a little time on learning to use keyboard macros instead. They can
save a lot of time if you find yourself doing the same thing over and
over again.

-- 
* Harald Hanche-Olsen     <URL:http://www.math.ntnu.no/~hanche/>
- It is undesirable to believe a proposition
  when there is no ground whatsoever for supposing it is true.
  -- Bertrand Russell

Re: copy-line

[Helmut Eller]

* Harald Hanche-Olsen [2009-02-01 11:13+0100] writes:

> Lots of suggestions here, but what is wrong with C-a C-k C-k C-y C-y?

Well, I did C-a <down> C-<spc> C-w C-y C-y before and I often get it
wrong so that it insert 2 lines (often an empty one) and I have to edit
that again.

> Spend a little time on learning to use keyboard macros instead. They can
> save a lot of time if you find yourself doing the same thing over and
> over again.

Are you saving your macros to a file?  I never do that.  Simply because
editing Lisp code is much easier for me than editing keyboard macros.

Helmut.

Re: copy-line

[Harald Hanche-Olsen]

+ Helmut Eller <eller.helmut@gmail.com>:

> * Harald Hanche-Olsen [2009-02-01 11:13+0100] writes:
>
>> Spend a little time on learning to use keyboard macros instead. They can
>> save a lot of time if you find yourself doing the same thing over and
>> over again.
>
> Are you saving your macros to a file?  I never do that.

No. I create them when needed, then forget them.

> Simply because editing Lisp code is much easier for me than editing
> keyboard macros.

Sure. I don't bother with editing keyboard macros either. If I make a
mistake while recording one, I make it over again from scratch. And I am
not saying you shouldn't write elisp code, nor that I don't do it
myself. But in my experience, it is often a wasted effort when dealing
with relatively simple repetitive tasks. It all depends on how often the
task crops up, and how hard it is to get it right.

-- 
* Harald Hanche-Olsen     <URL:http://www.math.ntnu.no/~hanche/>
- It is undesirable to believe a proposition
  when there is no ground whatsoever for supposing it is true.
  -- Bertrand Russell