How to really clear eshell buffer?

How to really clear eshell buffer?

[Florian Lindner]

Hello,

I want to really clear an eshell buffer, which means that all former output is deleted, not just scrolled away.
eshell/clear only scrolls away, eshell-truncate-buffer also does not clear. comint-clear-buffer gives an error message,
probably because eshell is not comint mode.

Thanks,
Florian

Re: How to really clear eshell buffer?

[Bob Newell]

> I want to really clear an eshell buffer, which means that all former output is deleted, not just scrolled away.

(defun clear-eshell ()
(interactive)
(setq inhibit-read-only t)
(kill-region (point-min) (point-max)))

I don't see any real need to switch back to read-only mode.

Tie to a key if you wish and run while in the eshell buffer.





-- 
Bob Newell
Honolulu, Hawai`i

Sent via Linux Mint 17.

Re: How to really clear eshell buffer?

[Colin Baxter]

>>>>> "Bob" == Bob Newell <bobnewell@bobnewell.net> writes:

    >> I want to really clear an eshell buffer, which means that all
    >> former
    Bob> output is deleted, not just scrolled away.

    Bob> (defun clear-eshell () (interactive) (setq inhibit-read-only t)
    Bob> (kill-region (point-min) (point-max)))

    Bob> I don't see any real need to switch back to read-only mode.

    Bob> Tie to a key if you wish and run while in the eshell buffer.
If you do, via say:

(add-hook 'eshell-mode-hook
          (lambda () (local-set-key (kbd "C-l") #'clear-eshell)))

then the eshell prompt is lost - regained if RET is entered.

Best wishes,

Re: How to really clear eshell buffer?

[Colin Baxter]

>>>>> "Colin" == Colin Baxter <m43cap@yandex.com> writes:

>>>>> "Bob" == Bob Newell <bobnewell@bobnewell.net> writes:
    >>> I want to really clear an eshell buffer, which means that all
    >>> former
    Bob> output is deleted, not just scrolled away.

    Bob> (defun clear-eshell () (interactive) (setq inhibit-read-only t)
    Bob> (kill-region (point-min) (point-max)))

    Bob> I don't see any real need to switch back to read-only mode.

    Bob> Tie to a key if you wish and run while in the eshell buffer.
    Colin> If you do, via say:

    Colin> (add-hook 'eshell-mode-hook (lambda () (local-set-key (kbd
    Colin> "C-l") #'clear-eshell)))

    Colin> then the eshell prompt is lost - regained if RET is entered.

Just need to add (eshell-send-input) to the defun. Sorry about the
noise.

Best wishes,

Re: How to really clear eshell buffer?

[Emanuel Berg]

Bob Newell wrote:

>> I want to really clear an eshell buffer,
>> which means that all former output is
>> deleted, not just scrolled away.
>
> (defun clear-eshell ()
> (interactive)
> (setq inhibit-read-only t)
> (kill-region (point-min) (point-max)))
>
> I don't see any real need to switch back to
> read-only mode.

Hit DEL and you'll see the need. (Besides it is
an unexpected side effect not evident from the
function name.)

Second, you also kill the prompt string this
way. Sure, it returns with RET, but this isn't
how one would expect clear to work. It should,
IMO, work just like in a VT with the state
unchanged WRT read-only, and with the prompt
intact, only the material removed!

Thrid, with `kill-region', the material ends up
in the kill ring. Unclear if this is intuitive
or not?

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: How to really clear eshell buffer?

[Emanuel Berg]

(defun eclear ()
  (interactive)
  (let ((inhibit-read-only t))
    (delete-region (point-min) (point-at-bol)) ))

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: How to really clear eshell buffer?

[Emanuel Berg]

> (defun eclear ()
>   (interactive)
>   (let ((inhibit-read-only t))
>     (delete-region (point-min) (point-at-bol)) ))

In the thread about ERC, the question was
raised why one couldn't just throw away the IRC
logs and be done with it.

Here, the question is the same, only opposite,
why would one want to throw the previous work
and IO away?

I remember using the Linux VT before I learned
about tmux [1], it was very annoying that one
could never scroll back to see information
already processed. Note that this limitation
was always there, and one didn't even have to
(ab)use clear, still, using clear this way
brings me back to that very
frustrated situation.

To clear the screen to clear one's thoughts,
i.e. to focus, is one thing, but then why is it
necessary to remove the material altogether,
why isn't just hiding it above enough?

[1] I hear one can do the same with screen and
    probably some other software as well.

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: How to really clear eshell buffer?

[Bob Newell]

> (defun eclear ()
>   (interactive)
>   (let ((inhibit-read-only t))
>     (delete-region (point-min) (point-at-bol)) ))

Much better in many ways. It doesn't disturb the kill-ring and limits
the scope of inhibit-read-only. Thank you. Please realize that I threw
something together in literally one minute, and I am the first to say
that I still have much to learn.

One thing I question, though ... what you have here preserves the
prompt but assumes that point is on the prompt line. This is probably
the normal case but it is not the universal case. I suppose one could
go to point-max and then back up a line, but for such an odd use case,
I wonder how much perfection is necessary.

-- 
Bob Newell
Honolulu, Hawai`i

Sent via Linux Mint 17.

Re: How to really clear eshell buffer?

[Emanuel Berg]

Bob Newell wrote:

> One thing I question, though ... what you
> have here preserves the prompt but assumes
> that point is on the prompt line. This is
> probably the normal case but it is not the
> universal case. I suppose one could go to
> point-max and then back up a line, but for
> such an odd use case, I wonder how much
> perfection is necessary.

Aha, it was assumed that the user types
"eclear" and hits RET, but OK, now it should
work as an arbitrary command as well:

(defun eclear ()
  (interactive)
  (goto-char (point-max))
  (let ((inhibit-read-only t))
    (delete-region (point-min) (point-at-bol)) ))

Perhaps too arbitrary BTW - perhaps one should
add a guard that confirms that the mode is
EShell, because otherwise one could get used
to it (to invoke it like any command, not type
"ecelar" and hit RET) and then by mistake
"clear" some other useful buffer that way.

DANGER

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: How to really clear eshell buffer?

[Emanuel Berg]

> Perhaps too arbitrary BTW - perhaps one should
> add a guard that confirms that the mode is
> EShell, because otherwise one could get used
> to it (to invoke it like any command, not type
> "ecelar" and hit RET) and then by mistake
> "clear" some other useful buffer that way.

(defun eclear ()
  (interactive)
  (when (eq major-mode 'eshell-mode)
    (goto-char (point-max))
    (let ((inhibit-read-only t))
      (delete-region (point-min) (point-at-bol)) )))

-- 
underground experts united
http://user.it.uu.se/~embe8573