How to get the current column regardless of the content of the current line?

How to get the current column regardless of the content of the current line?

[Rodrigo Morales]

Table of Contents
_________________

1. The context
2. The question
3. The current workaround
4. Additional information

1 The context
=============

  I'm aware that `current-column' returns the column of the cursor
  position. See two minimal working examples below.

  ,----
  | (with-temp-buffer
  |   (insert "foo")
  |   (end-of-line)
  |   (princ (current-column)))
  `----

  ,----
  | 1
  `----

  ,----
  | (with-temp-buffer
  |   (insert "foofoo")
  |   (end-of-line)
  |   (princ (current-column)))
  `----

  ,----
  | 6
  `----

  Sometimes, `current-column' considers one character as if it were
  two. In the minimal working example below, you can see that the line
  contains `你' (U+4F60) 3 times and `current-column' returns 6 when it
  is at the end of the line.

  ,----
  | (with-temp-buffer
  |   (insert "你你你")
  |   (end-of-line)
  |   (princ (current-column)))
  `----

  ,----
  | 6
  `----

  In the minimal working example below, you can see that even though the
  line contains two characters, `current-column' returns `3'. This
  happens because, as shown in the previous example, `你' is counted as
  two characters by `current-column'.

  ,----
  | (with-temp-buffer
  |   (insert "a你")
  |   (end-of-line)
  |   (princ (current-column)))
  `----

  ,----
  | 3
  `----


2 The question
==============

  Which function could I use to obtain the column of the current
  position that would work for any line regardless of its content?


3 The current workaround
========================

  I have written the following function to get the results that I
  expect. However, I decided to open this thread just in case there's
  another (preferably, shorter or built-in) function that any of you
  might know.

  ,----
  | (defun my/current-column ()
  |   (save-excursion
  |     ;; Save the current point
  |     (let ((orig (point))
  |           (counter 0))
  |       (beginning-of-line)
  |       ;; Count the number of characters from the beginning of the line
  |       ;; to the previously stored point
  |       (while (and (<= (point) orig)
  |                   (not (eobp)))
  |         (setq counter (1+ counter))
  |         (forward-char))
  |       counter)))
  `----

  The following code blocks contains minimal working examples that show
  the results of this function.

  ,----
  | (with-temp-buffer
  |   (insert "你你你")
  |   (my/current-column))
  `----

  ,----
  | 3
  `----

  ,----
  | (with-temp-buffer
  |   (insert "a你")
  |   (my/current-column))
  `----

  ,----
  | 2
  `----


4 Additional information
========================

  I opened a thread in the bug-gnu-emacs mailing list, because I thought
  that there was a bug in `current-column', and Eli Zaretskii explained
  some details of this function. You can find the thread in this link at
  the archives:
  <https://lists.gnu.org/archive/html/bug-gnu-emacs/2022-12/msg01524.html>

Re: How to get the current column regardless of the content of the current line?

[Gregory Heytings]

>
> Which function could I use to obtain the column of the current position 
> that would work for any line regardless of its content?
>

(defun my/current-column ()
   (- (point) (progn (save-excursion (beginning-of-line) (point)))))

Re: How to get the current column regardless of the content of the current line?

[Gregory Heytings]

>> Which function could I use to obtain the column of the current position 
>> that would work for any line regardless of its content?
>
> (defun my/current-column ()
>   (- (point) (progn (save-excursion (beginning-of-line) (point)))))
>

Sorry, the progn is unnecessary:

(defun my/current-column ()
   (- (point) (save-excursion (beginning-of-line) (point))))

Re: How to get the current column regardless of the content of the current line?

[Stefan Monnier via Users list for the GNU Emacs text editor]

> (defun my/current-column ()
>   (- (point) (save-excursion (beginning-of-line) (point))))
               ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
               (line-beginning-position)

-- Stefan

Re: How to get the current column regardless of the content of the current line?

[Emanuel Berg]

Stefan Monnier via Users list for the GNU Emacs text editor wrote:

>> (defun my/current-column ()
>>   (- (point) (save-excursion (beginning-of-line) (point))))
>                ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
>                (line-beginning-position)

(pos-bol)?

-- 
underground experts united
https://dataswamp.org/~incal

Re: How to get the current column regardless of the content of the current line?

[Gregory Heytings]

>> (defun my/current-column ()
>>   (- (point) (save-excursion (beginning-of-line) (point))))
>               ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
>               (line-beginning-position)
>
> -- Stefan
>

Indeed.  Or even 'pos-bol':

(defun my/current-column ()
   (- (point) (pos-bol)))

Re: How to get the current column regardless of the content of the current line?

[Rodrigo Morales]

Thanks! That works well.

On Thu, Dec 15, 2022 at 4:41 PM Gregory Heytings <gregory@heytings.org>
wrote:

