RE: [External] : Re: What are invisible frames for?

[Drew Adams <drew.adams@oracle.com>]

> OK.  Presumably you set this up by setting the 'visibility frame
> parameter.  I don't think setting that frame parameter causes
> Fmake_frame_invisible to get called.  At least, I can't find the call
> anywhere.
> 
> I don't think I was clear enough in my OP, but it's calls to
> Fmake_frame_invisible which are bothering me.  That function moves any
> minibuffer on the frame to some other frame.  I don't think it should.
> That's what I'm trying to sort out.

I use the Lisp function `make-frame-invisible'.  For example:

(defun hide-frame (frame &optional prefix)
  "Make FRAME invisible.  Like `make-frame-invisible', but reads frame name.
Non-nil PREFIX makes it invisible even if all other frames are invisible."
  (interactive (list (read-frame "Frame to make invisible: ")))
  (make-frame-invisible (get-a-frame frame) prefix))

(defun show-frame (frame)
  "Make FRAME visible and raise it, without selecting it.
FRAME may be a frame or its name."
  (interactive (list (read-frame "Frame to make visible: ")))
  (setq frame  (get-a-frame frame))
  (make-frame-visible frame)
  (raise-frame frame))

(defun hide-everything ()
  "Hide all frames of session at once.
Iconify minibuffer frame; make all others invisible.
Remembers frame configuration in register `C-l' (Control-L).
To restore this frame configuration, use `\\[jump-to-register] C-l'."
  (interactive)
  (frame-configuration-to-register frame-config-register)
  (let ((minibuf-frame-name
         (and (boundp '1on1-minibuffer-frame)
              (cdr (assq 'name (frame-parameters
                                 1on1-minibuffer-frame)))))
        (thumfr-thumbify-dont-iconify-flag  nil)) ; In `thumb-frm.el'.
    (dolist (frame  (frame-list))
      (if (eq minibuf-frame-name
              (cdr (assq 'name (frame-parameters frame))))
          (iconify-frame frame)         ; minibuffer frame
        (make-frame-invisible frame t))))) ; other frames

(defun show-hide ()
  "1 frame visible: `show-hide-show-function'; else: `hide-everything'.
This acts as a toggle between showing all frames and showing only an
iconified minibuffer frame."
  (interactive)
  (if (< (length (visible-frame-list)) 2)
      (funcall show-hide-show-function)
    (hide-everything)))

https://www.emacswiki.org/emacs/download/frame-cmds.el