C-u prefix behavior of TAB broken

C-u prefix behavior of TAB broken

[Miles Bader]

Until the recent changes to the default TAB command, it used to be that
using a C-u prefix with TAB (in a programming language mode) would
indent the entire following form to reflect the change in indentation
(where the form selected was whatever the sexp commands would select --
e.g. an entire brace-delimited code block).

This was a very handy feature, but doesn't work anymore.

For instance if you place the cursor before "(when" in the following
elisp code:

(defun test (flag)
(when flag
  (format "hello")))

and hit TAB, the result _used_ to be:

(defun test (flag)
  (when flag
    (format "hello")))

But now it just gives you:

(defun test (flag)
  (when flag
  (format "hello")))

[I don't know exactly _where_ this feature was implemented, but it
worked at least in lisp mode and the various C related modes.]

Thanks,

-Miles

-- 
"Though they may have different meanings, the cries of 'Yeeeee-haw!' and
 'Allahu akbar!' are, in spirit, not actually all that different."

Re: C-u prefix behavior of TAB broken

[martin rudalics]

 > Until the recent changes to the default TAB command, it used to be that
 > using a C-u prefix with TAB (in a programming language mode) would
 > indent the entire following form to reflect the change in indentation
 > (where the form selected was whatever the sexp commands would select --
 > e.g. an entire brace-delimited code block).
 >
 > This was a very handy feature, but doesn't work anymore.

This never worked for me.  I had:

With argument, indent any additional lines of the same expression
rigidly along with this one.

 > [I don't know exactly _where_ this feature was implemented, but it
 > worked at least in lisp mode and the various C related modes.]

If you ever find out where you got this code from please post the source
here.  I'd like to bind it to TAB TAB.

Re: C-u prefix behavior of TAB broken

[Miles Bader]

martin rudalics <rudalics@gmx.at> writes:
> This never worked for me.  I had:
>
> With argument, indent any additional lines of the same expression
> rigidly along with this one.

I'm not sure what you mean... maybe my explanation was poor, but the
above is what I'm referring to.

Anyway, that feature is now broken.

-Miles

-- 
I'm beginning to think that life is just one long Yoko Ono album; no rhyme
or reason, just a lot of incoherent shrieks and then it's over.  --Ian Wolff

Re: C-u prefix behavior of TAB broken

[martin rudalics]

 > I'm not sure what you mean... maybe my explanation was poor, but the
 > above is what I'm referring to.

I thought you had a less rigid version of that.

 > Anyway, that feature is now broken.

FWIW in lisp-mode it's due to that change:

2007-09-19  Stefan Monnier  <monnier@iro.umontreal.ca>

         ...

	* emacs-lisp/lisp-mode.el (lisp-mode-shared-map): Use the default TAB
	binding, so tab-always-indent works right.

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    Anyway, that feature is now broken.

That is an important feature -- can someone please debug it
and ack?

Re: C-u prefix behavior of TAB broken

[Stefan Monnier]

>> I'm not sure what you mean... maybe my explanation was poor, but the
>> above is what I'm referring to.

> I thought you had a less rigid version of that.

>> Anyway, that feature is now broken.

> FWIW in lisp-mode it's due to that change:

> 2007-09-19  Stefan Monnier  <monnier@iro.umontreal.ca>

>         ...

> 	* emacs-lisp/lisp-mode.el (lisp-mode-shared-map): Use the default TAB
> 	binding, so tab-always-indent works right.

It may be the superficial reason for it, but it shouldn't be the root
cause for it: indent-for-tab-command used to pass the C-u prefix to the
indent-line-function.

This said, IMNSHO the feature we're talking about shouldn't be implement
in lisp-mode and c-mode but directly generically in
indent-for-tab-command.

