Re: Subject: [PATCH] * lisp/xwidget.el (xwidget-webkit-browse-url): Remove space prefix of url.

[Po Lu <luangruo@yahoo.com>]

Lars Ingebrigtsen <larsi@gnus.org> writes:

> Well, it's a DWIM function, so: 😅.  It just tries to do what any
> browser does when a user types something into the address bar, and it'll
> probably change over time (as users' expectations change).
>
> But basically tries to guess whether a user is typing in a (possibly
> incomplete) URL or a search term.

I'd like to add this:

(defun url-dwim-expand-url (url local-regex search-prefix)
  "Canonicalize URL.
Try to determine if URL is an incomplete URL or a search query, and
return the canonical form of URL.
SEARCH-PREFIX is the prefix to be prepended to URL if it is a search query.
LOCAL-REGEX is a regular expression that URL is matched against.  If the
match is successful, then URL is treated as an address."
  (setq url (string-trim url))
  (cond ((string-match-p "\\`file:/" url))
	;; Don't mangle file: URLs at all.
        ((string-match-p "\\`ftp://" url)
         (user-error "FTP is not supported"))
        (t
	 ;; Anything that starts with something that vaguely looks
	 ;; like a protocol designator is interpreted as a full URL.
         (if (or (string-match "\\`[A-Za-z]+:" url)
		 ;; Also try to match "naked" URLs like
		 ;; en.wikipedia.org/wiki/Free software
		 (string-match "\\`[A-Za-z_]+\\.[A-Za-z._]+/" url)
		 (and (= (length (split-string url)) 1)
		      (or (and (not (string-match-p "\\`[\"'].*[\"']\\'" url))
			       (> (length (split-string url "[.:]")) 1))
			  (string-match local-regex url))))
             (progn
               (unless (string-match-p "\\`[a-zA-Z][-a-zA-Z0-9+.]*://" url)
                 (setq url (concat "http://" url)))
               ;; Some sites do not redirect final /
               (when (string= (url-filename (url-generic-parse-url url)) "")
                 (setq url (concat url "/"))))
           (setq url (concat search-prefix
                             (mapconcat
                              #'url-hexify-string (split-string url) "+"))))))
  url)

to url-util.

Does this look good to you?  Thanks in advance.