How to advice save-buffers-kill-terminal?

How to advice save-buffers-kill-terminal?

[Shiyao Ma]

For the following code:

(advice-add 'save-buffers-kill-terminal :around #'(lambda (oldfunc &rest r)
                                                    (cl-flet ((yes-or-no-p
(msg)

(message "test:%S" msg)))
                                                      (apply oldfunc r))))


The yes-or-no-p in cl-flet doesn't affect the calling of yes-or-no-p inside
save-buffers-kill-terminal.

After a quick look, I found the suspicious *- lexical-binding:t -*- in
files.el.


Any possibility to modify that yes-or-no-p inside
save-buffers-kill-terminal?


(I know I can define a save-buffers-kill-terminal on my own, but that will
sooner or later not in sync with the official one).


Regards.


-- 

吾輩は猫である。ホームーページはhttps://introo.me <http://introo.me>。

Re: How to advice save-buffers-kill-terminal?

[Stefan Monnier]

> (advice-add 'save-buffers-kill-terminal :around
>             #'(lambda (oldfunc &rest r)
>                 (cl-flet ((yes-or-no-p (msg)
>                             (message "test:%S" msg)))
>                   (apply oldfunc r))))

> The yes-or-no-p in cl-flet doesn't affect the calling of yes-or-no-p inside
> save-buffers-kill-terminal.

Indeed.  `cl-flet` is documented as being lexical, which means that it
only affects calls to `yes-or-no-p` made *syntactically within* (as
opposed to: *during the execution of*) the `cl-flet`.

> After a quick look, I found the suspicious *- lexical-binding:t -*- in
> files.el.

That's actually unrelated: `lexical-binding` affects the scoping of
variables, whereas your case depends on the scoping of functions.

> Any possibility to modify that yes-or-no-p inside
> save-buffers-kill-terminal?

Of course.  You could use

    (defvar my-skip-yes-or-no-p nil)
    (advice-add 'yes-or-no-p :around
                (lambda (orig-fun &rest args)
                  (if my-skip-yes-or-no-p
                      (apply #'message "test:%S" args)
                    (apply orig-fun args))))
    (advice-add 'save-buffers-kill-terminal :around
                #'(lambda (oldfunc &rest r)
                    (let ((my-skip-yes-or-no-p t))
                      (apply oldfunc r))))

or

    (advice-add 'save-buffers-kill-terminal :around
                #'(lambda (oldfunc &rest r)
                    (cl-letf (((symbol-function 'yes-or-no-p)
                               (lambda (msg) (message "test:%S" msg))))
                      (apply oldfunc r))))

The second is more concise, but I the like the first better, because
C-h f yes-or-no-p RET will then tell you honestly about the fact that
it's sometimes overridden.


        Stefan

Re: How to advice save-buffers-kill-terminal?

[Michael Heerdegen]

Shiyao Ma <i@introo.me> writes:

> For the following code:
>
> (advice-add 'save-buffers-kill-terminal :around #'(lambda (oldfunc &rest r)
>                                                     (cl-flet ((yes-or-no-p
> (msg)
>
> (message "test:%S" msg)))
>                                                       (apply oldfunc r))))
>
>
> The yes-or-no-p in cl-flet doesn't affect the calling of yes-or-no-p inside
> save-buffers-kill-terminal.
>
> After a quick look, I found the suspicious *- lexical-binding:t -*- in
> files.el.
>
>
> Any possibility to modify that yes-or-no-p inside
> save-buffers-kill-terminal?

[Skipping the usual warnings that this is generally a bad idea]

Use `cl-letf' to bind a `symbol-function' place.

BTW, you are not just searching for `confirm-kill-emacs'?


Michael.

Re: How to advice save-buffers-kill-terminal?

[Shiyao Ma]

Thanks.

Youre answer really helps.

Re: How to advice save-buffers-kill-terminal?

[Emanuel Berg]

Shiyao Ma <i@introo.me> writes:

> For the following code:
>
> (advice-add 'save-buffers-kill-terminal :around
> #'(lambda (oldfunc &rest r) (cl-flet ((yes-or-no-p
> (msg)

*Sigh*!

Did I ever hear of I guy who succeeded doing anything
with advices? Yes: several times!

:)

Here is what I would do. In the now commented-out
"kill-everything" function is where you shut
everything down gracefully, e.g., Gnus and any other
software you might run.

    (defun no-confirm-emacs-quit ()
      (interactive)
      ; (kill-everything)
      (save-buffers-kill-terminal t) ) ; silently save ... kill

    (define-key (current-global-map)
      [remap save-buffers-kill-terminal] #'no-confirm-emacs-quit)

Full example source:

    http://user.it.uu.se/~embe8573/conf/emacs-init/quit.el

Sensible blog post on this theme:

    http://user.it.uu.se/~embe8573/blogomatic/emacs/automatization-hooks-advices-or-new-functions.html

-- 
underground experts united .... http://user.it.uu.se/~embe8573
Emacs Gnus Blogomatic ......... http://user.it.uu.se/~embe8573/blogomatic
                   - so far: 25 Blogomatic articles -