Re: minibuffer-eldef

[Miles Bader <miles@lsi.nec.co.jp>]

[-- Attachment #1: Type: text/plain, Size: 1373 bytes --]

storm@cua.dk (Kim F. Storm) writes:
> Couldn't minibuffer-electric-default-mode automatically
> change (default X) to [X] ?

Hmmm, clever!

Try the attached patch, and then eval the following function and do:

   (setq minibuf-eldef-frob-function 'minibuf-eldef-squirk-default)

   (defun minibuf-eldef-squirk-default (overlay state)
     (cond (state
            (unless (overlay-get overlay 'replacement)
              (let ((string 
                     (buffer-substring (overlay-start overlay)
                                       (overlay-end overlay))))
                (setq string 
                      (replace-regexp-in-string " *(default `?\\(.*\\)'?)"
                                                " [\\1]"
                                                string))
                (overlay-put overlay 'replacement string)))
            (overlay-put overlay 'display (overlay-get overlay 'replacement)))
           (t
            (overlay-put overlay 'invisible t)
            (overlay-put overlay 'intangible t)
            (overlay-put overlay 'display nil))))


The only (slight) problem is that it uses a `display' property, which
can be annoying if you want to manually copy the value of the default
or something.  It could probably do something more clever like only
overlaying the bracketting portions of the default or something.

-Miles


Patch:


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: +minibuf-default-frob.patch --]
[-- Type: text/x-patch, Size: 1676 bytes --]

--- orig/lisp/minibuf-eldef.el
+++ mod/lisp/minibuf-eldef.el
@@ -1,6 +1,6 @@
 ;;; minibuf-eldef.el --- Only show defaults in prompts when applicable
 ;;
-;; Copyright (C) 2000, 2001 Free Software Foundation, Inc.
+;; Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
 ;;
 ;; Author: Miles Bader <miles@gnu.org>
 ;; Keywords: convenience
@@ -46,6 +46,8 @@
 matching the default part of the prompt, and who's cdr indicates the
 regexp subexpression that matched.")
 
+(defvar minibuf-eldef-frob-function nil)
+
 \f
 ;;; Internal variables
 
@@ -103,7 +105,11 @@
 	    (minibuffer-contents-no-properties))
       (setq minibuf-eldef-initial-buffer-length (point-max))
       (add-to-list 'minibuf-eldef-frobbed-minibufs (current-buffer))
-      (add-hook 'post-command-hook #'minibuf-eldef-update-minibuffer nil t))))
+      (add-hook 'post-command-hook #'minibuf-eldef-update-minibuffer nil t)
+      (when minibuf-eldef-frob-function
+	(funcall minibuf-eldef-frob-function
+		 minibuf-eldef-overlay
+		 minibuf-eldef-showing-default-in-prompt)))))
 
 ;; post-command-hook to swap prompts when necessary
 (defun minibuf-eldef-update-minibuffer ()
@@ -118,7 +124,11 @@
     ;; swap state
     (setq minibuf-eldef-showing-default-in-prompt
 	  (not minibuf-eldef-showing-default-in-prompt))
-    (cond (minibuf-eldef-showing-default-in-prompt
+    (cond (minibuf-eldef-frob-function
+	   (funcall minibuf-eldef-frob-function
+		    minibuf-eldef-overlay
+		    minibuf-eldef-showing-default-in-prompt))
+	  (minibuf-eldef-showing-default-in-prompt
 	   (overlay-put minibuf-eldef-overlay 'invisible nil)
 	   (overlay-put minibuf-eldef-overlay 'intangible nil))
 	  (t

[-- Attachment #3: Type: text/plain, Size: 80 bytes --]

-- 
.Numeric stability is probably not all that important when you're guessing.

[-- Attachment #4: Type: text/plain, Size: 142 bytes --]

_______________________________________________
Emacs-devel mailing list
Emacs-devel@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-devel