[PATCH] Add org-babel support for hledger

[PATCH] Add org-babel support for hledger

[Simon Michael]

Hello all, thanks for org-mode. 

I'd like org-babel to support hledger for generating financial reports, similar to the existing support for Ledger. 

I don't know the exact process to follow (instructions in the git repo, on the website and in irc are different) and have not yet signed FSF copyright assignment - any help appreciated. Below is the output of git format-patch.

Best,
-Simon


From 4b9348d9b8eaecea948b4295776d4f33e1d43c0d Mon Sep 17 00:00:00 2001
From: Simon Michael <simon@joyful.com>
Date: Sat, 18 Feb 2017 18:14:54 +0000
Subject: [PATCH] Add org-babel support for hledger

* lisp/ob-hledger.el:
* lisp/org.el (org-babel-load-languages):
* lisp/ox-html.el (org-html-style-default): allow calling hledger from org-babel
---
 lisp/ob-hledger.el | 70 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 lisp/org.el        |  1 +
 lisp/ox-html.el    |  1 +
 3 files changed, 72 insertions(+)
 create mode 100644 lisp/ob-hledger.el

diff --git a/lisp/ob-hledger.el b/lisp/ob-hledger.el
new file mode 100644
index 000000000..90c6fa981
--- /dev/null
+++ b/lisp/ob-hledger.el
@@ -0,0 +1,70 @@
+;;; ob-hledger.el --- org-babel functions for hledger
+
+;; Copyright (C) 2010-2017 Free Software Foundation, Inc.
+
+;; Author: Simon Michael
+;; Keywords: literate programming, reproducible research, plain text accounting
+;; Homepage: http://orgmode.org
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Org-Babel support for evaluating hledger entries.
+;;
+;; Based on ob-ledger.el.  
+;; If the source block is empty, hledger will use a default journal file,
+;; probably ~/.hledger.journal (it may not notice your $LEDGER_FILE env var).
+;; So make ~/.hledger.journal a symbolic link to the real file if necessary.
+
+;;; Code:
+(require 'ob)
+
+(defvar org-babel-default-header-args:hledger
+  '((:results . "output") (:exports . "results") (:cmdline . "bal"))
+  "Default arguments to use when evaluating a hledger source block.")
+
+(defun org-babel-execute:hledger (body params)
+  "Execute a block of hledger entries with org-babel.  This function is
+called by `org-babel-execute-src-block'."
+  (message "executing hledger source code block")
+  (let ((result-params (split-string (or (cdr (assoc :results params)) "")))
+	(cmdline (cdr (assoc :cmdline params)))
+        (in-file (org-babel-temp-file "hledger-"))
+	(out-file (org-babel-temp-file "hledger-output-")))
+    (with-temp-file in-file (insert body))
+    (message "%s" (concat "hledger"
+                          (if (> (length body) 0)
+                              (concat " -f " (org-babel-process-file-name in-file))
+                            "")
+                          " " cmdline))
+    (with-output-to-string
+      (shell-command (concat "hledger"
+                             (if (> (length body) 0)
+                                 (concat " -f " (org-babel-process-file-name in-file))
+                               "")
+                             " " cmdline
+                             " > " (org-babel-process-file-name out-file))))
+    (with-temp-buffer (insert-file-contents out-file) (buffer-string))))
+
+(defun org-babel-prep-session:hledger (session params)
+  (error "hledger does not support sessions"))
+
+(provide 'ob-hledger)
+
+
+
+;;; ob-hledger.el ends here
diff --git a/lisp/org.el b/lisp/org.el
index 3290a2b96..0afd37360 100644
--- a/lisp/org.el
+++ b/lisp/org.el
@@ -268,6 +268,7 @@ requirements) is loaded."
 		 (const :tag "Fortran" fortran)
 		 (const :tag "Gnuplot" gnuplot)
 		 (const :tag "Haskell" haskell)
+		 (const :tag "hledger" hledger)
 		 (const :tag "IO" io)
 		 (const :tag "J" J)
 		 (const :tag "Java" java)
diff --git a/lisp/ox-html.el b/lisp/ox-html.el
index 0ca19ef45..f629cbd52 100644
--- a/lisp/ox-html.el
+++ b/lisp/ox-html.el
@@ -333,6 +333,7 @@ for the JavaScript code in this tag.
   pre.src-fortran:before { content: 'Fortran'; }
   pre.src-gnuplot:before { content: 'gnuplot'; }
   pre.src-haskell:before { content: 'Haskell'; }
+  pre.src-hledger:before { content: 'hledger'; }
   pre.src-java:before { content: 'Java'; }
   pre.src-js:before { content: 'Javascript'; }
   pre.src-latex:before { content: 'LaTeX'; }
-- 
2.11.0

Re: [PATCH] Add org-babel support for hledger

[Nicolas Goaziou]

Hello,

Simon Michael <simon@joyful.com> writes:

> I'd like org-babel to support hledger for generating financial
> reports, similar to the existing support for Ledger.

Thank you. I'll happily merge it with the code base after some details
are sorted out.

> I don't know the exact process to follow (instructions in the git
> repo, on the website and in irc are different) and have not yet signed
> FSF copyright assignment - any help appreciated.

The first step is to sign the FSF copyright assignment since the patch
is non-trivial. Then we can apply the patch.

An entry in ORG-NEWS file would be great. It can be sent separately from
the patch, or with it, as you see fit. Unit tests are more than welcome,
too.

> Below is the output of git format-patch.

Some comments follow.

> +;;; ob-hledger.el --- org-babel functions for hledger

It is a common mistake across code base, but it should be: Org Babel ...
or simply Babel ...

Also, you should activate lexical binding:

  ob-ledger.el --- Babel Functions for hledger      -*- lexical-binding: t; -*-  

> +;; Org-Babel support for evaluating hledger entries.

See above.

> +(defun org-babel-execute:hledger (body params)
> +  "Execute a block of hledger entries with org-babel.  This function is
> +called by `org-babel-execute-src-block'."

The first line of a docstring needs to be a sentence on its own. So,

      Execute a block of hledger entries with Babel.  
   This function is   called by `org-babel-execute-src-block'."

> +  (message "executing hledger source code block")
> +  (let ((result-params (split-string (or (cdr (assoc :results params)) "")))

assoc -> assq

> +	(cmdline (cdr (assoc :cmdline params)))

Ditto.

> +        (in-file (org-babel-temp-file "hledger-"))
> +	(out-file (org-babel-temp-file "hledger-output-")))
> +    (with-temp-file in-file (insert body))
> +    (message "%s" (concat "hledger"
> +                          (if (> (length body) 0)
> +                              (concat " -f " (org-babel-process-file-name in-file))
> +                            "")
> +                          " " cmdline))
> +    (with-output-to-string
> +      (shell-command (concat "hledger"
> +                             (if (> (length body) 0)
> +                                 (concat " -f " (org-babel-process-file-name in-file))
> +                               "")
> +                             " " cmdline
> +                             " > " (org-babel-process-file-name out-file))))

This is calling for some refactoring:

  (concat "hledger" (if ...) " " cmdline)

could be built only once and bound to a symbol.


Regards,

-- 
Nicolas Goaziou