From: Dmitry Alexandrov <321942@gmail.com>
Subject: Re: prevent scroll-lock-mode from scrolling?
Date: Mon, 20 Jun 2016 13:05:34 +0300 [thread overview]
Message-ID: <87y4609nv5.fsf@gmail.com> (raw)
In-Reply-To: <87mvmgpwf9.fsf@heimdali.yagibdah.de> (lee's message of "Mon, 20 Jun 2016 01:54:02 +0200")
lee <lee@yagibdah.de> writes:
> Can you explain to me why the cursor remains at its position /on the
> screen/ while I'm scrolling with scroll-lock-mode enabled all the time
> like it should --- and then suddenly moves when the top or bottom of the
> buffer contents come into view? That doesn't make any sense to me; the
> cursor still shouldn't move.
Given that there is no free space before the first line of a buffer,
this does make perfect sense with regard to scrolling backward (to the
top of a buffer). The other way we would just get stuck with the point
in the middle of a screen not being able to reach first lines. The
scrolling forward behaves the same way for sake of coherence, I guess.
Anyway, if you look into the code, you’ll see that this behaviour is
definetely intentional:
(defun scroll-lock-next-line (&optional arg)
"Scroll up ARG lines keeping point fixed."
(interactive "p")
(or arg (setq arg 1))
(scroll-lock-update-goal-column)
(if (pos-visible-in-window-p (point-max))
(forward-line arg)
(scroll-up arg))
(scroll-lock-move-to-column scroll-lock-temporary-goal-column))
(defun scroll-lock-previous-line (&optional arg)
"Scroll up ARG lines keeping point fixed."
(interactive "p")
(or arg (setq arg 1))
(scroll-lock-update-goal-column)
(condition-case nil
(scroll-down arg)
(beginning-of-buffer (forward-line (- arg))))
(scroll-lock-move-to-column scroll-lock-temporary-goal-column))
However, if you do not like it, just remove the condition:
(defun my-scroll-lock-next-line (&optional arg)
"Scroll up ARG lines keeping point fixed."
(interactive "p")
(or arg (setq arg 1))
(scroll-lock-update-goal-column)
(scroll-up arg)
(scroll-lock-move-to-column scroll-lock-temporary-goal-column))
(defun my-scroll-lock-previous-line (&optional arg)
"Scroll up ARG lines keeping point fixed."
(interactive "p")
(or arg (setq arg 1))
(scroll-lock-update-goal-column)
(scroll-down arg)
(scroll-lock-move-to-column scroll-lock-temporary-goal-column))
(advice-add 'scroll-lock-next-line :override #'my-scroll-lock-next-line)
(advice-add 'scroll-lock-previous-line :override #'my-scroll-lock-previous-line)
Also, if you are regularily toggling the ‘scroll-lock-mode’ on and off,
you might consider to use approach that, one might say, is more
‘Emacsish’ — another keychord instead of mode:
(setq scroll-preserve-screen-position 'always)
(global-set-key (kbd "M-n") #'scroll-up-line)
(global-set-key (kbd "M-<down>") #'scroll-up-line)
(global-set-key (kbd "M-p") #'scroll-down-line)
(global-set-key (kbd "M-<up>") #'scroll-down-line)
next prev parent reply other threads:[~2016-06-20 10:05 UTC|newest]
Thread overview: 19+ messages / expand[flat|nested] mbox.gz Atom feed top
2016-06-17 1:12 prevent scroll-lock-mode from scrolling? lee
2016-06-17 1:25 ` Emanuel Berg
2016-06-17 4:14 ` Stefan Monnier
2016-06-17 6:00 ` Emanuel Berg
2016-06-17 22:40 ` Stefan Monnier
2016-06-18 1:19 ` what to require (was: Re: prevent scroll-lock-mode from scrolling?) Emanuel Berg
2016-06-17 22:47 ` prevent scroll-lock-mode from scrolling? lee
2016-06-17 6:47 ` Eli Zaretskii
2016-06-17 23:10 ` lee
2016-06-18 8:38 ` Eli Zaretskii
2016-06-19 23:54 ` lee
2016-06-20 8:33 ` tomas
2016-06-20 14:32 ` lee
2016-06-20 10:05 ` Dmitry Alexandrov [this message]
2016-06-20 15:24 ` lee
2016-06-20 16:12 ` Dmitry Alexandrov
2016-06-20 19:50 ` lee
2016-06-20 14:34 ` Eli Zaretskii
2016-06-20 21:21 ` lee
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87y4609nv5.fsf@gmail.com \
--to=321942@gmail.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this external index
https://git.savannah.gnu.org/cgit/emacs.git
https://git.savannah.gnu.org/cgit/emacs/org-mode.git
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.