Re: [PATCH] Flymake Support Indicator Errors in Margin

[Elijah G <eg642616@gmail.com>]

[-- Attachment #1.1: Type: text/plain, Size: 1753 bytes --]

On Wed, Mar 13, 2024 at 6:18 AM Eli Zaretskii <eliz@gnu.org> wrote:

> > From: Elijah G <eg642616@gmail.com>
> > Date: Tue, 12 Mar 2024 11:22:04 -0600
> > Cc: emacs-devel@gnu.org
> >
> > Thank you, I've fixed my patch.
>
> Thanks, I have a few more comments below.
>
> > Also I merged every flymake *-bitmap variable
> > into a single user option.
>
> I think this is a mistake: it makes this change backward-incompatible,
> in the sense that users who had customizations of the options you are
> removing will now have to rework their customizations.  We try to
> avoid backward-incompatible changes like this as much as possible.  It
> doesn't sound to me like this part of the patch is strictly needed, is
> it?
>

You are right, i was planning something like marking those variables as
deprecated for 30,
but since it makes backward incompatible think it can be too early to do it
in this patch,
However I find merging them easier to customize instead of defining them
separately.

If these variables are necessary, I've now reverted the changes in the
patch.

> +  :type '(choice (const :tag "Use Fringes" fringes)
> > +                 (const :tag "Use Margins "margins)
>                                             ^^
> A typo there.
>

Thanks, I've fixed it.

> +(defcustom flymake-margin-indicators-string '((error "‼"
> compilation-error)
>
> This is a non-ASCII character, so we should either use its ASCII
> equivalent "!!" or test the display for being able to show it on the
> screen (since it is likely the margin indicator will be used on TTY
> frames).
>
> Please also accompany your patch with the ChangeLog-style commit log
> message (see the file CONTRIBUTE for the details).
>

[-- Attachment #1.2: Type: text/html, Size: 2720 bytes --]

[-- Attachment #2: 0001-Flymake-Support-Indicator-Errors-in-Margin.patch --]
[-- Type: application/octet-stream, Size: 6809 bytes --]

From f02877c60337fd873fb04af2563e063d05762d48 Mon Sep 17 00:00:00 2001
From: Elias G <eg642616@gmail.com>
Date: Mon, 11 Mar 2024 13:35:06 -0600
Subject: [PATCH] Flymake Support Indicator Errors in Margin

Add support for displaying flymake errors in margin which
allows displaying in both graphical and text displays

* lisp/progmodes/flymake.el (flymake-margin-indicators-string,
flymake-indicator-type): New.
(flymake--fringe-overlay-spec, flymake--equal-diagnostic-p): Rework.
(flymake-error, flymake-warning, flymake-note): Use new margin value.
---
 lisp/progmodes/flymake.el | 93 +++++++++++++++++++++++++++++++++------
 1 file changed, 79 insertions(+), 14 deletions(-)

diff --git a/lisp/progmodes/flymake.el b/lisp/progmodes/flymake.el
index db00cc59c0e..da7e0079fc6 100644
--- a/lisp/progmodes/flymake.el
+++ b/lisp/progmodes/flymake.el
@@ -180,6 +180,52 @@ See `flymake-error-bitmap' and `flymake-warning-bitmap'."
 		 (const right-fringe)
 		 (const :tag "No fringe indicators" nil)))
 
+(defcustom flymake-indicator-type 'fringes
+  "Indicate which indicator type to use for display errors.
+
+The value can be nil (dont indicate errors but just highlight them),
+fringes (use fringes) or margins (use margins)
+
+Difference between fringes and margin is that fringes support diplaying
+bitmaps on graphical displays and margins display text in a blank area
+of buffer that works in both graphical and text displays.
+
+See Info node `Fringes' and Info node `(elisp)Display Margins'."
+  :version "30.1"
+  :type '(choice (const :tag "Use Fringes" fringes)
+                 (const :tag "Use Margins" margins)
+                 (const :tag "No indicators" nil)))
+
+(defcustom flymake-margin-indicators-string
+  `((error ,(if (char-displayable-p 8252)
+               "‼"
+             "!!")
+     compilation-error)
+    (warning "!" compilation-warning)
+    (note "!" compilation-info))
+  "Strings used for margins indicators.
+The value of each list may be a list of 3 elements where specifies the
+error type, its string to use and its face,
+or a list of 2 elements specifying only the error type and its string.
+
+The option `flymake-margin-indicator-position' controls how and where
+this is used."
+  :version "30.1"
+  :type '(repeat :tag "Error types lists"
+                 (list :tag "String and face for error types"
+                       (symbol :tag "Error type")
+                       (string :tag "String")
+                       (face :tag "Face"))))
+
+(defcustom flymake-margin-indicator-position 'left-margin
+  "The position to put Flymake margin indicator.
+The value can be nil (do not use indicators), `left-margin' or `right-margin'.
+See `flymake-error-margin-string' and `flymake-warning-margin-string'."
+  :version "30.1"
+  :type '(choice (const left-margin)
+                 (const right-margin)
+                 (const :tag "No margin indicators" nil)))
+
 (make-obsolete-variable 'flymake-start-syntax-check-on-newline
 		        "can check on newline in post-self-insert-hook"
                         "27.1")
