;;; -*- lexical-binding:t -*-
(setq debug-on-error t)

(defvar old-window-alist nil)
(defvar old-window-list nil)
(defvar new-window-alist nil)
(defvar window-alist nil)

(defun window-alist (&optional window)
  (setq window-alist nil)
  (walk-window-subtree
   (lambda (w)
     (setq window-alist
	   (cons (cons w (window-parent w))
		 window-alist)))
   (or window (frame-root-window))))

(defun old-window-alist ()
  (setq old-window-list (window-list))
  (setq old-window-alist nil)
  (dolist (window old-window-list)
    (setq old-window-alist
	  (cons
	   (cons window (window-parent window))
	   old-window-alist)))

  (setq old-window-alist (nreverse old-window-alist)))

(defun new-window-alist ()
  (setq new-window-alist nil)
  (dolist (window old-window-list)
    (setq new-window-alist
	  (cons
	   (cons window (window-parent window))
	   new-window-alist)))

  (setq new-window-alist (nreverse new-window-alist)))

(defun window-tree-pixel-sizes (window &optional next)
  "Return pixel sizes of all windows rooted at WINDOW.
The return value is a list where each window is represented either by a
triple whose first element is either t for an internal window that is a
horizontal combination, nil for an internal window that is a vertical
combination, or the window itself for a live window.  The second element
is a cons of the pixel height and pixel width of the window.  The third
element is specified for internal windows only and recursively lists
that window's child windows using the same triple structure."
  (let (list)
    (while window
      (setq list
	    (cons
	     (cond
	      ((window-top-child window)
	       (cons t (cons (cons (window-pixel-height window)
				   (window-pixel-width window))
			     (window-tree-pixel-sizes
			      (window-top-child window) t))))
	      ((window-left-child window)
	       (cons nil (cons (cons (window-pixel-height window)
				     (window-pixel-width window))
			       (window-tree-pixel-sizes
				(window-left-child window) t))))
	      (t (list window (cons (window-pixel-height window)
				    (window-pixel-width window)))))
	     list))
      (setq window (when next (window-next-sibling window))))
    (nreverse list)))

