Re: Where to show message output while inputting [was: New multi-command facility displays in the wrong echo area]

[Gregory Heytings via "Emacs development discussions." <emacs-devel@gnu.org>]

[-- Attachment #1: Type: text/plain, Size: 1270 bytes --]


Hi Stefan,

>>> Eldoc's purpose is different from the purpose of displaying echo-area 
>>> messages.  For example, nothing significantly bad can happen if you 
>>> miss the Eldoc's hints, but the same is not true for some important 
>>> echo-area messages.
>>
>> AFAICS you can't miss them with the proposed solution: they are 
>> displayed on the left of the mode-line, with a different background and 
>> foreground.
>
> In my setup, the minibuffer is in its own frame, with no mode-line in 
> sight.  So indeed I don't get the eldoc hints in `M-:` because they're 
> placed in a non-displayed mode-line.  E.g.:
>
>    % src/emacs -Q --eval '(setq default-frame-alist (quote ((minibuffer . nil))))'
>    M-: (format
>    ...wait a little...
>
> ...and see that the mode-line doesn't display anything about `format`
>

I tried your recipe with Emacs 25 to 28, and the modeline _does_ display 
the eldoc info about 'format', so I'm not quite sure what you mean.

Your remark did, however, prompt me to look closer at this case, and to 
improve my "minibuffer-message-in-mode-line" feature a second time.  I 
attach its last version.  Could you perhaps have a look at/try this, and 
give your opinion on it?  It's an attempt to give a more robust solution 
to bug#38457.

[-- Attachment #2: Type: text/plain, Size: 2441 bytes --]

(defvar minibuffer-message-mode-line-string nil)
(defvar minibuffer-message-mode-line-buffer nil)
(defun clear-minibuffer-message ()
  (when (not noninteractive)
    (when (timerp minibuffer-message-timer)
      (cancel-timer minibuffer-message-timer)
      (setq minibuffer-message-timer nil))
    (setq minibuffer-message-mode-line-string nil)
    (when (bufferp minibuffer-message-mode-line-buffer)
      (with-current-buffer minibuffer-message-mode-line-buffer
        (let ((mls (and (listp mode-line-format)
                        (assq 'minibuffer-message-mode-line-string
                              mode-line-format))))
          (if mls (setq mode-line-format (cadr (remq mls mode-line-format))))))
      (setq minibuffer-message-mode-line-buffer nil))))
(defface minibuffer-message-face
  `((t (:background ,(face-attribute 'default :background)
        :foreground ,(face-attribute 'default :foreground)))) "")
(defun set-minibuffer-message (message)
  (when (and (not noninteractive)
             (window-live-p (active-minibuffer-window))
             (or (eq (window-frame) (window-frame (active-minibuffer-window)))
                 (eq (frame-parameter (window-frame (active-minibuffer-window)) 'minibuffer) 'only)))
    (progn
      (when (numberp minibuffer-message-clear-timeout)
        (setq minibuffer-message-timer
              (run-with-timer minibuffer-message-clear-timeout nil
                              #'clear-minibuffer-message)))
      (with-current-buffer
          (window-buffer
           (or (window-in-direction 'above (minibuffer-window))
               (minibuffer-selected-window)
               (get-largest-window)))
        (clear-minibuffer-message)
        (when (and mode-line-format
                   (not (and (listp mode-line-format)
                             (assq 'minibuffer-message-mode-line-string
                                   mode-line-format))))
          (setq minibuffer-message-mode-line-buffer (current-buffer))
          (setq mode-line-format
                (list "" '(minibuffer-message-mode-line-string
                           (" " (:propertize minibuffer-message-mode-line-string
                                             face minibuffer-message-face) " "))
                      mode-line-format)))
        (setq minibuffer-message-mode-line-string message)
        (force-mode-line-update))
      t)))