Apply Emacs-Lisp `font-lock' rules to a string

Apply Emacs-Lisp `font-lock' rules to a string

[Alexander Shukaev]

Assume I have a string somewhere in Emacs-Lisp program.  I want this
string to be propertized in such a way that when I display this string
somewhere, it should have identical highlighting as if it would have
been typed in Emacs-Lisp major mode (with `font-lock').

To expand on the problem, I have a string which contains regular
expression, which I display in the echo area.  It would be nice to
apply standard highlighting to it.  Is there any way to achieve this
smoothly (preferably with one or a few calls to built-in functions)?
Thanks.

Regards,
Alexander

Re: Apply Emacs-Lisp `font-lock' rules to a string

[Emanuel Berg]

Alexander Shukaev <haroogan@gmail.com> writes:

> Assume I have a string somewhere in Emacs-Lisp
> program. I want this string to be propertized in
> such a way that when I display this string
> somewhere, it should have identical highlighting as
> if it would have been typed in Emacs-Lisp major mode
> (with `font-lock').
>
> To expand on the problem, I have a string which
> contains regular expression, which I display in the
> echo area. It would be nice to apply standard
> highlighting to it. Is there any way to achieve this
> smoothly (preferably with one or a few calls to
> built-in functions)? Thanks.

Check out this Lisp I wrote some years ago. Be sure to
evaluate the test forms. If you are into colors, check
out this page as well:

    http://user.it.uu.se/~embe8573/cols/www/index.html

Keep it up!

;; This file: http://user.it.uu.se/~embe8573/cols/www/emacs-test-faces.el

(defun insert-colored-text (str color bright)
  "Insert STR at point, in COLOR, and sometimes BRIGHT."
  (interactive (list (read-string "string: ")
                     (read-string "color: ")
                     (y-or-n-p    "bright? ") ))
  (insert (propertize str 'font-lock-face
                      `(:weight ,(if bright 'bold 'normal) :foreground ,color) )))

;; use this to test
(when nil
  (progn
    (forward-line 1)
    (insert "The French flag is ")
    (insert-colored-text "blue, "   "blue"  t)
    (insert-colored-text "white, "  "white" t)
    (insert-colored-text "and red." "red"   nil) ) ; <- eval me

  )

(defun test-all-faces ()
  "Print a test strings in every color, normal and bright."
  (interactive)
  (forward-line 1)
  (let ((str "This is what it looks like"))
    (dolist (bold '(nil t))
      (dolist (color
               '("black" "red" "green" "yellow" "blue"
                 "magenta" "cyan" "white"))
        (insert-colored-text
         (format "%s in %s (that is %sbold)\n" str color
                 (if bold "" "not ")) color bold) ))))

;; test all colors
;; (test-all-faces) ; <- eval me

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: Apply Emacs-Lisp `font-lock' rules to a string

[John Mastro]

> Assume I have a string somewhere in Emacs-Lisp program.  I want this
> string to be propertized in such a way that when I display this string
> somewhere, it should have identical highlighting as if it would have
> been typed in Emacs-Lisp major mode (with `font-lock').

This seems to work here:

(defun my-font-lock-string (string &optional mode)
  (let ((mode (or mode major-mode)))
    (with-temp-buffer
      (insert string)
      (funcall mode)
      (funcall font-lock-fontify-buffer-function)
      (buffer-string))))

