Mix of completing-read and read-string

Mix of completing-read and read-string

[Johan Andersson]

[-- Attachment #1: Type: text/plain, Size: 227 bytes --]

Hi!

I'm looking for a function that is a mix of read-string and completing-read.
I want completion and I want to be able to input anything, such as spaces.
Is there any such function or do I have to write one myself?

Thanks!

[-- Attachment #2: Type: text/html, Size: 248 bytes --]

RE: Mix of completing-read and read-string

[Drew Adams]

> I'm looking for a function that is a mix of read-string
> and completing-read. I want completion and I want to be
> able to input anything, such as spaces. Is there any such
> function or do I have to write one myself?

1. Use lax completion (`completing-read' with nil as the REQUIRE-MATCH argument.

2. Use a keymap that has SPC bound to `self-insert-command'.

You can do #2 by binding `minibuffer-local-completion-map' (so it is restored
afterward), and doing (define-key minibuffer-local-completion-map " "
'self-insert-command).

IOW, something like this:

(defun my-read-string-completing (prompt collection
                                  &optional predicate
                                  init hist def i-i-m)
  "..."
  (let ((minibuffer-local-completion-map
         minibuffer-local-completion-map))
    (define-key minibuffer-local-completion-map
                " " 'self-insert-command)
    (completing-read prompt collection 
                     predicate nil init def hist i-i-m)))

You would call the function with a COLLECTION argument that is a list of strings
(Emacs 22+) or a list of singleton string lists (all versions). E.g.:

(my-read-string-completing "String: "
  '(("alpha") ("beta") ("gamma")))

(If you use Icicles, `icicle-read-string-completing' does this.)

Re: Mix of completing-read and read-string

[Johan Andersson]

[-- Attachment #1: Type: text/plain, Size: 1482 bytes --]

Thanks a lot Drew. Exactly what I was looking for!

On Sun, Feb 8, 2009 at 5:09 AM, Drew Adams <drew.adams@oracle.com> wrote:

> > I'm looking for a function that is a mix of read-string
> > and completing-read. I want completion and I want to be
> > able to input anything, such as spaces. Is there any such
> > function or do I have to write one myself?
>
> 1. Use lax completion (`completing-read' with nil as the REQUIRE-MATCH
> argument.
>
> 2. Use a keymap that has SPC bound to `self-insert-command'.
>
> You can do #2 by binding `minibuffer-local-completion-map' (so it is
> restored
> afterward), and doing (define-key minibuffer-local-completion-map " "
> 'self-insert-command).
>
> IOW, something like this:
>
> (defun my-read-string-completing (prompt collection
>                                  &optional predicate
>                                  init hist def i-i-m)
>  "..."
>  (let ((minibuffer-local-completion-map
>         minibuffer-local-completion-map))
>    (define-key minibuffer-local-completion-map
>                " " 'self-insert-command)
>    (completing-read prompt collection
>                     predicate nil init def hist i-i-m)))
>
> You would call the function with a COLLECTION argument that is a list of
> strings
> (Emacs 22+) or a list of singleton string lists (all versions). E.g.:
>
> (my-read-string-completing "String: "
>  '(("alpha") ("beta") ("gamma")))
>
> (If you use Icicles, `icicle-read-string-completing' does this.)
>
>

[-- Attachment #2: Type: text/html, Size: 2302 bytes --]

Re: Mix of completing-read and read-string

[Kevin Rodgers]

Drew Adams wrote:
>> I'm looking for a function that is a mix of read-string
>> and completing-read. I want completion and I want to be
>> able to input anything, such as spaces. Is there any such
>> function or do I have to write one myself?
> 
> 1. Use lax completion (`completing-read' with nil as the REQUIRE-MATCH argument.
> 
> 2. Use a keymap that has SPC bound to `self-insert-command'.
> 
> You can do #2 by binding `minibuffer-local-completion-map' (so it is restored
> afterward), and doing (define-key minibuffer-local-completion-map " "
> 'self-insert-command).
> 
> IOW, something like this:
> 
> (defun my-read-string-completing (prompt collection
>                                   &optional predicate
>                                   init hist def i-i-m)
>   "..."
>   (let ((minibuffer-local-completion-map
>          minibuffer-local-completion-map))

(copy-keymap minibuffer-local-completion-map) would be safer, eh?

>     (define-key minibuffer-local-completion-map
>                 " " 'self-insert-command)
>     (completing-read prompt collection 
>                      predicate nil init def hist i-i-m)))
> 
> You would call the function with a COLLECTION argument that is a list of strings
> (Emacs 22+) or a list of singleton string lists (all versions). E.g.:
> 
> (my-read-string-completing "String: "
>   '(("alpha") ("beta") ("gamma")))
> 
> (If you use Icicles, `icicle-read-string-completing' does this.)

-- 
Kevin Rodgers
Denver, Colorado, USA

RE: Mix of completing-read and read-string

[Drew Adams]

> >   (let ((minibuffer-local-completion-map
> >          minibuffer-local-completion-map))
> 
> (copy-keymap minibuffer-local-completion-map) would be safer, eh?

Yes. In case of error or quitting (`C-g') during completion, that will prevent
possibly leaving behind a SPC binding as `self-insert-command'.

(let ((minibuffer-local-completion-map
       (copy-keymap minibuffer-local-completion-map)))
 ...

Re: Mix of completing-read and read-string

[Kevin Rodgers]

Drew Adams wrote:
>>>   (let ((minibuffer-local-completion-map
>>>          minibuffer-local-completion-map))
>> (copy-keymap minibuffer-local-completion-map) would be safer, eh?
> 
> Yes. In case of error or quitting (`C-g') during completion, that will prevent
> possibly leaving behind a SPC binding as `self-insert-command'.
> 
> (let ((minibuffer-local-completion-map
>        (copy-keymap minibuffer-local-completion-map)))
>  ...

Actually, I was considering the possibility that define-key would 
destructively modify the keymap:

     (define-key minibuffer-local-completion-map
                 " " 'self-insert-command)

It doesn't happen in emacs -Q, but if SPC were already bound or
minibuffer-local-completion-map were a full keymap...

-- 
Kevin Rodgers
Denver, Colorado, USA

RE: Mix of completing-read and read-string

[Drew Adams]

>>   (let ((minibuffer-local-completion-map
>>          minibuffer-local-completion-map))
>
> (copy-keymap minibuffer-local-completion-map) would be safer, eh?


This is probably the best approach; it is used in Emacs sources:

(let ((minibuffer-local-completion-map
       (let ((map  (make-sparse-keymap)))
         (set-keymap-parent map minibuffer-local-completion-map)
         (define-key map " " 'self-insert-command)
         (define-key map "?" 'self-insert-command)
         map)))
  (completing-read ...))