org-mew.el

org-mew.el

[Bastien]

[-- Attachment #1: Type: text/plain, Size: 227 bytes --]

Here is org-mew.el: it lets you create links from and to Mew messages.
Mew is another mailer for Emacs, written by Kazu Yamamoto. 

  http://www.mew.org

This is very basic for now, and I will improve it if requested.

Enjoy!


[-- Attachment #2: org-mew.el --]
[-- Type: application/emacs-lisp, Size: 2200 bytes --]

[-- Attachment #3: Type: text/plain, Size: 13 bytes --]


-- 
Bastien

[-- Attachment #4: Type: text/plain, Size: 204 bytes --]

_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode

Re: org-mew.el

[Tim Stewart]

Hello The List,

Bastien <bzg@altern.org> writes:

> Here is org-mew.el: it lets you create links from and to Mew
> messages.  Mew is another mailer for Emacs, written by Kazu
> Yamamoto.

Very cool.  Too bad I don't use Mew.  :D

Is there any functionality like this that works with GNUS?  I could
really use the ability to link to GNUS messages.

Cheers,

-- 
-TimS

Tim Stewart
Lead UNIX Systems Administrator
Ciena Corporation
Alpharetta, GA, USA
tstewart@ciena.com

Re: org-mew.el

[Bastien Guerry]

Tim Stewart <tstewart@ciena.com> writes:

> Is there any functionality like this that works with GNUS?  I could
> really use the ability to link to GNUS messages.

Well, this has been in Org for a long time! 

Just try M-x org-store-link in a Gnus group or in a message, it will
make a link to the message at point.  Check this:

(info "(org)External links")

HTH

-- 
Bastien

Re: org-mew.el

[Tim Stewart]

Bastien Guerry <bzg@altern.org> writes:

> Tim Stewart <tstewart@ciena.com> writes:
>
>> Is there any functionality like this that works with GNUS?  I could
>> really use the ability to link to GNUS messages.
>
> Well, this has been in Org for a long time! 

Great!

> Just try M-x org-store-link in a Gnus group or in a message, it will
> make a link to the message at point.  Check this:
>
> (info "(org)External links")

Oh man, thanks a lot.  I thought I'd been through all of the Org
manual by now, but I suppose I'm mistaken!

Cheers,

-- 
-TimS

Tim Stewart
Lead UNIX Systems Administrator
Ciena Corporation
Alpharetta, GA, USA
tstewart@ciena.com

Re: org-mew.el

[Leo]

On 2008-02-13 21:58 +0000, Tim Stewart wrote:
> Is there any functionality like this that works with GNUS?  I could
> really use the ability to link to GNUS messages.

org-mode supports Gnus by default.

-- 
.:  Leo  :.  [ sdl.web AT gmail.com ]  .:  [ GPG Key: 9283AA3F ]  :.

          Use the best OS -- http://www.fedoraproject.org/

org-mew.el

[Tokuya Kameshima]

[-- Attachment #1: Type: Text/Plain, Size: 322 bytes --]

Hi,

I wrote org-mew.el, which implements links to Mew messages and tested
with Mew version 5.2 and 5.2.55.
Could someone try and test it?

I am considering myself switching my primary MUA from Wanderlust to
Mew and found that org-mew.el was missing in org-6.00pre-5.  So I just
hacked this emacs lisp.

Thanks,
--Tokuya


[-- Attachment #2: org-mew.el --]
[-- Type: Text/Plain, Size: 4529 bytes --]

;;; org-mew.el --- Support for links to Mew messages from within Org-mode

;; Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.

;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
;; Keywords: outlines, hypermedia, calendar, wp
;; Homepage: http://orgmode.org
;; Version: TBD
;;
;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;; Commentary:

;; This file implements links to Mew messages from within Org-mode.
;; Org-mode loads this module by default - if this is not what you want,
;; configure the variable `org-modules'.

;;; Code:

(require 'org)

(defgroup org-mew nil
  "Options concerning the Mew link."
  :tag "Org Startup"
  :group 'org-link)

(defcustom org-mew-link-to-refile-destination t
  "Create a link to the refile destination if the message is marked as refile."
  :group 'org-mew
  :type 'boolean)

;; Declare external functions and variables
(declare-function mew-header-get-value "ext:mew-header"
		  (field &optional as-list))
(declare-function mew-init "ext:mew" ())
(declare-function mew-refile-get "ext:mew-refile" (msg))
(declare-function mew-summary-display "ext:mew-summary2" (&optional redisplay))
(declare-function mew-summary-folder-name "ext:mew-syntax" (&optional ext))
(declare-function mew-summary-get-mark "ext:mew-mark" ())
(declare-function mew-summary-message-number2 "ext:mew-syntax" ())
(declare-function mew-summary-pick-with-mewl "ext:mew-pick"
		  (pattern folder src-msgs))
(declare-function mew-summary-search-msg "ext:mew-const" (msg))
(declare-function mew-summary-set-message-buffer "ext:mew-summary3" (fld msg))
(declare-function mew-summary-visit-folder "ext:mew-summary4"
		  (folder &optional goend no-ls))
(declare-function mew-window-push "ext:mew" ())
(defvar mew-init-p)

;; Install the link type
(org-add-link-type "mew" 'org-mew-open)
(add-hook 'org-store-link-functions 'org-mew-store-link)

;; Implementation
(defun org-mew-store-link ()
  "Store a link to a MEW folder or message."
  (when (memq major-mode '(mew-summary-mode mew-virtual-mode))
    (let* ((msgnum (mew-summary-message-number2))
	   (mark-info (mew-summary-get-mark))
	   (folder-name
	    (if (and org-mew-link-to-refile-destination
		     (eq mark-info ?o))	; marked as refile
		(nth 1 (mew-refile-get msgnum))
	      (mew-summary-folder-name)))
	   message-id from to subject desc link)
      (save-window-excursion
	(mew-summary-set-message-buffer folder-name msgnum)
	(setq message-id (mew-header-get-value "Message-Id:"))
	(setq from (mew-header-get-value "From:"))
	(setq to (mew-header-get-value "To:"))
	(setq subject (mew-header-get-value "Subject:")))
      (org-store-link-props :type "mew" :from from :to to
			    :subject subject :message-id message-id)
      (setq message-id (org-remove-angle-brackets message-id))
      (setq desc (org-email-link-description))
      (setq link (org-make-link "mew:" folder-name
				"#" message-id))
      (org-add-link-props :link link :description desc)
      link)))

(defun org-mew-open (path)
  "Follow the Mew message link specified by PATH."
  (require 'mew)
  (mew-window-push)
  (unless mew-init-p (mew-init))
  ;; XXX: The imap-uw's MH folder names start with "%#".
  (if (not (string-match "\\`\\(\\(?:%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path))
      (error "Error in Mew link"))
  (let* ((folder (match-string 1 path))
	 (article (match-string 3 path))
	 (pattern (concat "message-id=" article))
	 msgs)
    (mew-summary-visit-folder folder)
    ;; TODO: sync the visited folder
    (setq msgs (mew-summary-pick-with-mewl pattern folder nil))
    (if msgs
	(progn
	  (mew-summary-search-msg (car msgs))
	  (mew-summary-display))
      (error "Message not found"))))

(provide 'org-mew)

;;; org-mew.el ends here

[-- Attachment #3: Type: text/plain, Size: 204 bytes --]

_______________________________________________
Emacs-orgmode mailing list
Remember: use `Reply All' to send replies to the list.
Emacs-orgmode@gnu.org
http://lists.gnu.org/mailman/listinfo/emacs-orgmode