I use the following code in my local version of indent-for-tab-command
for that purpose:

  (cond
   [...]
   (arg
    (let ((old-indent (current-indentation)))
      (if (eq (indent-according-to-mode) 'noindent)
	  (funcall (default-value 'indent-line-function)))
      (let ((new-indent (current-indentation))
	    (beg (line-beginning-position 2))
	    (end (save-excursion (beginning-of-line)
				 (forward-sexp 1)
				 (point))))
	(when (and (> end beg) (/= new-indent old-indent))
	  (indent-code-rigidly beg end (- new-indent old-indent))))))
   [...])



        Stefan

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    This said, IMNSHO the feature we're talking about shouldn't be implement
    in lisp-mode and c-mode but directly generically in
    indent-for-tab-command.

If that works, by all means do it.

Re: C-u prefix behavior of TAB broken

[Miles Bader]

Richard Stallman <rms@gnu.org> writes:
>     This said, IMNSHO the feature we're talking about shouldn't be implement
>     in lisp-mode and c-mode but directly generically in
>     indent-for-tab-command.
>
> If that works, by all means do it.

I'd certainly be grateful!

[I didn't realize I used it so much (on the face of it, it seems like a
rather obscure bit of functionality), but I find my fingers keep trying
to invoke it, and I keep being surprised when it doesn't work...  ]

-Miles

-- 
What the fuck do white people have to be blue about!?  Banana Republic ran
out of Khakis?  The Espresso Machine is jammed?  Hootie and The Blowfish are
breaking up??!  Shit, white people oughtta understand, their job is to GIVE
people the blues, not to get them!    -- George Carlin

Re: C-u prefix behavior of TAB broken

[martin rudalics]

[-- Attachment #1: Type: text/plain, Size: 1002 bytes --]

 >>    This said, IMNSHO the feature we're talking about shouldn't be implement
 >>    in lisp-mode and c-mode but directly generically in
 >>    indent-for-tab-command.
 >>
 >>If that works, by all means do it.

FWIW all indent-line-functions with the exception of `lisp-indent-line'
either don't have arguments or, like `c-indent-line', `f90-indent-line',
and `(c)perl-indent-line' expect completely different arguments here.
Hence a generic solution seems hardly practicable.

For the case a prefix argument is given and the region is not active, we
could try to set the region around the smallest containing form and call
`indent-region' on that.  But that would be a different feature.

 > I'd certainly be grateful!
 >
 > [I didn't realize I used it so much (on the face of it, it seems like a
 > rather obscure bit of functionality), but I find my fingers keep trying
 > to invoke it, and I keep being surprised when it doesn't work...  ]

For `lisp-indent-line' I can offer the attached patch.

[-- Attachment #2: lisp-mode.patch --]
[-- Type: text/plain, Size: 803 bytes --]

*** lisp-mode.el.~1.209.~	Tue Oct  9 11:52:54 2007
--- lisp-mode.el	Sat Dec 22 09:55:52 2007
***************
*** 821,827 ****
        (if (> (- (point-max) pos) (point))
  	  (goto-char (- (point-max) pos)))
        ;; If desired, shift remaining lines of expression the same amount.
!       (and whole-exp (not (zerop shift-amt))
  	   (save-excursion
  	     (goto-char beg)
  	     (forward-sexp 1)
--- 821,831 ----
        (if (> (- (point-max) pos) (point))
  	  (goto-char (- (point-max) pos)))
        ;; If desired, shift remaining lines of expression the same amount.
!       (and (or whole-exp
! 	       (and current-prefix-arg
! 		    (or (not transient-mark-mode)
! 			(not mark-active))))
! 	   (not (zerop shift-amt))
  	   (save-excursion
  	     (goto-char beg)
  	     (forward-sexp 1)

[-- Attachment #3: Type: text/plain, Size: 142 bytes --]

_______________________________________________
Emacs-devel mailing list
Emacs-devel@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-devel

Re: C-u prefix behavior of TAB broken

[Miles Bader]

martin rudalics <rudalics@gmx.at> writes:
> For the case a prefix argument is given and the region is not active, we
> could try to set the region around the smallest containing form and call
> `indent-region' on that.  But that would be a different feature.

Can't indent-for-tab-command simply, if there's a prefix argument given,
rigidly indent the following sexp by the change in indentation?  That
doesn't seem hard at all, and matches the behavior I remember (perhaps
there are corner cases where it would differ, but I don't think I know
about them...).

For instance, the following isn't the most elegant code, but it seems to
do the right thing:

--- orig/lisp/indent.el
+++ mod/lisp/indent.el
@@ -99,13 +99,26 @@
 	     (or (> (current-column) (current-indentation))
 		 (eq this-command last-command))))
     (insert-tab arg))
-   ;; Those functions are meant specifically for tabbing and not for
-   ;; indenting, so we can't pass them to indent-according-to-mode.
-   ((memq indent-line-function '(indent-relative indent-relative-maybe))
-    (funcall indent-line-function))
-   ;; Indent the line.
    (t
-    (indent-according-to-mode))))
+    (let ((end-marker (and arg (save-excursion (forward-sexp) (point-marker))))
+	  (old-indent (current-indentation)))
+
+      ;; Those functions are meant specifically for tabbing and not for
+      ;; indenting, so we can't pass them to indent-according-to-mode.
+      (if (memq indent-line-function '(indent-relative indent-relative-maybe))
+	  (funcall indent-line-function)
+	;; Indent the line.
+	(indent-according-to-mode))
+
+      ;; If a prefix argument was given, rigidly indent the following
+      ;; sexp to match the change in the current line's indentation.
+      ;;
+      (when arg
+	(let ((indentation-change (- (current-indentation) old-indent)))
+	  (save-excursion
+	    (forward-line 1)
+	    (when (< (point) end-marker)
+	      (indent-rigidly (point) end-marker indentation-change)))))))))
 
 (defun insert-tab (&optional arg)
   (let ((count (prefix-numeric-value arg)))


-Miles

-- 
"An atheist doesn't have to be someone who thinks he has a proof that there
can't be a god.  He only has to be someone who believes that the evidence
on the God question is at a similar level to the evidence on the werewolf
question."  [John McCarthy]

Re: C-u prefix behavior of TAB broken

[martin rudalics]

 > Can't indent-for-tab-command simply, if there's a prefix argument given,
 > rigidly indent the following sexp by the change in indentation?  That
 > doesn't seem hard at all, and matches the behavior I remember (perhaps
 > there are corner cases where it would differ, but I don't think I know
 > about them...).

For `tab-always-indent' t it might make sense to do `beginning-of-line'
before the `forward-sexp'.  Otherwise it should work wherever
`forward-sexp' behaves reasonably.  BTW, isn't

    ((memq indent-line-function '(indent-relative indent-relative-maybe))
     (funcall indent-line-function))
    ;; Indent the line.
    (t
     (indent-according-to-mode))

semantically equivalent to

    (t
     (funcall indent-line-function))

Re: C-u prefix behavior of TAB broken

[Miles Bader]

martin rudalics <rudalics@gmx.at> writes:
> For `tab-always-indent' t it might make sense to do `beginning-of-line'
> before the `forward-sexp'.

True.  It doesn't reach that code at all if tab-always-indent is nil and
the point is not in the indentation, so I think it can just always move
to the start of the line before calling forward-sexp.

> BTW, isn't
>
>    ((memq indent-line-function '(indent-relative indent-relative-maybe))
>     (funcall indent-line-function))
>    ;; Indent the line.
>    (t
>     (indent-according-to-mode))
>
> semantically equivalent to
>
>    (t
>     (funcall indent-line-function))

Indeed yes!  That's a nice simplification...

I fixed some other little problems (e.g. it should have been using "P"
[raw-prefix] in the interactive spec), so here's the current patch:

--- orig/lisp/indent.el
+++ mod/lisp/indent.el
@@ -86,10 +86,10 @@
 indent the region.
 The function actually called to indent the line is determined by the value of
 `indent-line-function'."
-  (interactive "p")
+  (interactive "P")
   (cond
    ;; The region is active, indent it.
-   ((and arg transient-mark-mode mark-active
+   ((and transient-mark-mode mark-active
 	 (not (eq (region-beginning) (region-end))))
     (indent-region (region-beginning) (region-end)))
    ((or ;; indent-to-left-margin is only meant for indenting,
@@ -99,13 +99,26 @@
 	     (or (> (current-column) (current-indentation))
 		 (eq this-command last-command))))
     (insert-tab arg))
-   ;; Those functions are meant specifically for tabbing and not for
-   ;; indenting, so we can't pass them to indent-according-to-mode.
-   ((memq indent-line-function '(indent-relative indent-relative-maybe))
-    (funcall indent-line-function))
-   ;; Indent the line.
    (t
-    (indent-according-to-mode))))
+    (let ((end-marker
+	   (and arg
+		(save-excursion
+		  (forward-line 0) (forward-sexp) (point-marker))))
+	  (old-indent
+	   (current-indentation)))
+
+      ;; Indent the line.
+      (funcall indent-line-function)
+
+      ;; If a prefix argument was given, rigidly indent the following
+      ;; sexp to match the change in the current line's indentation.
+      ;;
+      (when arg
+	(let ((indentation-change (- (current-indentation) old-indent)))
+	  (save-excursion
+	    (forward-line 1)
+	    (when (< (point) end-marker)
+	      (indent-rigidly (point) end-marker indentation-change)))))))))
 
 (defun insert-tab (&optional arg)
   (let ((count (prefix-numeric-value arg)))


-- 
Ich bin ein Virus. Mach' mit und kopiere mich in Deine .signature.

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    FWIW all indent-line-functions with the exception of `lisp-indent-line'
    either don't have arguments or, like `c-indent-line', `f90-indent-line',
    and `(c)perl-indent-line' expect completely different arguments here.
    Hence a generic solution seems hardly practicable.

Could you name one or two, so I can take a look and see specifically what
you mean?

Re: C-u prefix behavior of TAB broken

[martin rudalics]

 >     FWIW all indent-line-functions with the exception of `lisp-indent-line'
 >     either don't have arguments or, like `c-indent-line', `f90-indent-line',
 >     and `(c)perl-indent-line' expect completely different arguments here.
 >     Hence a generic solution seems hardly practicable.
 >
 > Could you name one or two, so I can take a look and see specifically what
 > you mean?

I meant that

(defun lisp-indent-line (&optional whole-exp)

takes one optional argument `whole-exp' that implements the feature.

(defun c-indent-line (&optional syntax quiet ignore-point-pos)

takes three completely unrelated arguments and won't implement the
feature.

(defun python-indent-line ()

takes no argument at all and won't implement the feature either.

All this based on the assumption that `indent-for-tab-command' with a
prefix argument would pass something like `whole-exp' down to the
indent-line function of the major mode and have the latter do the job.

Miles elegantly side-stepped the issue in his patch by implementing the
feature within `indent-for-tab-command' so my argument is void.

Re: C-u prefix behavior of TAB broken

[martin rudalics]

 > +	(let ((indentation-change (- (current-indentation) old-indent)))

`lisp-indent-line' quits here when `indentation-change' equals zero.

 > +	  (save-excursion
 > +	    (forward-line 1)
 > +	    (when (< (point) end-marker)
 > +	      (indent-rigidly (point) end-marker indentation-change)))))))))

