From: Peter Dyballa <Peter_Dyballa@Web.DE>
To: Yuan Luo <yuan.hypnos.luo@gmail.com>
Cc: help-gnu-emacs@gnu.org
Subject: Re: install lmtypewriter fonts for emacs on CentOS/RHEL
Date: Mon, 16 Jan 2012 01:10:39 +0100 [thread overview]
Message-ID: <B05742FD-A693-4CC8-89A6-D630204A1C26@Web.DE> (raw)
In-Reply-To: <CAMY509noctBTPS7mGQGQuHgxE3P+JQqz5zb_GuUnvp6ThmJK9w@mail.gmail.com>
Am 15.1.2012 um 23:37 schrieb Yuan Luo:
> How to get them for CentOS/RHEL
TRAMP?
> and is there any configuration after
> installation to enable emacs to use them?
Put them somewhere the X server can find them, if necessary create the fonts.* files and encodings.dir, extend if necessary the X server's font path, make it rehash the fonts – and check! (xlsfonts, xfontsel)
Make them also available to the libfontconfig service and put them into its cache (with fc-cache) – and check! (fc-list, fc-match)
Inside GNU Emacs you can use this code from Miles Bader to check whether GNU Emacs sees the fonts:
;;; ----------------------------------------------------------------
;;; list-fonts-display via font-config
(defun list-fonts-display (&optional matching)
"Display a list of font-families available via font-config, in a new buffer.
If the optional argument MATCHING is non-nil, only font families
matching that regexp are displayed; interactively, a prefix
argument will prompt for the regexp.
The name of each font family is displayed using that family, as
well as in the default font (to handle the case where a font
cannot be used to display its own name)."
(interactive
(list
(and current-prefix-arg
(read-string "Display font families matching regexp: "))))
(let (families)
(with-temp-buffer
(shell-command "fc-list : family" t)
(goto-char (point-min))
(while (not (eobp))
(let ((fam (buffer-substring (line-beginning-position)
(line-end-position))))
(when (or (null matching) (string-match matching fam))
(push fam families)))
(forward-line)))
(setq families
(sort families
(lambda (x y) (string-lessp (downcase x) (downcase y)))))
(let ((buf (get-buffer-create "*Font Families*")))
(with-current-buffer buf
(erase-buffer)
(dolist (family families)
;; We need to pick one of the comma-separated names to
;; actually use the font; choose the longest one because some
;; fonts have ambiguous general names as well as specific
;; ones.
(let ((family-name
(car (sort (split-string family ",")
(lambda (x y) (> (length x) (length y))))))
(nice-family (replace-regexp-in-string "," ", " family)))
(insert (concat (propertize nice-family
'face (list :family family-name))
" (" nice-family ")"))
(newline)))
(goto-char (point-min)))
(display-buffer buf))))
;; --------------------------------------------------------
--
Greetings
Pete
"Evolution" o __o _o _
°\___o /0~ -\<, ^\___ /=\\_/-%
oo~_______ /\ /\______/ \_________O/ O_______________o===>-->O--o____
prev parent reply other threads:[~2012-01-16 0:10 UTC|newest]
Thread overview: 2+ messages / expand[flat|nested] mbox.gz Atom feed top
2012-01-15 22:37 install lmtypewriter fonts for emacs on CentOS/RHEL Yuan Luo
2012-01-16 0:10 ` Peter Dyballa [this message]
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=B05742FD-A693-4CC8-89A6-D630204A1C26@Web.DE \
--to=peter_dyballa@web.de \
--cc=help-gnu-emacs@gnu.org \
--cc=yuan.hypnos.luo@gmail.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.