Re: Mail mode vs message mode

[Katsumi Yamaoka <yamaoka@jpl.org>]

>>>>> Reiner Steib wrote:
> On Tue, Nov 24 2009, Katsumi Yamaoka wrote:

>> They may not be serious, but as for `message-yank-prefix', it may
>> not be easy to users to find the way to make Gnus work as before
>> (the new behavior is that cited lines are prefixed only with three
>> space characters).

> This is not acceptable IMHO.  We need to find a solution for this.
> I don't have a good idea, though.

How about using the value of mail-* if and only if the value of
mail-* is customized by a user or its default value is suitable
to Gnus?

(defcustom MESSAGE-VAR
  (if (or
       ;; MAIL-VAR's value is set by a user in the ~/.emacs file but
       ;; the .el file containing the form `(defcustom MAIL-VAR ...)'
       ;; is not loaded yet.
       (and (boundp MAIL-VAR)
	    (not (get MAIL-VAR 'standard-value)))
       ;; MAIL-VAR's value is customized by a user.
       (and (get MAIL-VAR 'standard-value)
	    (not (equal (car (get MAIL-VAR 'standard-value))
			(symbol-value MAIL-VAR))))
       ;; MAIL-VAR's default value is suitable to Gnus' default.
       (and (boundp MAIL-VAR)
	    (equal (symbol-value MAIL-VAR) VALUE-SUITABLE-TO-GNUS)))
      ;; Use MAIL-VAR's value.
      (symbol-value MAIL-VAR)
    ;; Use a value suitable to Gnus' default.
    VALUE-SUITABLE-TO-GNUS)
  "doc string")

For `message-yank-prefix', it will be the following:

(defcustom message-yank-prefix
  (if (or (and (boundp 'mail-yank-prefix)
	       (not (get 'mail-yank-prefix 'standard-value)))
	  (and (get 'mail-yank-prefix 'standard-value)
	       (not (equal (car (get 'mail-yank-prefix 'standard-value))
			   mail-yank-prefix)))
	  (and (boundp 'mail-yank-prefix)
	       (equal mail-yank-prefix "> ")))
      mail-yank-prefix
    "> ")
  "doc string")

In Emacs 22, it will default to "> ", while mail-yank-prefix's
default is nil.

The above one differs from this:

(defcustom message-yank-prefix "> "
  "doc string")

User's preference to mail-* is reflected to message-*.

Regards,