Re: word-wrap (visual-line) and indents

[Stephen Berman <stephen.berman@gmx.net>]

On Tue, 25 May 2010 13:05:08 -0400 Stefan Monnier <monnier@iro.umontreal.ca> wrote:

>> Speaking of word-wrapping, I thought now would be a good time to bring
>> up the missing feature of per-line indentation when word wrapping.
>> A recent conversation is quoted below, pointing out that word-wrap is
>> less than ideal when it comes to displaying e-mail (and the like).
>> A similar example would be org-mode, where you would begin a (buffer)
>> line with "- " or "  - "  and where word-wrap would, ideally,
>> recognize such indentations.  
>
> The C code already has hooks that make such a thing possible:
> Just place a `wrap-prefix' property on the long-line which specify what
> prefix to use when wrapping the line.
>
> So all we need is a new minor-mode that uses jit-lock-register and then
> sets up this property using something like fill-context-prefix.

See <http://thread.gmane.org/gmane.emacs.devel/100184/focus=100375>.
You followed up with some suggestions, incorporated in the code below (I
had included the commented out lines, but you thought they should be
separate features).  Maybe this could be the basis for such a minor
mode.

Steve Berman


(defun srb-adaptive-indent (beg end)
  "Indent the region between BEG and END with adaptive filling."
  (goto-char beg)
  (while
      (let ((lbp (line-beginning-position))
	    (lep (line-end-position)))
	(put-text-property lbp lep 'wrap-prefix (fill-context-prefix lbp lep))
	(search-forward "\n" end t))))

(define-minor-mode srb-adaptive-wrap-mode
  "Wrap the buffer text with adaptive filling."
  :lighter ""
  (save-excursion
    (save-restriction
      (widen)
      (let ((buffer-undo-list t)
	    (inhibit-read-only t)
	    (mod (buffer-modified-p)))
	(if srb-adaptive-wrap-mode
	    (progn
	      ;; (setq word-wrap t)
	      ;; (unless (member '(continuation) fringe-indicator-alist)
	      ;; 	(push '(continuation) fringe-indicator-alist))
	      (jit-lock-register 'srb-adaptive-indent))
	  (jit-lock-unregister 'srb-adaptive-indent)
	  (remove-text-properties (point-min) (point-max) '(wrap-prefix pref))
	  ;; (setq fringe-indicator-alist
	  ;; 	(delete '(continuation) fringe-indicator-alist))
	  ;; (setq word-wrap nil))
	(restore-buffer-modified-p mod))))))