@@ -630,6 +676,7 @@ Node `(Flymake)Flymake error types'"
 
 (put 'flymake-error 'face 'flymake-error)
 (put 'flymake-error 'flymake-bitmap 'flymake-error-bitmap)
+(put 'flymake-error 'flymake-margin-string (alist-get 'error flymake-margin-indicators-string))
 (put 'flymake-error 'severity (warning-numeric-level :error))
 (put 'flymake-error 'mode-line-face 'flymake-error-echo)
 (put 'flymake-error 'echo-face 'flymake-error-echo)
@@ -638,6 +685,7 @@ Node `(Flymake)Flymake error types'"
 
 (put 'flymake-warning 'face 'flymake-warning)
 (put 'flymake-warning 'flymake-bitmap 'flymake-warning-bitmap)
+(put 'flymake-warning 'flymake-margin-string (alist-get 'warning flymake-margin-indicators-string))
 (put 'flymake-warning 'severity (warning-numeric-level :warning))
 (put 'flymake-warning 'mode-line-face 'flymake-warning-echo)
 (put 'flymake-warning 'echo-face 'flymake-warning-echo)
@@ -646,6 +694,7 @@ Node `(Flymake)Flymake error types'"
 
 (put 'flymake-note 'face 'flymake-note)
 (put 'flymake-note 'flymake-bitmap 'flymake-note-bitmap)
+(put 'flymake-note 'flymake-margin-string (alist-get 'note flymake-margin-indicators-string))
 (put 'flymake-note 'severity (warning-numeric-level :debug))
 (put 'flymake-note 'mode-line-face 'flymake-note-echo)
 (put 'flymake-note 'echo-face 'flymake-note-echo)
@@ -682,19 +731,32 @@ associated `flymake-category' return DEFAULT."
   (flymake--lookup-type-property type 'severity
                                  (warning-numeric-level :error)))
 
-(defun flymake--fringe-overlay-spec (bitmap &optional recursed)
-  (if (and (symbolp bitmap)
-           (boundp bitmap)
-           (not recursed))
-      (flymake--fringe-overlay-spec
-       (symbol-value bitmap) t)
-    (and flymake-fringe-indicator-position
-         bitmap
-         (propertize "!" 'display
-                     (cons flymake-fringe-indicator-position
-                           (if (listp bitmap)
-                               bitmap
-                             (list bitmap)))))))
+(defun flymake--fringe-overlay-spec (indicator)
+  "Return INDICATOR as propertized string to use in error indicators."
+  (let* ((value (if (symbolp indicator)
+                    (symbol-value indicator)
+                  indicator))
+         (indicator-car (if (listp value)
+                            (car value)
+                          value))
+         (indicator-cdr (if (listp value)
+                            (cdr value))))
+    (cond
+     ((symbolp indicator-car)
+      (propertize "!" 'display
+                  (cons flymake-fringe-indicator-position
+                        (if (listp value)
+                            value
+                          (list value)))))
+     ((stringp indicator-car)
+      (propertize "!"
+                  'display
+                  `((margin ,flymake-margin-indicator-position)
+                    ,(propertize
+                      indicator-car
+                      'face
+                      `(:inherit (,indicator-cdr
+                                  default)))))))))
 
 (defun flymake--equal-diagnostic-p (a b)
   "Tell if A and B are equivalent `flymake--diag' objects."
@@ -843,7 +905,10 @@ Return nil or the overlay created."
         (flymake--fringe-overlay-spec
          (flymake--lookup-type-property
           type
-          'flymake-bitmap
+          (cond ((eq flymake-indicator-type 'fringes)
+                 'flymake-bitmap)
+                ((eq flymake-indicator-type 'margins)
+                 'flymake-margin-string))
           (alist-get 'bitmap (alist-get type ; backward compat
                                         flymake-diagnostic-types-alist)))))
       ;; (default-maybe 'after-string
-- 
2.44.0.windows.1