(defun rotate-windows-anticlockwise (&optional subtree frame-or-window)
  "Rotate windows of FRAME-OR-WINDOW anticlockwise by 90 degrees.
FRAME-OR-WINDOW must be a live frame or window and defaults to the
selected frame.  If FRAME-OR-WINDOW is a frame, rotate the main window
of the frame, otherwise rotate FRAME-OR-WINDOW.  See
`rotate-windows-clockwise' for how to rotate windows in the opposite
direction.  If SUBTREE is non-nil, the function will act as if
FRAME-OR-WINDOW is the parent window of the selected window."
  (interactive "P")
  (let ((window (if subtree
		    (window-parent)
		  (if (windowp frame-or-window)
		      frame-or-window
		    (window-main-window frame-or-window)))))
    (window--transpose window '(right . above) nil)))

(defun rotate-windows-clockwise (&optional subtree frame-or-window)
  "Rotate windows of FRAME-OR-WINDOW clockwise by 90 degrees.
FRAME-OR-WINDOW must be a live frame or window and defaults to the
selected frame.  If FRAME-OR-WINDOW is a frame, rotate the main window
of the frame, otherwise rotate FRAME-OR-WINDOW.  See
`rotate-windows-anticlockwise' for how to rotate windows in the opposite
direction.  If SUBTREE is non-nil, the function will act as if
FRAME-OR-WINDOW is the parent window of the selected window."
  (interactive "P")
  (let ((window (cond
		 (subtree
		  (window-parent))
		 ((windowp frame-or-window)
		  frame-or-window)
		 (t
		  (window-main-window frame-or-window)))))
    (old-window-alist)
    (window-alist window)
;;     (message "%s" window-alist) (sit-for 3)
    (window--transpose window '(left . below) nil)
    (new-window-alist)
    (with-current-buffer (get-buffer-create "*foo*")
      (erase-buffer)
      (pp old-window-alist (current-buffer))
      (insert "\n")
      (pp new-window-alist (current-buffer)))))

(defun flip-windows-horizontally (&optional subtree frame-or-window)
  "Horizontally flip windows of FRAME-OR-WINDOW.
When the windows are flipped horzontally, the window layout is made to
it's reflection from the side edge.  FRAME-OR-WINDOW must be a live
frame or window and defaults to the selected frame.  If FRAME-OR-WINDOW
is a frame, flip from the main window of the frame, otherwise flip from
FRAME-OR-WINDOW.  See `flip-windows-vertically' for how to flip windows
vertically.  If SUBTREE is non-nil, the function will act as if
FRAME-OR-WINDOW is the parent window of the selected window."
  (interactive "P")
  (let ((window (cond
		 (subtree
		  (window-parent))
		 ((windowp frame-or-window)
		  frame-or-window)
		 (t
		  (window-main-window frame-or-window)))))
    (window--transpose window '(below . left) t)))

(defun flip-windows-vertically (&optional subtree frame-or-window)
  "Horizontally flip windows of FRAME-OR-WINDOW.
When the windows are flipped vertically, the window layout is made to
it's reflection from the top edge.  FRAME-OR-WINDOW must be a live frame
or window and defaults to the selected frame.  If FRAME-OR-WINDOW is a
frame, flip from the main window of the frame, otherwise flip from
FRAME-OR-WINDOW.  See `flip-windows-horizontally' for how to flip
windows horizontally."
  (interactive "P")
  (let ((window (if subtree
		    (window-parent)
		  (if (windowp frame-or-window)
		      frame-or-window
		    (window-main-window frame-or-window)))))
    (window--transpose window '(above . right) t)))

(defun transpose-windows (&optional subtree frame-or-window)
  "Transpose windows of FRAME-OR-WINDOW.
Rearrange windows such that where a horizontal split was used a vertical
one is used instead, and vice versa.  FRAME-OR-WINDOW must be a live
frame or window and defaults to the selected frame.  If FRAME-OR-WINDOW
is a frame, transpose the main window of the frame, otherwise transpose
FRAME-OR-WINDOW.  If SUBTREE is non-nil, the function will act as if
FRAME-OR-WINDOW is the parent window of the selected window."
  (interactive "P")
  (let ((window (if subtree
		    (window-parent)
		  (if (windowp frame-or-window)
		      frame-or-window
		    (window-main-window frame-or-window)))))
    (window--transpose window '(right . below) nil)))

(defun window--transpose (window conf do-not-convert-size)
  "Rearrange windows of WINDOW recursively.
CONF should be a cons cell: (HORIZONTAL-SPLIT . VERTICAL-SPLIT) where
HORIZONTAL-SPLIT will be used as the third argument of `split-window'
when splitting a window that was previously horizontally split, and
VERTICAL-SPLIT as third argument of `split-window' for a window that was
previously vertically split.  If DO-NOT-CONVERT-SIZE non-nil, the size
argument of the window-split is converted from vertical to horizontal or
vice versa, with the same proportion of the total split."
  (if (or (not window)
	  (window-live-p window))
      (message "No windows to transpose")
    (let* ((frame (window-frame window))
	   (fwin window)
	   (selwin (frame-selected-window window))
	   (win-tree (car (window-tree-pixel-sizes window))))
      (while (not (window-live-p fwin))
	(setq fwin (window-child fwin)))
      (delete-other-windows-internal
       fwin (and (window-valid-p (car win-tree)) (car win-tree)))
      (window--transpose-1 win-tree fwin conf do-not-convert-size)
      ;; Go back to previously selected window.
      (set-frame-selected-window frame selwin))))

(defun window--transpose-1 (subtree cwin conf do-not-convert-size)
  "Subroutine of `window--transpose'.
SUBTREE must be in the format of the result of
`window-tree-pixel-sizes'.  CWIN is the current window through which the
window splits are made.  The CONF and DO-NOT-CONVERT-SIZE arguments are
the same as the ones in `window--transpose'."
  ;; `ilen' is the max size a window could be of given the split type.
  ;; `flen' is max size the window could be converted to the opposite
  ;; of the given split type.
  (pcase-let ((`(,ilen . ,flen) (if (car subtree)
				    (cons (float (car (cadr subtree)))
					  (float (window-pixel-width cwin)))
				  (cons (float (cdr (cadr subtree)))
					(float (window-pixel-height cwin))))))
    (mapc
     (pcase-lambda (`(,win . ,size))
       (let ((split-size (- (if do-not-convert-size
				size
			      (round (* flen  (/ size ilen))))))
	     (split-type
	      (funcall (if (car subtree) 'car 'cdr) conf)))
	 (if (listp win)
	     (let* ((refer-car (seq-some
				(lambda (x)
				  (and (windowp x) x))
				(flatten-list win)))
		    (refer (cons refer-car
				 (cdr (assq cwin window-alist)))))
;; 	       (message "1 .. %s" (cons refer (cdr (assq refer-car window-alist)))) (sit-for 3)
	       ;; `win' is a window subtree.
	       (window--transpose-1 win (split-window cwin
						      split-size
						      split-type
						      t
						      refer)
				    conf do-not-convert-size))
	   ;; `win' is a window.
;; 	   (message "2 .. %s" (cons win (cdr (assq win window-alist)))) (sit-for 3)
	   (split-window cwin split-size
			 split-type t
			 (cons win (cdr (assq win window-alist)))))))
     (mapcar
      (lambda (e)
	(let ((window? (if (windowp (car e)) (car e) e)))
	  (cons window?
		;; The respective size of the window.
		(if (car subtree)
		    (car (cadr e))
		  (cdr (cadr e))))))
      ;; By using cdddr, we ignore window split type, sizes and the
      ;; first window (it's implicitly created).
      (nreverse (cdddr subtree))))
    ;; (caaddr subtree) is the first window.
    (unless (windowp (caaddr subtree))
      (window--transpose-1 (caddr subtree) cwin conf do-not-convert-size))))

(global-set-key [(super p)] 'transpose-windows)
(global-set-key [(super q)] 'rotate-windows-clockwise)

(let ((window (split-window)))
  (set-window-buffer window (get-buffer-create "*foo*"))
  (setq window (split-window nil nil t))
  (set-window-buffer window (get-buffer-create "*Messages*"))
  (select-window window))