Re: C-u prefix behavior of TAB broken

[Miles Bader]

martin rudalics <rudalics@gmx.at> writes:
>> +	(let ((indentation-change (- (current-indentation) old-indent)))
>
> `lisp-indent-line' quits here when `indentation-change' equals zero.

Good point (fixed below).

-Miles


--- orig/lisp/indent.el
+++ mod/lisp/indent.el
@@ -86,10 +86,10 @@
 indent the region.
 The function actually called to indent the line is determined by the value of
 `indent-line-function'."
-  (interactive "p")
+  (interactive "P")
   (cond
    ;; The region is active, indent it.
-   ((and arg transient-mark-mode mark-active
+   ((and transient-mark-mode mark-active
 	 (not (eq (region-beginning) (region-end))))
     (indent-region (region-beginning) (region-end)))
    ((or ;; indent-to-left-margin is only meant for indenting,
@@ -99,13 +99,27 @@
 	     (or (> (current-column) (current-indentation))
 		 (eq this-command last-command))))
     (insert-tab arg))
-   ;; Those functions are meant specifically for tabbing and not for
-   ;; indenting, so we can't pass them to indent-according-to-mode.
-   ((memq indent-line-function '(indent-relative indent-relative-maybe))
-    (funcall indent-line-function))
-   ;; Indent the line.
    (t
-    (indent-according-to-mode))))
+    (let ((end-marker
+	   (and arg
+		(save-excursion
+		  (forward-line 0) (forward-sexp) (point-marker))))
+	  (old-indent
+	   (current-indentation)))
+
+      ;; Indent the line.
+      (funcall indent-line-function)
+
+      ;; If a prefix argument was given, rigidly indent the following
+      ;; sexp to match the change in the current line's indentation.
+      ;;
+      (when arg
+	(let ((indentation-change (- (current-indentation) old-indent)))
+	  (unless (zerop indentation-change)
+	    (save-excursion
+	      (forward-line 1)
+	      (when (< (point) end-marker)
+		(indent-rigidly (point) end-marker indentation-change))))))))))
 
 (defun insert-tab (&optional arg)
   (let ((count (prefix-numeric-value arg)))


-- 
The car has become... an article of dress without which we feel uncertain,
unclad, and incomplete.  [Marshall McLuhan, Understanding Media, 1964]

Re: C-u prefix behavior of TAB broken

[Stefan Monnier]

> FWIW all indent-line-functions with the exception of `lisp-indent-line'
> either don't have arguments or, like `c-indent-line', `f90-indent-line',
> and `(c)perl-indent-line' expect completely different arguments here.
> Hence a generic solution seems hardly practicable.

I don't see the relation: these modes do not use indent-for-tab-command
and bind TAB to something else instead (except for perl-mode, maybe,
but we can change this one).


        Stefan

Re: C-u prefix behavior of TAB broken

[Stefan Monnier]

>> Can't indent-for-tab-command simply, if there's a prefix argument given,
>> rigidly indent the following sexp by the change in indentation?  That
>> doesn't seem hard at all, and matches the behavior I remember (perhaps
>> there are corner cases where it would differ, but I don't think I know
>> about them...).

