Tests involving post-command-hook

Tests involving post-command-hook

[Stephen Berman]

I'm using ERT to test for the hl-line face property and it appears that
in the test environment, the function hl-line-highlight is not
automatically run from post-command-hook as it should be, although I use
call-interactively to mimic a command invocation.  It works only if I
explicitly call run-hooks.  I also see this without ERT:

(let ((buf (get-buffer-create "*hl-line-test*")))
  (with-current-buffer buf
    (erase-buffer)
    (insert "This is a test.\n")
    (hl-line-mode)
    (call-interactively (lambda () (interactive) (forward-line -1)))
    ;; (run-hooks 'post-command-hook)
    (if (eq 'hl-line (get-char-property (point) 'face))
	(message "test1 passed")
      (message "test1 failed"))
    (hl-line-mode -1)
    (erase-buffer)
    (insert "This is a test.\n")
    (call-interactively (lambda () (interactive) (forward-line -1)))
    (hl-line-mode)
    (if (eq 'hl-line (get-char-property (point) 'face))
	(message "test2 passed")
      (message "test2 failed"))
    (hl-line-mode -1)
    (erase-buffer)
    (insert "This is line 1.\nThis is line 2.\n")
    (call-interactively (lambda () (interactive) (forward-line -1)))
    (hl-line-mode)
    (if (eq 'hl-line (get-char-property (point) 'face))
	(message "test3.1 passed")
      (message "test3.1 failed"))
    (call-interactively (lambda () (interactive) (forward-line -1)))
    ;; (run-hooks 'post-command-hook)
    (if (eq 'hl-line (get-char-property (point) 'face))
	(message "test3.2 passed")
      (message "test3.2 failed")))
    (hl-line-mode -1))

Evaluating this in emacs -Q or loading it with emacs --batch yields
this:

test1 failed
test2 passed
test3.1 passed
test3.2 failed

The two successful tests are because hl-line-mode calls
hl-line-highlight before adding it to post-command-hook.  Uncommenting
the two (run-hooks 'post-command-hook) lines yields this, which is what
I expected without run-hooks (and what I see when testing without them
interactively):

test1 passed
test2 passed
test3.1 passed
test3.2 passed

Is this behavior of post-command-hook expected and if so, is using
run-hooks in ERT valid, i.e. is it still really testing hl-line-mode
behavior?

Steve Berman

Re: Tests involving post-command-hook

[Noam Postavsky]

On 31 July 2018 at 18:10, Stephen Berman <stephen.berman@gmx.net> wrote:

> Is this behavior of post-command-hook expected and if so, is using
> run-hooks in ERT valid, i.e. is it still really testing hl-line-mode
> behavior?

Asking whether it's "really" testing seems in danger of getting
philosophical, but you might also want to look at ert-simulate-command
which runs those hooks (it doesn't perfectly simulate everything
though).

Re: Tests involving post-command-hook

[Stephen Berman]

On Tue, 31 Jul 2018 19:50:14 -0400 Noam Postavsky <npostavs@gmail.com> wrote:

> On 31 July 2018 at 18:10, Stephen Berman <stephen.berman@gmx.net> wrote:
>
>> Is this behavior of post-command-hook expected and if so, is using
>> run-hooks in ERT valid, i.e. is it still really testing hl-line-mode
>> behavior?
>
> Asking whether it's "really" testing seems in danger of getting
> philosophical, but you might also want to look at ert-simulate-command
> which runs those hooks (it doesn't perfectly simulate everything
> though).

Thanks, this indeed works just like calling run-hooks.  I didn't mean to
wax philosophical, just wondering whether running a hook function
explicitly in a test when it isn't automatically run as expected is
legitimate in the test environment, and given the existence of
ert-simulate-command, I conclude the answer is yes.  Thanks (once again)
for the pointer.

Steve Berman

Re: Tests involving post-command-hook

[Stefan Monnier]

> I'm using ERT to test for the hl-line face property and it appears that
> in the test environment, the function hl-line-highlight is not
> automatically run from post-command-hook as it should be, although I use
> call-interactively to mimic a command invocation.  It works only if I

pre/post-command-hook is run by the command *loop*, not by call-interactively.

The command loop is the chunk of C code which does something like:

    (while t
      (let ((keys (read-key-sequence)))
        (run-hooks 'pre-command-hook)
        (call-interactively (key-binding keys))
        (run-hooks 'post-command-hook)
        (redisplay)))

We don't want call-interactively to run those hooks, because commands
may internally call call-interactively themselves.


        Stefan

Re: Tests involving post-command-hook

[Stephen Berman]

On Wed, 01 Aug 2018 07:51:06 -0400 Stefan Monnier <monnier@iro.umontreal.ca> wrote:

>> I'm using ERT to test for the hl-line face property and it appears that
>> in the test environment, the function hl-line-highlight is not
>> automatically run from post-command-hook as it should be, although I use
>> call-interactively to mimic a command invocation.  It works only if I
>
> pre/post-command-hook is run by the command *loop*, not by call-interactively.
>
> The command loop is the chunk of C code which does something like:
>
>     (while t
>       (let ((keys (read-key-sequence)))
>         (run-hooks 'pre-command-hook)
>         (call-interactively (key-binding keys))
>         (run-hooks 'post-command-hook)
>         (redisplay)))
>
> We don't want call-interactively to run those hooks, because commands
> may internally call call-interactively themselves.

My misunderstanding, thanks for clarifying.  In any case, as Noam
Postavsky pointed out, I can get the job done with ert-simulate-command.

Steve Berman