bug#62696: python.el: Extra indentation for conditionals

[kobarity <kobarity@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 3323 bytes --]


Gustaf Waldemarson wrote:
> One noticeable caveat is that **any** parenthesis can now be additionally
> indented, e.g., the follow is now also possible:
> 
>     this_is_a_tuple = (long_variable_name_here,
>                                       also_a_long_variable_name)
> 
> Although, given that this can be cycled at will by the user, I'm not sure if it
> is a bad additional feature or not.
> 
> Ideally, I suppose that `python-indent-context` could be modified to add a
> `:inside-cond-paren` symbol that signals that the parenthesis is for a
> conditional expression and thus the extra indentation should be applied, and not
> in any other case. That does seem a bit harder for me to fix at a cursory glance
> however, so maybe this fix is enough?

Hi Gustaf,

I agree with you in that it's better to have a new indent context, and
I tried to implement it.

At first, I thought that it would be enough to add a counterpart of
the user option `python-indent-def-block-scale' and corresponding
`:inside-paren-newline-start-from-block' context.
`python-indent-def-block-scale' can be used to customize the following
code

#+begin_src python
if (
        "VALUE" in my_unnecessarily_long_dictionary
        and some_other_long_condition_case
        ):
    do_something()
#+end_src

to be indented as follows (with a TAB at "):" line):

#+begin_src python
if (
    "VALUE" in my_unnecessarily_long_dictionary
    and some_other_long_condition_case
):
    do_something()
#+end_src

This is the style used by the popular formatter "black".

From the name `python-indent-def-block-scale' and its docstring, it is
easy to assume that it only works for def block, but in fact it works
for every blocks.  As `python-indent-def-block-scale' works only when
there is no item on the same line following the opening paren, I tried
to add a similar user option and an indent context for the opening
paren followed by some items on the same line.  It could indent as
follows:

#+begin_src python
if ("VALUE" in my_unnecessarily_long_dictionary
        and some_other_long_condition_case):
    do_something()
#+end_src

However, it could not handle correctly the following example:

#+begin_src python
elif (some_case or
          another_case):
    do_another()
#+end_src

The extra indentation is not needed here.

So I think it is best to increase the indentation only if the
calculated indentation equals to the indentation of the contents of
the block ("do_something()" in the above example).  This is similar to
the way I fixed Bug#57262.

Unlike Bug#57262, the current indentation shown below is not a
violation of the latest PEP8:

#+begin_src python
if ("VALUE" in my_unnecessarily_long_dictionary
    and some_other_long_condition_case):
    do_something()
#+end_src

Although pycodestyle reports E129 "visually indented line with same
indent as next logical line," PEP8 was changed to allow this.  This is
explained in the following issue, for example:
https://github.com/PyCQA/pycodestyle/issues/474

So changing this indentation should be a user option.  Attached is my
implementation of this.  The user option
`python-indent-block-paren-deeper' is added to customize this
indentation.  I would be glad if you could try it.

