RE: info faces for strings and quotations

["Drew Adams" <drew.adams@oracle.com>]

[-- Attachment #1: Type: text/plain, Size: 3022 bytes --]

This version works well. The fontify function is in line below; the full
patch is attached. This seems to do everything the previous version did,
plus treat initial \" correctly. Things like this from (ccmode)Indentation
Functions are not highlighted now, which is the correct behavior: (\"Hello
world!\");

Thanks to everyone who contributed suggestions. I went with David's
suggestion for treating initial \".

Per Luc's suggestion, I added a note to the doc string of
`Info-fontify-quotations-flag' explaining that fontification can never be
100% reliable, that occasional inappropriate highlighting is not a bug, and
that highlighting can be turned off. It is now off by default.

I won't be working any more on this. I think it is ready for prime time, and
I hope the decision will be to add it to Emacs.

BTW, with this highlighting, I noticed these additional Info text bugs (the
first one I had noticed earlier, but forgot to point out):

 - (eintr)the-the -- "the' should be "the"
 - (gnus)Fancy Mail Splitting: (any "mypackage@somewhere\" -
"bugs-mypackage" "mypkg.list") -- I'm guessing that the backslash doesn't
belong here.
 - (elisp)Specification List -- `(spec .  [(more specs...)])') -- ' is in
wrong place.

 - Drew

;; The regexp has these parts: double-quoted string or single-quoted stuff.
;;
;; String has, inside "...", zero or more of these characters:
;;   - any character except \ and "
;;   - \ followed by any character
;;
;; Single-quoted stuff has, inside `...': any character except '
;;
;; The regexp matches `...' or "...". The latter case also includes
;; pseudo-strings that start with \". The second branch of the
;; conditional tests this: if that is the match, then it moves past
;; the \.
(defun info-fontify-quotations ()
  "Fontify text between double-quotes (\"...\") and single-quotes (`...')
For single-quotes, use face `info-quoted-name'.
For double-quotes, use face `info-string'."
  (while (re-search-forward             ; Match `...' or "..."
          "\"\\(?:[^\\\"]\\|\\\\\\(?:.\\|[\n]\\)\\)*\"\\|`[^']+'"
          nil t)
    (cond ((eq ?` (aref (match-string 0) 0))
           (put-text-property (1+ (match-beginning 0)) (1- (match-end 0))
                              'font-lock-face 'info-quoted-name))
          ((and (goto-char (match-beginning 0)) ; "...": If preceded by \,
skip it
                (= 1 (mod (save-excursion (skip-chars-backward "\\\\")) 2)))
           (forward-char 1))
          ((goto-char (match-end 0))    ; "..." not preceded by \
           (put-text-property (match-beginning 0) (match-end 0)
                              'font-lock-face 'info-string)))))


-----Original Message-----From: Stefan, quoting David, replying to Stefan
> If you don't need regexps, it is usually quite faster just to check with
> (zerop (mod (save-excursion (skip-chars-backward "\\\\")) 2)) whether you
> have an even number of preceding backslashes.

That's true.  The "\\(^\\|[^\\]\\)\\(\\\\\\\\\\)*" prefix can slow down
regexp searching significantly.

[-- Attachment #2: diff-info-highlight-quotations-fourth.txt --]
[-- Type: text/plain, Size: 4215 bytes --]

diff -c "c:/emacs-21.3.50/lisp/info.el" "c:/drews-lisp-20/info-w-quotes-fourth.el"
*** c:/emacs-21.3.50/lisp/info.el	Mon Jul 26 09:42:06 2004
--- c:/drews-lisp-20/info-w-quotes-fourth.el	Thu Oct  7 21:30:04 2004
***************
*** 65,70 ****
--- 65,94 ----
  The Lisp code is executed when the node is selected.")
  (put 'Info-enable-active-nodes 'risky-local-variable t)
  
+ (defcustom Info-fontify-quotations-flag nil
+   "*Non-nil means `info' fontifies text between quotes.
+ This applies to double-quote strings (\"...\") and text between
+ single-quotes (`...').
+ 
+ Note: This fontification can never be 100% reliable. It aims to
+ be useful in most Info texts, but it can occasionally result in
+ fontification that you might not expect. This is not a bug; it is
+ part of the design to be able to appropriately fontify a great
+ variety of texts. Set this flag to nil if you do not find this
+ fontification useful."
+   :type 'boolean
+   :group 'info)
+ 
+ (defface info-quoted-name               ; For `...'
+   '((t (:inherit font-lock-constant-face)))
+   "Face used for quoted names (`...') in `info'."
+   :group 'info)
+ 
+ (defface info-string                    ; For "..."
+   '((t (:inherit font-lock-string-face)))
+   "Face used for strings (\"...\") in `info'."
+   :group 'info)
+ 
  (defface info-node
    '((((class color) (background light)) :foreground "brown" :weight bold :slant italic)
      (((class color) (background dark)) :foreground "white" :weight bold :slant italic)
***************
*** 3416,3421 ****
--- 3440,3449 ----
                (skip-chars-backward " \t,")
                (put-text-property (point) header-end 'invisible t)))))
  
+       ;; Fontify `...' and "..."
+       (goto-char (point-min))
+       (when Info-fontify-quotations-flag (info-fontify-quotations))
+ 
        ;; Fontify titles
        (goto-char (point-min))
        (when not-fontified-p
***************
*** 3669,3676 ****
                                 '(font-lock-face info-xref
                                                  mouse-face highlight
                                                  help-echo "mouse-2: go to this URL"))))
- 
        (set-buffer-modified-p nil))))
  \f
  
  ;; When an Info buffer is killed, make sure the associated tags buffer
--- 3697,3733 ----
                                 '(font-lock-face info-xref
                                                  mouse-face highlight
                                                  help-echo "mouse-2: go to this URL"))))
        (set-buffer-modified-p nil))))
+ 
+ 
+ ;; The regexp has these parts: double-quoted string or single-quoted stuff.
+ ;;
+ ;; String has, inside "...", zero or more of these characters:
+ ;;   - any character except \ and "
+ ;;   - \ followed by any character
+ ;;
+ ;; Single-quoted stuff has, inside `...': any character except '
+ ;;
+ ;; The regexp matches `...' or "...". The latter case also includes
+ ;; pseudo-strings that start with \". The second branch of the
+ ;; conditional tests this: if that is the match, then it moves past
+ ;; the \.
+ (defun info-fontify-quotations ()
+   "Fontify text between double-quotes (\"...\") and single-quotes (`...')
+ For single-quotes, use face `info-quoted-name'.
+ For double-quotes, use face `info-string'."
+   (while (re-search-forward             ; Match `...' or "..."
+           "\"\\(?:[^\\\"]\\|\\\\\\(?:.\\|[\n]\\)\\)*\"\\|`[^']+'"
+           nil t)
+     (cond ((eq ?` (aref (match-string 0) 0))
+            (put-text-property (1+ (match-beginning 0)) (1- (match-end 0))
+                               'font-lock-face 'info-quoted-name))
+           ((and (goto-char (match-beginning 0)) ; "...": If preceded by \, skip it
+                 (= 1 (mod (save-excursion (skip-chars-backward "\\\\")) 2)))
+            (forward-char 1))
+           ((goto-char (match-end 0))    ; "..." not preceded by \
+            (put-text-property (match-beginning 0) (match-end 0)
+                               'font-lock-face 'info-string)))))
  \f
  
  ;; When an Info buffer is killed, make sure the associated tags buffer

[-- Attachment #3: Type: text/plain, Size: 142 bytes --]

_______________________________________________
Emacs-devel mailing list
Emacs-devel@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-devel