>
> >> Which function could I use to obtain the column of the current position
> >> that would work for any line regardless of its content?
> >
> > (defun my/current-column ()
> >   (- (point) (progn (save-excursion (beginning-of-line) (point)))))
> >
>
> Sorry, the progn is unnecessary:
>
> (defun my/current-column ()
>    (- (point) (save-excursion (beginning-of-line) (point))))
>
>

Re: How to get the current column regardless of the content of the current line?

[Jean Louis]

Tell me how did you format your email with table of contents?

Jean

Re: How to get the current column regardless of the content of the current line?

[Eli Zaretskii]

> Date: Thu, 15 Dec 2022 22:02:59 +0000
> From: Gregory Heytings <gregory@heytings.org>
> cc: help-gnu-emacs@gnu.org
> 
> 
> >> (defun my/current-column ()
> >>   (- (point) (save-excursion (beginning-of-line) (point))))
> >               ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
> >               (line-beginning-position)
> >
> > -- Stefan
> >
> 
> Indeed.  Or even 'pos-bol':
> 
> (defun my/current-column ()
>    (- (point) (pos-bol)))

It's not entirely correct to call this a "column", though...

Re: How to get the current column regardless of the content of the current line?

[Gregory Heytings]

>> (defun my/current-column ()
>>    (- (point) (pos-bol)))
>
> It's not entirely correct to call this a "column", though...
>

That's what the OP wanted, indeed it's not a "column" in the visual sense 
anymore (e.g. a TAB counts for 1), but it's still a "column" in a "number 
of characters" sense.  Well, almost: when glyphs are composed, that 
function will not give the result the OP expects I think, e.g. with a line 
with only "🧙🏻" 2 is returned.

Re: How to get the current column regardless of the content of the current line?

[Rodrigo Morales]

> Tell me how did you format your email with table of contents?

I wrote the email in an org-mode buffer, then

1. Press C-c C-e (by defualt, bound to org-export-dispatch)
2. Press "t" to choose "Export to plain text"
3. Press "A" to choose "As ASCII buffer"
4. Copy the content in the buffer "*Org ASCII Export*" in my mail
   client and send the email.

I also use Org Mode to write Markdown (i.e. issues in Gitlab, Github,
etc.). After I finish writing it in an Org Mode buffer, I export it to
Markdown and use the export as desired.

On Fri, Dec 16, 2022 at 12:12 AM Jean Louis <bugs@gnu.support> wrote:

> Tell me how did you format your email with table of contents?
>
> Jean
>

Re: How to get the current column regardless of the content of the current line?

[Emanuel Berg]

Gregory Heytings wrote:

>>> (defun my/current-column ()
>>>    (- (point) (pos-bol)))
>>
>> It's not entirely correct to call this a "column", though...
>
> That's what the OP wanted, indeed it's not a "column" in the
> visual sense anymore (e.g. a TAB counts for 1), but it's
> still a "column" in a "number of characters" sense.

One shouldn't use tabs anyway ...

-- 
underground experts united
https://dataswamp.org/~incal

Re: How to get the current column regardless of the content of the current line?

[Jean Louis]

* Rodrigo Morales <moralesrodrigo1100@gmail.com> [2022-12-16 20:45]:
> > Tell me how did you format your email with table of contents?
> 
> I wrote the email in an org-mode buffer, then
> 
> 1. Press C-c C-e (by defualt, bound to org-export-dispatch)
> 2. Press "t" to choose "Export to plain text"
> 3. Press "A" to choose "As ASCII buffer"
> 4. Copy the content in the buffer "*Org ASCII Export*" in my mail
>    client and send the email.
> 
> I also use Org Mode to write Markdown (i.e. issues in Gitlab, Github,
> etc.). After I finish writing it in an Org Mode buffer, I export it to
> Markdown and use the export as desired.

Ah, yes, that is Org type of export. Thanks. I was thinking there is
some other mode.

-- 
Jean

Take action in Free Software Foundation campaigns:
https://www.fsf.org/campaigns

In support of Richard M. Stallman
https://stallmansupport.org/

Re: How to get the current column regardless of the content of the current line?

[Emanuel Berg]

Jean Louis wrote:

> Ah, yes, that is Org type of export. Thanks. I was thinking
> there is some other mode.

No ToS for mails.

Send one mail per section instead, and put the section name as
the mail's Subject.

-- 
underground experts united
https://dataswamp.org/~incal

Re: How to get the current column regardless of the content of the current line?

[Emanuel Berg]

>> Ah, yes, that is Org type of export. Thanks. I was thinking
>> there is some other mode.
>
> No ToS for mails.

*ToC

-- 
underground experts united
https://dataswamp.org/~incal