How to define a `multiple prompt' function?

How to define a `multiple prompt' function?

[Rodolfo Medina]

I wish to define a function that prompts me more than once: let's call it
`my-function': when I type `M-x my-function', in the echo area I see (just an
example):

 Hi, how are you today?

.  Then I type, e.g., `fine RET', and again it prompts me with:

 I see.  And, what did you do yesterday?

... and so on.  Then I'm going to put some `if... else' conditions over my
possible answers.  Can anybody please provide some hints about how to elisp
this?

Thanks for any help
Rodolfo

Re: How to define a `multiple prompt' function?

[Barry Margolin]

In article <87ej42m64o.fsf@gmail.com>,
 Rodolfo Medina <rodolfo.medina@gmail.com> wrote:

> I wish to define a function that prompts me more than once: let's call it
> `my-function': when I type `M-x my-function', in the echo area I see (just an
> example):
> 
>  Hi, how are you today?
> 
> .  Then I type, e.g., `fine RET', and again it prompts me with:
> 
>  I see.  And, what did you do yesterday?
> 
> ... and so on.  Then I'm going to put some `if... else' conditions over my
> possible answers.  Can anybody please provide some hints about how to elisp
> this?
> 
> Thanks for any help
> Rodolfo


(defun my-function ()
  (interactive)
  (let* ((response (read-from-minibuffer "Hi, how are you today? "))
         (new-prompt (format "I see, you're %s?  And where did you go 
yesterday?" response))
         (response2 (read-from-minibuffer new-prompt)))
    (message "I hope you enjoyed %s" response2)))

-- 
Barry Margolin, barmar@alum.mit.edu
Arlington, MA
*** PLEASE post questions in newsgroups, not directly to me ***
*** PLEASE don't copy me on replies, I'll read them in the group ***

Re: How to define a `multiple prompt' function?

[Evans Winner]

Rodolfo Medina <rodolfo.medina@gmail.com> writes:

    I wish to define a function that prompts me more than
    once: let's call it `my-function': when I type `M-x
    my-function', in the echo area I see (just an example):

     Hi, how are you today?
 
    .  Then I type, e.g., `fine RET', and again it prompts me with:
 
     I see.  And, what did you do yesterday?
 
    ... and so on.  Then I'm going to put some `if... else'
    conditions over my possible answers.  Can anybody please
    provide some hints about how to elisp this?

'read-from-minibuffer might be what you want.


(format "Your name is: %s"
	(read-from-minibuffer "Who are you? "))

Re: ps-print variables interactive setting

[Lennart Borgman (gmail)]

Rodolfo Medina wrote:
> (defun my-manage-ps-font-size ()
>   (interactive)
>   (let* ((prompt1 (read-from-minibuffer "Font size? "))
> 	 (prompt2 (format "(quote (7 . %s))" prompt1))
> 	 )
>   (setq ps-font-size prompt2)
>     )
> )
> 
> 
> , but it seems that the variable's value is put between "" and so it is not
> accepted.  I need help in this point.  Thanks to anyone still helping.


Maybe like this

(defun my-manage-ps-font-size ()
  (interactive)
  (let ((font-size (read-number "Font size? ")))
    (setq ps-font-size (cons 7 font-size))))

ps-print variables interactive setting (was: How to define a `multiple prompt' function?)

[Rodolfo Medina]

Rodolfo Medina <rodolfo.medina@gmail.com> wrote:

>> I wish to define a function that prompts me more than once: let's call it
>> `my-function': when I type `M-x my-function', in the echo area I see (just an
>> example):
>> 
>>  Hi, how are you today?
>> 
>> .  Then I type, e.g., `fine RET', and again it prompts me with:
>> 
>>  I see.  And, what did you do yesterday?
>> 
>> ... and so on.  Then I'm going to put some `if... else' conditions over my
>> possible answers.  Can anybody please provide some hints about how to elisp
>> this?



Barry Margolin <barmar@alum.mit.edu> writes:

> (defun my-function ()
>   (interactive)
>   (let* ((response (read-from-minibuffer "Hi, how are you today? "))
>          (new-prompt (format "I see, you're %s?  And where did you go 
> yesterday?" response))
>          (response2 (read-from-minibuffer new-prompt)))
>     (message "I hope you enjoyed %s" response2)))


Thanks, that works.
I wish to set some ps-print variables in an interactive way, i.e. be prompted
for the value that I want to set.  So, following Barry's hint, I put:


(defun my-manage-ps-font-size ()
  (interactive)
  (let* ((prompt1 (read-from-minibuffer "Font size? "))
	 (prompt2 (format "(quote (7 . %s))" prompt1))
	 )
  (setq ps-font-size prompt2)
    )
)


, but it seems that the variable's value is put between "" and so it is not
accepted.  I need help in this point.  Thanks to anyone still helping.

Rodolfo

Re: ps-print variables interactive setting

[Andreas Politz]

Rodolfo Medina wrote:
> Rodolfo Medina <rodolfo.medina@gmail.com> wrote:
> 
>>> I wish to define a function that prompts me more than once: let's call it
>>> `my-function': when I type `M-x my-function', in the echo area I see (just an
>>> example):
>>>
>>>  Hi, how are you today?
>>>
>>> .  Then I type, e.g., `fine RET', and again it prompts me with:
>>>
>>>  I see.  And, what did you do yesterday?
>>>
>>> ... and so on.  Then I'm going to put some `if... else' conditions over my
>>> possible answers.  Can anybody please provide some hints about how to elisp
>>> this?
> 
> 
> 
> Barry Margolin <barmar@alum.mit.edu> writes:
> 
>> (defun my-function ()
>>   (interactive)
>>   (let* ((response (read-from-minibuffer "Hi, how are you today? "))
>>          (new-prompt (format "I see, you're %s?  And where did you go 
>> yesterday?" response))
>>          (response2 (read-from-minibuffer new-prompt)))
>>     (message "I hope you enjoyed %s" response2)))
> 
> 
> Thanks, that works.
> I wish to set some ps-print variables in an interactive way, i.e. be prompted
> for the value that I want to set.  So, following Barry's hint, I put:
> 
> 
> (defun my-manage-ps-font-size ()
>   (interactive)
>   (let* ((prompt1 (read-from-minibuffer "Font size? "))
> 	 (prompt2 (format "(quote (7 . %s))" prompt1))
> 	 )
>   (setq ps-font-size prompt2)
>     )
> )
> 
> 
> , but it seems that the variable's value is put between "" and so it is not
> accepted.  I need help in this point.  Thanks to anyone still helping.
> 
> Rodolfo


Take a look at the documentation of the interactive call, it let's you
read any kind of data from the minibuffer.

(defun my-manage-ps-font-size(size string)
   (interactive "nFont size ? \nsErase all memory ? ")
   (setq ps-font-size (cons 7 size)))

This reads a number and a string.

-ap

`are-you-fine' function definition (was: ps-print variables interactive setting)

[Rodolfo Medina]

Rodolfo Medina wrote:

>>>> I wish to define a function that prompts me more than once
>>>>
>>>> [...]
>>>>
>>>> Then I'm going to put some `if... else' conditions over my
>>>> possible answers.  Can anybody please provide some hints about how to
>>>> elisp this?



Barry Margolin <barmar@alum.mit.edu> writes:

>>> (defun my-function ()
>>>   (interactive)
>>>   (let* ((response (read-from-minibuffer "Hi, how are you today? "))
>>>          (new-prompt (format "I see, you're %s?  And where did you go
>>> yesterday?" response))
>>>          (response2 (read-from-minibuffer new-prompt)))
>>>     (message "I hope you enjoyed %s" response2)))



"Lennart Borgman (gmail)" <lennart.borgman@gmail.com> writes:

> Maybe like this
>
> (defun my-manage-ps-font-size ()
>   (interactive)
>   (let ((font-size (read-number "Font size? ")))
>     (setq ps-font-size (cons 7 font-size))))



Andreas Politz <politza@fh-trier.de> writes:

> Take a look at the documentation of the interactive call, it let's you
> read any kind of data from the minibuffer.
>
> (defun my-manage-ps-font-size(size string)
>   (interactive "nFont size ? \nsErase all memory ? ")
>   (setq ps-font-size (cons 7 size)))
>
> This reads a number and a string.



Thanks very much to all who helped.  With their help I'm building a
`my-ps-print-buffer' function, that I'll report so that it may be useful to
others: now I need something like this: the function says:

 Are you fine today?

.  If I say `y', it says: `Oh, good.'; otherwise it says: `Why don't you see a
doctor?'

I tried a lot but don't manage by myself.

Please help in this regard

Thanks again
Rodolfo

ps-right-footer interactive setting (was: ps-print variables interactive setting)

[Rodolfo Medina]

Rodolfo Medina <rodolfo.medina@gmail.com> writes:

> I wish to set some ps-print variables in an interactive way, i.e. be
> prompted for the value that I want to set.



Now I'm working on the ps-right-footer variable.  I wish to be prompted for a
page number so that the variable is set to:

 (list <page number>)

.  I did:

(defun my-ps-right-footer ()
  (interactive)
  (let ((my-page-number (read-number "page number? ")))
    (setq ps-print-footer t)
    (setq ps-right-footer (list 'my-page-number))
    )
  )

, but it doesn't work.  Any suggestion?

Thanks
Rodolfo

Re: ps-right-footer interactive setting (was: ps-print variables interactive setting)

[Barry Margolin]

In article <87aben37np.fsf@gmail.com>,
 Rodolfo Medina <rodolfo.medina@gmail.com> wrote:

> Rodolfo Medina <rodolfo.medina@gmail.com> writes:
> 
> > I wish to set some ps-print variables in an interactive way, i.e. be
> > prompted for the value that I want to set.
> 
> 
> 
> Now I'm working on the ps-right-footer variable.  I wish to be prompted for a
> page number so that the variable is set to:
> 
>  (list <page number>)
> 
> .  I did:
> 
> (defun my-ps-right-footer ()
>   (interactive)
>   (let ((my-page-number (read-number "page number? ")))
>     (setq ps-print-footer t)
>     (setq ps-right-footer (list 'my-page-number))
>     )
>   )
> 
> , but it doesn't work.  Any suggestion?
> 
> Thanks
> Rodolfo

It should be (list my-page number).  Quoting prevents the variable from 
being evaluated.

-- 
Barry Margolin, barmar@alum.mit.edu
Arlington, MA
*** PLEASE post questions in newsgroups, not directly to me ***
*** PLEASE don't copy me on replies, I'll read them in the group ***

Re: `are-you-fine' function definition

[Kevin Rodgers]

Rodolfo Medina wrote:
> Thanks very much to all who helped.  With their help I'm building a
> `my-ps-print-buffer' function, that I'll report so that it may be useful to
> others: now I need something like this: the function says:
> 
>  Are you fine today?
> 
> .  If I say `y', it says: `Oh, good.'; otherwise it says: `Why don't you see a
> doctor?'

(if (equal (read-string "Are you fine today? ") "y")
     (message "Oh, good.")
   (message "Why don't you see a doctor?"))

You might want to change the (equal ...) test to one of these:

(y-or-n-p "Are you fine today? ")

(yes-or-no-p "Are you fine today? ")

(let ((case-fold-search t))
   (string-match "\\`y\\(es\\)?\\'" (read-string "Are you fine today? ")))

-- 
Kevin Rodgers
Denver, Colorado, USA

Re: ps-right-footer interactive setting

[Rodolfo Medina]

Rodolfo Medina <rodolfo.medina@gmail.com> wrote:

>> Now I'm working on the ps-right-footer variable.  I wish to be prompted for
>> a page number so that the variable is set to:
>> 
>>  (list <page number>)
>> 
>> .  I did:
>> 
>> (defun my-ps-right-footer ()
>>   (interactive)
>>   (let ((my-page-number (read-number "page number? ")))
>>     (setq ps-print-footer t)
>>     (setq ps-right-footer (list 'my-page-number))
>>     )
>>   )
>> 
>> , but it doesn't work.  Any suggestion?



Barry Margolin <barmar@alum.mit.edu> writes:

> It should be (list my-page number).  Quoting prevents the variable from 
> being evaluated.



Unfortunately it doesn't work either:

(defun my-ps-right-footer ()
  (interactive)
  (let ((my-page-number (read-number "page number? ")))
    (setq ps-print-footer t)
    (setq ps-right-footer (list my-page-number))
    )
  )

produces a ps print error.  I can't find a solution.  Thanks for furhter
suggestions.
Rodolfo

Re: ps-right-footer interactive setting

[Chetan]

Rodolfo Medina <rodolfo.medina@gmail.com> writes:

> Rodolfo Medina <rodolfo.medina@gmail.com> wrote:
>
>>> Now I'm working on the ps-right-footer variable.  I wish to be prompted for
>>> a page number so that the variable is set to:
>>> 
>>>  (list <page number>)
>>> 
>>> .  I did:
>>> 
>>> (defun my-ps-right-footer ()
>>>   (interactive)
>>>   (let ((my-page-number (read-number "page number? ")))
>>>     (setq ps-print-footer t)
>>>     (setq ps-right-footer (list 'my-page-number))
>>>     )
>>>   )
>>> 
>>> , but it doesn't work.  Any suggestion?
>
>
>
> Barry Margolin <barmar@alum.mit.edu> writes:
>
>> It should be (list my-page number).  Quoting prevents the variable from 
>> being evaluated.
>
>
>
> Unfortunately it doesn't work either:
>
> (defun my-ps-right-footer ()
>   (interactive)
>   (let ((my-page-number (read-number "page number? ")))
>     (setq ps-print-footer t)
>     (setq ps-right-footer (list my-page-number))
>     )
>   )
>
> produces a ps print error.  I can't find a solution.  Thanks for furhter
> suggestions.
> Rodolfo
It is a postscript string...
(list (concat "(" (number-to-string my-page-number) ")"))

Re: `are-you-fine' function definition

[Rodolfo Medina]

Rodolfo Medina wrote:

>> now I need something like this: the function says:
>>
>>  Are you fine today?
>>
>> .  If I say `y', it says: `Oh, good.'; otherwise it says: `Why don't you
>> see a doctor?'



Kevin Rodgers <kevin.d.rodgers@gmail.com> writes:

> (if (equal (read-string "Are you fine today? ") "y")
>     (message "Oh, good.")
>   (message "Why don't you see a doctor?"))
>
> You might want to change the (equal ...) test to one of these:
>
> (y-or-n-p "Are you fine today? ")
>
> (yes-or-no-p "Are you fine today? ")
>
> (let ((case-fold-search t))
>   (string-match "\\`y\\(es\\)?\\'" (read-string "Are you fine today? ")))


Thanks, the `y-or-n-p' function is perfect for what I was looking for.  But
now I wish to have something like `y-or-n-p' that asks me if I want right or
left ps footer, like this:

 Right or left? (r/l)

.  If I could access the `y-or-n-p' defun, then I could try to adapt it to an
`r-or-l-p' version, but can't find it anywhere.  Please any suggestion?

Thanks
Rodolfo

Re: ps-right-footer interactive setting

[Rodolfo Medina]

Rodolfo Medina <rodolfo.medina@gmail.com> writes:

>>>> Now I'm working on the ps-right-footer variable.  I wish to be prompted
>>>> for a page number so that the variable is set to:
>>>> 
>>>>  (list <page number>)
>>>> 
>>>> .  I did:
>>>> 
>>>> (defun my-ps-right-footer ()
>>>>   (interactive)
>>>>   (let ((my-page-number (read-number "page number? ")))
>>>>     (setq ps-print-footer t)
>>>>     (setq ps-right-footer (list 'my-page-number))
>>>>     )
>>>>   )
>>>> 
>>>> , but it doesn't work.  Any suggestion?



Barry Margolin <barmar@alum.mit.edu> writes:

>>> It should be (list my-page number).  Quoting prevents the variable from 
>>> being evaluated.



Rodolfo:

>> Unfortunately it doesn't work either:
>>
>> (defun my-ps-right-footer ()
>>   (interactive)
>>   (let ((my-page-number (read-number "page number? ")))
>>     (setq ps-print-footer t)
>>     (setq ps-right-footer (list my-page-number))
>>     )
>>   )
>>
>> produces a ps print error.  I can't find a solution.  Thanks for furhter
>> suggestions.




Chetan <Chet.xspam@xspam.sbcglobal.net> writes:

> It is a postscript string...
> (list (concat "(" (number-to-string my-page-number) ")"))



Thanks, this worked!
Rodolfo

`y-or-n-p' function definition (was: `are-you-fine' function definition)

[Rodolfo Medina]

Rodolfo Medina wrote:

>> now I need something like this: the function says:
>>
>>  Are you fine today?
>>
>> .  If I say `y', it says: `Oh, good.'; otherwise it says: `Why don't you
>> see a doctor?'



Kevin Rodgers <kevin.d.rodgers@gmail.com> writes:

> (if (equal (read-string "Are you fine today? ") "y")
>     (message "Oh, good.")
>   (message "Why don't you see a doctor?"))
>
> You might want to change the (equal ...) test to one of these:
>
> (y-or-n-p "Are you fine today? ")
>
> (yes-or-no-p "Are you fine today? ")
>
> (let ((case-fold-search t))
>   (string-match "\\`y\\(es\\)?\\'" (read-string "Are you fine today? ")))


Thanks, the `y-or-n-p' function is perfect for what I was looking for.  But
now I wish to have something like `y-or-n-p' that asks me if I want right or
left ps footer, like this:

 Right or left? (r/l)

.  If I could access the `y-or-n-p' defun, then I could try to adapt it to an
`r-or-l-p' version, but can't find it anywhere.  Please any suggestion?

Thanks
Rodolfo

A `my-ps-print-setting' function (was: ps-print variables interactive setting)

[Rodolfo Medina]

Rodolfo Medina <rodolfo.medina@gmail.com> writes:

> [...] I wish to set some ps-print variables in an interactive way, i.e. be
> prompted for the value that I want to set.



With the help that came from this list, I defined a `my-ps-print-setting'
function, that I'm reporting below.  Improvements are welcome: in particular
I wish it said: "please answer `r' or `l'" when prompting for a right or left
footer and the answer is neither r nor l.  Besides, I wish to have
automatically odd page numbers in the right footer and even page numbers in
the left footer.  But I'm starting a new thread for that.

bye
Rodolfo



(defun my-ps-print-setting ()
  "Prompts for some ps print settings.
Other settings are inside the function definition
and can be changed at pleasure."
  (interactive)
  (if (equal (y-or-n-p "Do you want footer? ") t)
      (let (key val)
	(while (progn
		 (setq key
		       (let ((cursor-in-echo-area t))
			 (read-char
			  (format "right or left? "))))
		 (not (memq key '(?r ?l)))))
	(if (eq key ?r)
	    (if (equal (y-or-n-p "So, you want right footer.  \
Do you want the default footer? ") nil)
		(let ((my-page-number (read-string 
				       "Enter the footer you want: ")))
		  (setq ps-right-footer (list (concat "(" my-page-number ")"))
			ps-print-footer t
			ps-print-footer-frame nil
			ps-top-margin 20
			ps-bottom-margin 5
			ps-left-margin 10
			ps-right-margin 7
			ps-print-header nil
			ps-show-n-of-n nil
			ps-print-footer-frame nil
			ps-footer-lines 1
			ps-left-footer (quote ( ))
			ps-footer-offset -10))
	      (setq ps-right-footer (quote ("/pagenumberstring load"))
		    ps-print-footer t
		    ps-print-footer-frame nil
		    ps-top-margin 20
		    ps-bottom-margin 5
		    ps-left-margin 10
		    ps-right-margin 7
		    ps-print-header nil
		    ps-show-n-of-n nil
		    ps-print-footer-frame nil
		    ps-footer-lines 1
		    ps-left-footer (quote ( ))
		    ps-footer-offset -10))
	  (if (equal (y-or-n-p "So, you want left footer.  \
Do you want the default footer? ") nil)
	      (let ((my-page-number (read-string 
				     "Enter the footer you want: ")))
		(setq ps-left-footer (list (concat "(" my-page-number ")"))
		      ps-print-footer t
		      ps-print-footer-frame nil
		      ps-top-margin 20
		      ps-bottom-margin 5
		      ps-left-margin 10
		      ps-right-margin 7
		      ps-print-header nil
		      ps-show-n-of-n nil
		      ps-print-footer-frame nil
		      ps-footer-lines 1
		      ps-right-footer (quote ( ))
		      ps-footer-offset -10))
	    (setq ps-left-footer (quote ("/pagenumberstring load"))
		  ps-print-footer t
		  ps-print-footer-frame nil
		  ps-top-margin 20
		  ps-bottom-margin 5
		  ps-left-margin 10
		  ps-right-margin 7
		  ps-print-header nil
		  ps-show-n-of-n nil
		  ps-print-footer-frame nil
		  ps-footer-lines 1
		  ps-right-footer (quote ( ))
		  ps-footer-offset -10))
	  ))
    (setq ps-print-footer nil
					;	  ps-top-margin 10
	  ps-top-margin 5
	  ps-bottom-margin 0
	  ps-left-margin 10
	  ps-right-margin 0
	  ps-print-header nil
	  ps-print-footer nil))    
  (let ((font-size (read-number "What font size do you want? ")))
    (setq ps-font-size (cons 7 font-size)))
  (if (equal ps-font-size '(7 . 9.5))
      (setq-default fill-column 101))
  (if (equal ps-font-size '(7 . 12))
      (setq-default fill-column 78))
  )

Re: A `my-ps-print-setting' function

[Andreas Politz]

Rodolfo Medina wrote:
> Rodolfo Medina <rodolfo.medina@gmail.com> writes:
> 
>> [...] I wish to set some ps-print variables in an interactive way, i.e. be
>> prompted for the value that I want to set.
> 
> 
> 
> With the help that came from this list, I defined a `my-ps-print-setting'
> function, that I'm reporting below.  Improvements are welcome: in particular
> I wish it said: "please answer `r' or `l'" when prompting for a right or left
> footer and [...]

Thank lisp you can make your own choices...

(defmacro defchoice (yes no)
   (let* ((name (format "%c-or-%c-p" yes no))
	 (name-symbol (intern name)))
     `(defun ,name-symbol (prompt)
        ,(format "Ask user a \"%c or %c\" question.  Return t is answer is \"%c\"."
		yes no yes)
        (let* ((pprompt1 (propertize (format "%s (%c or %c) ?" prompt ,yes ,no) 'face
				    'minibuffer-prompt))
	      (pprompt2 (concat (propertize (format "Please answer %c or %c.  " ,yes ,no) 'face
					    'minibuffer-prompt)
				pprompt1))
	      (answer (read-char-exclusive pprompt1)))
	 (while (not (or (= answer ,yes)
			 (= answer ,no)))
	   (setq answer (read-char-exclusive pprompt2)))
	 (= answer ,yes)))))


(defchoice ?r ?l)
(r-or-l-p "Choose !")

-ap

defchoice macro (was: A `my-ps-print-setting' function)

[Rodolfo Medina]

Rodolfo Medina <rodolfo.medina@gmail.com> writes:

>> With the help that came from this list, I defined a `my-ps-print-setting'
>> function, that I'm reporting below.  Improvements are welcome: in particular
>> I wish it said: "please answer `r' or `l'" when prompting for a right or
>> left footer [...]



Andreas Politz <politza@fh-trier.de> writes:

> Thank lisp you can make your own choices...
>
> (defmacro defchoice (yes no)
>   (let* ((name (format "%c-or-%c-p" yes no))
> 	 (name-symbol (intern name)))
>     `(defun ,name-symbol (prompt)
>        ,(format "Ask user a \"%c or %c\" question.  Return t is answer is \"%c\"."
> 		yes no yes)
>        (let* ((pprompt1 (propertize (format "%s (%c or %c) ?" prompt ,yes ,no) 'face
> 				    'minibuffer-prompt))
> 	      (pprompt2 (concat (propertize (format "Please answer %c or %c.  " ,yes ,no) 'face
> 					    'minibuffer-prompt)
> 				pprompt1))
> 	      (answer (read-char-exclusive pprompt1)))
> 	 (while (not (or (= answer ,yes)
> 			 (= answer ,no)))
> 	   (setq answer (read-char-exclusive pprompt2)))
> 	 (= answer ,yes)))))
>
>
> (defchoice ?r ?l)
> (r-or-l-p "Choose !")



Fantastic.  The `r-or-l-p' function so defined is even better than `y-or-n-p',
because if I put, e.g.:

(defun my-test ()
  (interactive)
  (y-or-n-p "y or n? "))

(defun my-test2 ()
  (interactive)
  (r-or-l-p "l or r? "))

, with my-test the text in the echo area does not disappear after answering,
whereas it does with my-test2, which is better.

Only two things:
1) the cursor should appear in the echo area, so I imagine that your macro
   definition should contain some `(let ((cursor-in-echo-area t)))' condition
   somewhere;
2) keys like up, down, right, left, next, prior, end have problems.

Would it be hard to fix those two things?

Thanks, bye
Rodolfo

Re: `y-or-n-p' function definition

[Nikolaj Schumacher]

Rodolfo Medina <rodolfo.medina@gmail.com> wrote:

> Thanks, the `y-or-n-p' function is perfect for what I was looking for.  But
> now I wish to have something like `y-or-n-p' that asks me if I want right or
> left ps footer, like this:
>
>  Right or left? (r/l)

Try `read-char'.

>  If I could access the `y-or-n-p' defun, then I could try to adapt it to an
> `r-or-l-p' version, but can't find it anywhere.

As `describe-function' will tell you, that function is in the C
sources.  So you won't be able to adapt it for lisp code.



regards,
Nikolaj Schumacher