> For `tab-always-indent' t it might make sense to do `beginning-of-line'
> before the `forward-sexp'.  Otherwise it should work wherever
> `forward-sexp' behaves reasonably.  BTW, isn't

>    ((memq indent-line-function '(indent-relative indent-relative-maybe))
>     (funcall indent-line-function))
>    ;; Indent the line.
>    (t
>     (indent-according-to-mode))

> semantically equivalent to

>    (t
>     (funcall indent-line-function))

No, it's not: check the definition of indent-according-to-mode.

The difference is to distinguish between the case where the user hits
TAB (and hence wants some kind of effect) as opposed to when
line-indentation is done non-interactively (e.g. by skeleton).


        Stefan

Re: C-u prefix behavior of TAB broken

[Miles Bader]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

>>> Can't indent-for-tab-command simply, if there's a prefix argument given,
>>> rigidly indent the following sexp by the change in indentation?  That
>>> doesn't seem hard at all, and matches the behavior I remember (perhaps
>>> there are corner cases where it would differ, but I don't think I know
>>> about them...).
>
>> For `tab-always-indent' t it might make sense to do `beginning-of-line'
>> before the `forward-sexp'.  Otherwise it should work wherever
>> `forward-sexp' behaves reasonably.  BTW, isn't
>
>>    ((memq indent-line-function '(indent-relative indent-relative-maybe))
>>     (funcall indent-line-function))
>>    ;; Indent the line.
>>    (t
>>     (indent-according-to-mode))
>
>> semantically equivalent to
>
>>    (t
>>     (funcall indent-line-function))
>
> No, it's not: check the definition of indent-according-to-mode.
>
> The difference is to distinguish between the case where the user hits
> TAB (and hence wants some kind of effect) as opposed to when
> line-indentation is done non-interactively (e.g. by skeleton).
>
>         Stefan

But indent-according-to-mode is defined like this:

   (defun indent-according-to-mode ()
      ....
     (if (memq indent-line-function
               '(indent-relative indent-relative-maybe))
               ... do some stuff ...
       ;; The normal case.
       (funcall indent-line-function)))

So this:

   (cond
    ...
    ((memq indent-line-function '(indent-relative indent-relative-maybe))
     (funcall indent-line-function))
    ;; Indent the line.
    (t
     (indent-according-to-mode))

Is equivalent to this:

   (cond
    ...
    ((memq indent-line-function '(indent-relative indent-relative-maybe))
     (funcall indent-line-function))
    ;; Indent the line.
    (t
     (if (memq indent-line-function
               '(indent-relative indent-relative-maybe))
               ... do some stuff ...
       ;; The normal case.
       (funcall indent-line-function)))

and since the first cond branch catches the same cases that the `if'
catches, it will always use the `else' part, meaning it's actually:

   (cond
    ...
    ((memq indent-line-function '(indent-relative indent-relative-maybe))
     (funcall indent-line-function))
    ;; Indent the line.
    (t
     (funcall indent-line-function)))

Which of course is the same as:

   (funcall indent-line-function)


-Miles

-- 
Occam's razor split hairs so well, I bought the whole argument!

Re: C-u prefix behavior of TAB broken

[martin rudalics]

> I don't see the relation: these modes do not use indent-for-tab-command
> and bind TAB to something else instead (except for perl-mode, maybe,
> but we can change this one).

I didn't check them all.  But Miles' patch should permit us to _not_
override the standard binding of TAB in c-mode :-) and I suppose a
similar solution can be found for most other modes too.

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    I meant that

    (defun lisp-indent-line (&optional whole-exp)

    takes one optional argument `whole-exp' that implements the feature.

    (defun c-indent-line (&optional syntax quiet ignore-point-pos)

    takes three completely unrelated arguments and won't implement the
    feature.

Nonetheless, C-u TAB seems to work correctly in C mode.  Whatever
differences there may be in the structure of the code in C mode, this
feature works, and it should continue to work.

Re: C-u prefix behavior of TAB broken

[martin rudalics]

> Nonetheless, C-u TAB seems to work correctly in C mode.

With Emacs -Q C-u TAB doesn't behave differently from TAB in C mode
on my system.  Can you give me some guidance on how to obtain the
"correct" behavior you mention?

Re: C-u prefix behavior of TAB broken

[Stefan Monnier]

>> No, it's not: check the definition of indent-according-to-mode.
[...]
> But indent-according-to-mode is defined like this:
[...]
> Which of course is the same as:
>    (funcall indent-line-function)

Duh, thanks for setting me straight,


        Stefan

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    With Emacs -Q C-u TAB doesn't behave differently from TAB in C mode
    on my system.  Can you give me some guidance on how to obtain the
    "correct" behavior you mention?

It works correctly in the EMACS_22_BASE sources, but it is broken
in the trunk.

Re: C-u prefix behavior of TAB broken

[martin rudalics]

 > It works correctly in the EMACS_22_BASE sources, but it is broken
 > in the trunk.

Because TAB is bound to `c-indent-command' in Emacs 22.  But Miles was
complaining about the _behavior in the trunk_.  FWIW, the following
change broke that:

2007-09-24  Dan Nicolaescu  <dann@ics.uci.edu>

	* progmodes/cc-mode.el (c-mode-base-map):
	Use c-indent-line-or-region instead of c-indent-line.

I think that change should be reverted.  We can always implement the
region-indenting behavior in `c-indent-command'.

Re: C-u prefix behavior of TAB broken

[Miles Bader]

Richard Stallman <rms@gnu.org> writes:
>     This said, IMNSHO the feature we're talking about shouldn't be
>     implement in lisp-mode and c-mode but directly generically in
>     indent-for-tab-command.
>
> If that works, by all means do it.

I've committed the final version of the patch I previously posted here,
which should implement this behavior.

-Miles

-- 
=====
(^o^;
(()))
*This is the cute octopus virus, please copy it into your sig so it can spread.

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

I cleaned up the confusion in c-indent-line-or-region.

I also made `region-active-p' do the same thing it does in XEmacs.
The function to check whether a command should operate on the region
instead of whatever it normally does
is now called `use-region-p'.

I fixed several files whose behavior might have been affected
by the fact that `region-active-p' is now defined in Emacs.

Re: C-u prefix behavior of TAB broken

[Vinicius Jose Latorre]

> I cleaned up the confusion in c-indent-line-or-region.
>
> I also made `region-active-p' do the same thing it does in XEmacs.
> The function to check whether a command should operate on the region
> instead of whatever it normally does
> is now called `use-region-p'.
>
> I fixed several files whose behavior might have been affected
> by the fact that `region-active-p' is now defined in Emacs.
>   

ps-print is one of the files affected.

Does  (mark)  have the same meaning as  (region-active-p)  now?

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    Does  (mark)  have the same meaning as  (region-active-p)  now?

Not the same, but (mark) looks like it is correct there.
It will return nil if no mark has been set in that buffer.
In Transient Mark mode it will signal an error if the mark
is not active, and that is ok too.

Re: C-u prefix behavior of TAB broken

[Juri Linkov]

> I also made `region-active-p' do the same thing it does in XEmacs.

What is the purpose of `region-active-p' in Emacs?  Is it only for
compatibility with XEmacs?  If so, then it seems it is not necessary
since compatibility code checks for (featurep 'xemacs) and as I see
now also for a new function (fboundp 'use-region-p).

> The function to check whether a command should operate on the region
> instead of whatever it normally does is now called `use-region-p'.

Perhaps a better function name could start with the `region-...' prefix
for consistency with other related functions.

-- 
Juri Linkov
http://www.jurta.org/emacs/

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    What is the purpose of `region-active-p' in Emacs?  Is it only for
    compatibility with XEmacs?

Yes, I think that will simplify some code
and avoid the need for conditionals in some places.

Re: C-u prefix behavior of TAB broken

[Richard Stallman]

    > The function to check whether a command should operate on the region
    > instead of whatever it normally does is now called `use-region-p'.

    Perhaps a better function name could start with the `region-...' prefix
    for consistency with other related functions.

That parallelism is desirable, but it is not the only factor in
choosing a good name.  The name `use-region-p' seems good to me, and I
don't see a better one.

Can you suggest another name that you think is better?

Re: C-u prefix behavior of TAB broken

[Juri Linkov]

>     > The function to check whether a command should operate on the region
>     > instead of whatever it normally does is now called `use-region-p'.
>
>     Perhaps a better function name could start with the `region-...' prefix
>     for consistency with other related functions.
>
> That parallelism is desirable, but it is not the only factor in
> choosing a good name.  The name `use-region-p' seems good to me, and I
> don't see a better one.
>
> Can you suggest another name that you think is better?

What about `region-use-p'?  It starts with a prefix `region-' and its
suffix `use-p' is more meaningful than `region-p' in `use-region-p'.

-- 
Juri Linkov
http://www.jurta.org/emacs/

Re: C-u prefix behavior of TAB broken

[Miles Bader]

Juri Linkov <juri@jurta.org> writes:
>> Can you suggest another name that you think is better?
>
> What about `region-use-p'?  It starts with a prefix `region-' and its
> suffix `use-p' is more meaningful than `region-p' in `use-region-p'.

"use-p" doesn't make much sense...

There are multiple naming conventions used in Emacs:  some people like
to rigidly use a "package prefix" style -- e.g. TYPE-FUNNAME -- whereas
a more traditional lisp convention is to instead prefer following
English conventions, which often are of the form "ACTION-TYPE" (for
actions) or "TYPE-PROPERTY" (for queries).

For instance, "make-FOO" is a traditional lisp name, whereas people
coming from other communities often will use something like "FOO-create"
instead to maintain the rigid prefix convention.

Richard's name fits traditional lisp style well.

-Miles

-- 
"Don't just question authority,
Don't forget to question me."
-- Jello Biafra

Re: C-u prefix behavior of TAB broken

[Juri Linkov]

> +      ;; If a prefix argument was given, rigidly indent the following
> +      ;; sexp to match the change in the current line's indentation.
> +      (when arg
> +	(let ((indentation-change (- (current-indentation) old-indent)))
> +	  (unless (zerop indentation-change)
> +	    (save-excursion
> +	      (forward-line 1)
> +	      (when (< (point) end-marker)
> +		(indent-rigidly (point) end-marker indentation-change))))))))))

I have bound a key to the command that calls `indent-for-tab-command'
with a prefix argument, and when I accidently type it a close parenthesis,
it fails with the error "Containing expression ends prematurely".

I think it would be better not to fail at such places, and just indent
the current line without indenting the following sexp.

The following patch fixes this.  Any better ideas?

Index: lisp/indent.el
===================================================================
RCS file: /sources/emacs/emacs/lisp/indent.el,v
retrieving revision 1.76
diff -u -r1.76 indent.el
--- lisp/indent.el	8 Jan 2008 20:44:48 -0000	1.76
+++ lisp/indent.el	24 Feb 2008 19:04:32 -0000
@@ -29,6 +29,8 @@
 
 ;;; Code:
 
+(eval-when-compile (require 'cl)) ;; for `ignore-errors'
+
 (defgroup indent nil
   "Indentation commands."
   :group 'editing)
@@ -109,7 +111,7 @@
     (let ((end-marker
 	   (and arg
 		(save-excursion
-		  (forward-line 0) (forward-sexp) (point-marker))))
+		  (forward-line 0) (ignore-errors (forward-sexp)) (point-marker))))
 	  (old-indent
 	   (current-indentation)))
 
-- 
Juri Linkov
http://www.jurta.org/emacs/

Re: C-u prefix behavior of TAB broken

[Miles Bader]

Juri Linkov <juri@jurta.org> writes:
> I have bound a key to the command that calls `indent-for-tab-command'
> with a prefix argument, and when I accidently type it a close parenthesis,
> it fails with the error "Containing expression ends prematurely".

That sounds correct to me...

> I think it would be better not to fail at such places, and just indent
> the current line without indenting the following sexp.

Wouldn't it be a bit more elegant for you to change your command to
do something like:

   (condition-case err (indent-for-tab-command t)
     (error (indent-for-tab-command)))

?

-Miles

-- 
Ich bin ein Virus. Mach' mit und kopiere mich in Deine .signature.

Re: C-u prefix behavior of TAB broken

[Juri Linkov]

>> I have bound a key to the command that calls `indent-for-tab-command'
>> with a prefix argument, and when I accidently type it a close parenthesis,
>> it fails with the error "Containing expression ends prematurely".
>
> That sounds correct to me...

This is correct, but I thought this is not very useful.

>> I think it would be better not to fail at such places, and just indent
>> the current line without indenting the following sexp.
>
> Wouldn't it be a bit more elegant for you to change your command to
> do something like:
>
>    (condition-case err (indent-for-tab-command t)
>      (error (indent-for-tab-command)))

This is not a problem for me, but I doubted that displaying an error message
would be useful for someone who types `C-u TAB' at the wrong place.

-- 
Juri Linkov
http://www.jurta.org/emacs/

Re: C-u prefix behavior of TAB broken

[Miles Bader]

Juri Linkov <juri@jurta.org> writes:
> This is correct, but I thought this is not very useful.
>
>>    (condition-case err (indent-for-tab-command t)
>>      (error (indent-for-tab-command)))
>
> This is not a problem for me, but I doubted that displaying an error message
> would be useful for someone who types `C-u TAB' at the wrong place.

I dunno, I'd think if someone types C-u before TAB, they do so
intentionally, thinking there's a balanced expression following, and
would like to know if something's screwy.

In the example you gave it's really obvious what the problem is, but
what if there's actually a non-trivial unbalanced expresison following?
It seems useful to give an error that says it can't find a balanced
expression rather than silently ignoring the C-u in that case...

E.g.:

   (hello [
      world)

The error message could be a bit more friendly though...

-Miles

-- 
Love is a snowmobile racing across the tundra.  Suddenly it flips over,
pinning you underneath.  At night the ice weasels come.  --Nietzsche