trouble overwriting C-r in a shell (term-mode)

trouble overwriting C-r in a shell (term-mode)

[Christian Seberino]

I'm trying to overwrite C-r in a shell and it isn't working.
Any help greatly appreciated.  I tried adding a term-mode hook as
follows....

(add-hook 'term-mode-hook
          '(lambda () (interactive)
                   (global-set-key (kbd "C-r")
                                   (lambda () (interactive)
                                              (if (get-buffer  "*Open
Recent*")
                                                  (kill-buffer "*Open
Recent*"))
                                              (recentf-open-files)))))

Thanks!

Chris

Re: trouble overwriting C-r in a shell (term-mode)

[Narendra Joshi]

Christian Seberino <cseberino@gmail.com> writes:

> I'm trying to overwrite C-r in a shell and it isn't working.
> Any help greatly appreciated.  I tried adding a term-mode hook as
> follows....
>
> (add-hook 'term-mode-hook
>           '(lambda () (interactive)
>                    (global-set-key (kbd "C-r")
>                                    (lambda () (interactive)
>                                               (if (get-buffer  "*Open
> Recent*")
>                                                   (kill-buffer "*Open
> Recent*"))
>                                               (recentf-open-files)))))

You can bind "C-r" in the keymap `term-raw-map' to the function: 
--8<---------------cut here---------------start------------->8---
(define-key term-raw-map (kbd "C-r") (lambda () (interactive)
                                       (if (get-buffer  "*Open Recent*")
                                           (kill-buffer "*Open Recent*"))
                                       (recentf-open-files)))
--8<---------------cut here---------------end--------------->8---

When `term-char-mode' is on, `term-raw-map' is activated as the local
map of the term buffer.


> Thanks!
>
> Chris

Best,
-- 
Narendra Joshi

Re: trouble overwriting C-r in a shell (term-mode)

[Christian Seberino]

Narendra

Oh wow.  Thanks so much.  Your code below worked!

cs


> (define-key term-raw-map (kbd "C-r") (lambda () (interactive)
>                                        (if (get-buffer  "*Open Recent*")
>                                            (kill-buffer "*Open Recent*"))
>                                        (recentf-open-files)))
>
>

Re: trouble overwriting C-r in a shell (term-mode)

[Emanuel Berg via Users list for the GNU Emacs text editor]

Narendra Joshi wrote:

> (define-key term-raw-map (kbd "C-r") (lambda () (interactive)
>                                        (if (get-buffer  "*Open Recent*")
>                                            (kill-buffer "*Open Recent*"))
>                                        (recentf-open-files)))

Style points:

  "\C-r" instead of (kbd "C-r")

  `let' so the hard-coded data item "*Open Recent*"
  appears onee time

  `when' instead of `if' as there is no else branch

:)

-- 
underground experts united
http://user.it.uu.se/~embe8573
https://dataswamp.org/~incal

Re: trouble overwriting C-r in a shell (term-mode)

[Jamie Beardslee]

> Style points:
>
>   "\C-r" instead of (kbd "C-r")
>
>   `let' so the hard-coded data item "*Open Recent*"
>   appears onee time
>
>   `when' instead of `if' as there is no else branch

Even more style points:

- don't bind a key to an anonymous function
- buffer name is dependent on `recentf-menu-title'
- use an informative docstring

(defun my-recentf-open-files ()
  "blah blah blah"
  (interactive)
  (let ((buffer (get-buffer (format "*%s*" recentf-menu-title))))
    (when buffer
      (kill-buffer buffer))
    (recentf-open-files)))

(define-key term-raw-map (kbd "C-r") #'my-recentf-open-files)