[-- Attachment #2: 0001-Add-a-new-user-option-in-Python-mode-to-improve-the-.patch --]
[-- Type: application/octet-stream, Size: 11074 bytes --]

From acec03331413b621843fb1489e9aeb6db927614a Mon Sep 17 00:00:00 2001
From: kobarity <kobarity@gmail.com>
Date: Sun, 9 Apr 2023 20:48:00 +0900
Subject: [PATCH] Add a new user option in Python mode to improve the
 indentation

* lisp/progmodes/python.el (python-indent-block-paren-deeper): New
user option.
(python-indent-context): Add a new context :inside-paren-from-block.
(python-indent--calculate-indentation): Modify according to
`python-indent-block-paren-deeper' and :inside-paren-from-block.
* test/lisp/progmodes/python-tests.el
(python-indent-inside-paren-block-1)
(python-indent-inside-paren-block-2)
(python-indent-inside-paren-block-3)
(python-indent-inside-paren-block-4): New tests.
(python-indent-inside-paren-5, python-indent-dedenters-8): Modify
according to the new context.
* etc/NEWS: Document the new user option.  (Bug#62696)
---
 etc/NEWS                            |   8 ++
 lisp/progmodes/python.el            |  43 +++++++++--
 test/lisp/progmodes/python-tests.el | 116 +++++++++++++++++++++++++++-
 3 files changed, 158 insertions(+), 9 deletions(-)

diff --git a/etc/NEWS b/etc/NEWS
index d20d9f65ac9..61736e8edf4 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -261,6 +261,14 @@ When non-nil, it will automatically register every package as a
 project, that you can quickly select using 'project-switch-project'
 ('C-x p p').
 
+** Python mode
+
+*** New user option 'python-indent-block-paren-deeper'.
+If this variable is set to non-nil, and some items follow the opening
+paren on the same line in a block statement, and the calculated
+indentation of a line inside the parens equals to the indentation of
+the block contents, the indentation level of the line is increased.
+
 \f
 * New Modes and Packages in Emacs 30.1
 
diff --git a/lisp/progmodes/python.el b/lisp/progmodes/python.el
index bbabce80b4d..dbc48038554 100644
--- a/lisp/progmodes/python.el
+++ b/lisp/progmodes/python.el
@@ -1270,6 +1270,17 @@ python-indent-def-block-scale
   :type 'integer
   :safe 'natnump)
 
+(defcustom python-indent-block-paren-deeper nil
+  "Non-nil means to increase indentation inside parens of a block.
+If this variable is set to non-nil, and some items follow the
+opening paren on the same line in a block statement, and the
+calculated indentation of a line inside the parens equals to the
+indentation of the block contents, the indentation level of the
+line is increased."
+  :version "30.1"
+  :type 'boolean
+  :safe 'booleanp)
+
 (defvar python-indent-current-level 0
   "Deprecated var available for compatibility.")
 
@@ -1367,6 +1378,10 @@ python-indent-context
  - Point is inside a paren with items starting in their own line
    from a block start.
  - START is the position of the open paren.
+:inside-paren-from-block
+ - Point is inside a paren from a block start followed by some
+   items on the same line.
+ - START is the first non space char position *after* the open paren.
 
 :after-backslash
  - Fallback case when point is after backslash.
@@ -1450,12 +1465,16 @@ python-indent-context
              (starts-in-newline
               (cons :inside-paren-newline-start start))
              ;; General case.
-             (t (cons :inside-paren
-                      (save-excursion
-                        (goto-char (1+ start))
-                        (skip-syntax-forward "(" 1)
-                        (skip-syntax-forward " ")
-                        (point))))))))
+             (t (let ((after-start (save-excursion
+                               (goto-char (1+ start))
+                               (skip-syntax-forward "(" 1)
+                               (skip-syntax-forward " ")
+                               (point))))
+                  (if (save-excursion
+                        (python-nav-beginning-of-statement)
+                        (python-info-looking-at-beginning-of-block))
+                      (cons :inside-paren-from-block after-start)
+                    (cons :inside-paren after-start))))))))
        ;; After backslash.
        ((let ((start (when (not (python-syntax-comment-or-string-p ppss))
                        (python-info-line-ends-backslash-p
@@ -1603,7 +1622,17 @@ python-indent--calculate-indentation
         (`(,(or :inside-paren-newline-start-from-block) . ,start)
          (goto-char start)
          (+ (current-indentation)
-            (* python-indent-offset python-indent-def-block-scale))))))
+            (* python-indent-offset python-indent-def-block-scale)))
+        (`(,:inside-paren-from-block . ,start)
+         (goto-char start)
+         (let ((column (current-column)))
+           (if (and python-indent-block-paren-deeper
+                    (= column (+ (save-excursion
+                                   (python-nav-beginning-of-statement)
+                                   (current-indentation))
+                                 python-indent-offset)))
+               (+ column python-indent-offset)
+             column))))))
 
 (defun python-indent--calculate-levels (indentation)
   "Calculate levels list given INDENTATION.
diff --git a/test/lisp/progmodes/python-tests.el b/test/lisp/progmodes/python-tests.el
index 50153e66da5..60b11d572cf 100644
--- a/test/lisp/progmodes/python-tests.el
+++ b/test/lisp/progmodes/python-tests.el
@@ -1139,7 +1139,7 @@ python-indent-inside-paren-5
    (should (eq (car (python-indent-context)) :no-indent))
    (should (= (python-indent-calculate-indentation) 0))
    (forward-line 1)
-   (should (eq (car (python-indent-context)) :inside-paren))
+   (should (eq (car (python-indent-context)) :inside-paren-from-block))
    (should (= (python-indent-calculate-indentation) 7))
    (forward-line 1)
    (should (eq (car (python-indent-context)) :after-block-start))
@@ -1174,6 +1174,118 @@ python-indent-inside-paren-7
    ;; This signals an error if the test fails
    (should (eq (car (python-indent-context)) :inside-paren-newline-start))))
 
+(ert-deftest python-indent-inside-paren-block-1 ()
+  "`python-indent-block-paren-deeper' set to nil (default).
+See Bug#62696."
+  (python-tests-with-temp-buffer
+   "
+if ('VALUE' in my_unnecessarily_long_dictionary and
+    some_other_long_condition_case):
+    do_something()
+elif (some_case or
+      another_case):
+    do_another()
+"
+   (python-tests-look-at "if")
+   (should (eq (car (python-indent-context)) :no-indent))
+   (should (= (python-indent-calculate-indentation) 0))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :inside-paren-from-block))
+   (should (= (python-indent-calculate-indentation) 4))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :after-block-start))
+   (should (= (python-indent-calculate-indentation) 4))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :at-dedenter-block-start))
+   (should (= (python-indent-calculate-indentation) 0))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :inside-paren-from-block))
+   (should (= (python-indent-calculate-indentation) 6))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :after-block-start))
+   (should (= (python-indent-calculate-indentation) 4))))
+
+(ert-deftest python-indent-inside-paren-block-2 ()
+  "`python-indent-block-paren-deeper' set to t.
+See Bug#62696."
+  (python-tests-with-temp-buffer
+   "
+if ('VALUE' in my_unnecessarily_long_dictionary and
+        some_other_long_condition_case):
+    do_something()
+elif (some_case or
+      another_case):
+    do_another()
+"
+   (let ((python-indent-block-paren-deeper t))
+     (python-tests-look-at "if")
+     (should (eq (car (python-indent-context)) :no-indent))
+     (should (= (python-indent-calculate-indentation) 0))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :inside-paren-from-block))
+     (should (= (python-indent-calculate-indentation) 8))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :after-block-start))
+     (should (= (python-indent-calculate-indentation) 4))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :at-dedenter-block-start))
+     (should (= (python-indent-calculate-indentation) 0))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :inside-paren-from-block))
+     (should (= (python-indent-calculate-indentation) 6))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :after-block-start))
+     (should (= (python-indent-calculate-indentation) 4)))))
+
+(ert-deftest python-indent-inside-paren-block-3 ()
+  "With backslash.  `python-indent-block-paren-deeper' set to nil (default).
+See Bug#62696."
+  (python-tests-with-temp-buffer
+   "
+if 'VALUE' in my_uncessarily_long_dictionary and\\
+   (some_other_long_condition_case or
+    another_case):
+    do_something()
+"
+   (python-tests-look-at "if")
+   (should (eq (car (python-indent-context)) :no-indent))
+   (should (= (python-indent-calculate-indentation) 0))
+   (forward-line 1)
+   (should (eq (car (python-indent-context))
+               :after-backslash-block-continuation))
+   (should (= (python-indent-calculate-indentation) 3))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :inside-paren-from-block))
+   (should (= (python-indent-calculate-indentation) 4))
+   (forward-line 1)
+   (should (eq (car (python-indent-context)) :after-block-start))
+   (should (= (python-indent-calculate-indentation) 4))))
+
+(ert-deftest python-indent-inside-paren-block-4 ()
+  "With backslash.  `python-indent-block-paren-deeper' set to t.
+See Bug#62696."
+  (python-tests-with-temp-buffer
+   "
+if 'VALUE' in my_uncessarily_long_dictionary and\\
+   (some_other_long_condition_case or
+        another_case):
+    do_something()
+"
+   (let ((python-indent-block-paren-deeper t))
+     (python-tests-look-at "if")
+     (should (eq (car (python-indent-context)) :no-indent))
+     (should (= (python-indent-calculate-indentation) 0))
+     (forward-line 1)
+     (should (eq (car (python-indent-context))
+                 :after-backslash-block-continuation))
+     (should (= (python-indent-calculate-indentation) 3))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :inside-paren-from-block))
+     (should (= (python-indent-calculate-indentation) 8))
+     (forward-line 1)
+     (should (eq (car (python-indent-context)) :after-block-start))
+     (should (= (python-indent-calculate-indentation) 4)))))
+
 (ert-deftest python-indent-after-block-1 ()
   "The most simple after-block case that shouldn't fail."
   (python-tests-with-temp-buffer
@@ -1670,7 +1782,7 @@ python-indent-dedenters-8
    (should (= (python-indent-calculate-indentation) 0))
    (should (= (python-indent-calculate-indentation t) 0))
    (python-tests-look-at "a == 4):\n")
-   (should (eq (car (python-indent-context)) :inside-paren))
+   (should (eq (car (python-indent-context)) :inside-paren-from-block))
    (should (= (python-indent-calculate-indentation) 6))
    (python-indent-line)
    (should (= (python-indent-calculate-indentation t) 4))
-- 
2.34.1