(my-font-lock-string "\"\\\\(1\\\\|2\\\\)\"" #'emacs-lisp-mode)

> To expand on the problem, I have a string which contains regular
> expression, which I display in the echo area.  It would be nice to
> apply standard highlighting to it.  Is there any way to achieve this
> smoothly (preferably with one or a few calls to built-in functions)?
> Thanks.

Hm, maybe not. When I do (message (my-font-lock-string ...)) it prints
the string readably rather than colorized. Hopefully someone else will
know how to get around that.

-- 
john

Re: Apply Emacs-Lisp `font-lock' rules to a string

[Alexander Shukaev]

> This seems to work here:
>
> (defun my-font-lock-string (string &optional mode)
>   (let ((mode (or mode major-mode)))
>     (with-temp-buffer
>       (insert string)
>       (funcall mode)
>       (funcall font-lock-fontify-buffer-function)
>       (buffer-string))))
>
> (my-font-lock-string "\"\\\\(1\\\\|2\\\\)\"" #'emacs-lisp-mode)

Nice!

>> To expand on the problem, I have a string which contains regular
>> expression, which I display in the echo area.  It would be nice to
>> apply standard highlighting to it.  Is there any way to achieve this
>> smoothly (preferably with one or a few calls to built-in functions)?
>> Thanks.
>
> Hm, maybe not. When I do (message (my-font-lock-string ...)) it prints
> the string readably rather than colorized. Hopefully someone else will
> know how to get around that.

There surely must be one as I see that when cursor hovers different
structures of Emacs Lisp code, echo area displays short summary of the
corresponding structures, and that summary is obviously highlighted
according to `font-lock' rules.

Re: Apply Emacs-Lisp `font-lock' rules to a string

[John Mastro]

>> (defun my-font-lock-string (string &optional mode)
>>   (let ((mode (or mode major-mode)))
>>     (with-temp-buffer
>>       (insert string)
>>       (funcall mode)
>>       (funcall font-lock-fontify-buffer-function)
>>       (buffer-string))))
>>
>> (my-font-lock-string "\"\\\\(1\\\\|2\\\\)\"" #'emacs-lisp-mode)
>>
>> Hm, maybe not. When I do (message (my-font-lock-string ...)) it prints
>> the string readably rather than colorized. Hopefully someone else will
>> know how to get around that.
>
> There surely must be one as I see that when cursor hovers different
> structures of Emacs Lisp code, echo area displays short summary of the
> corresponding structures, and that summary is obviously highlighted
> according to `font-lock' rules.

I may have found it. Try this:

(minibuffer-message
 (my-font-lock-string #'emacs-lisp-mode "\"\\\\(1\\\\|2\\\\)\""))

Appears to work as intended, though hopefully someone will still
comment on whether it's the best way to do it.

-- 
john

Re: Apply Emacs-Lisp `font-lock' rules to a string

[John Mastro]

> (minibuffer-message
>  (my-font-lock-string #'emacs-lisp-mode "\"\\\\(1\\\\|2\\\\)\""))

Oops, got the arguments backward there:

(minibuffer-message
 (my-font-lock-string "\"\\\\(1\\\\|2\\\\)\"" #'emacs-lisp-mode))

-- 
john

Re: Apply Emacs-Lisp `font-lock' rules to a string

[Alexander Shukaev]

>> (minibuffer-message
>>  (my-font-lock-string #'emacs-lisp-mode "\"\\\\(1\\\\|2\\\\)\""))
>
> Oops, got the arguments backward there:
>
> (minibuffer-message
>  (my-font-lock-string "\"\\\\(1\\\\|2\\\\)\"" #'emacs-lisp-mode))

Cool!  Thanks, John.  I just want to point out that plain `message'
also works fine if you do it like this (which is recommended anyway,
even in the documentation):

(message "%s" (my-font-lock-string ...))

Regards,
Alexander

Re: Apply Emacs-Lisp `font-lock' rules to a string

[Alexander Shukaev]

>>> (minibuffer-message
>>>  (my-font-lock-string #'emacs-lisp-mode "\"\\\\(1\\\\|2\\\\)\""))
>>
>> Oops, got the arguments backward there:
>>
>> (minibuffer-message
>>  (my-font-lock-string "\"\\\\(1\\\\|2\\\\)\"" #'emacs-lisp-mode))
>
> Cool!  Thanks, John.  I just want to point out that plain `message'
> also works fine if you do it like this (which is recommended anyway,
> even in the documentation):
>
> (message "%s" (my-font-lock-string ...))

Nevertheless, I still can't find a way to make

(user-error "%s" (my-font-lock-string ...))

display colored output.  Any suggestions?

Regards,
Alexander