Re: Native line numbers landed on master

[Alex <agrambot@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 1308 bytes --]

Eli Zaretskii <eliz@gnu.org> writes:

>> From: Alex <agrambot@gmail.com>
>> Cc: emacs-devel@gnu.org
>> Date: Sat, 08 Jul 2017 16:38:44 -0600
>> 
>> Why did you choose the name line-number-display-width over, e.g.,
>> display-line-number-width? It seems every other related variable has a
>> prefix of display-.
>
> Not every other one: the faces start with line-number.
>
> Is the name that bad?  It sounded right at the time, but if others
> think it might confuse, we could rename it.

I think it's a little confusing, but it's not a huge deal.

>> P.S. I was thinking about how a minor mode for this should be
>> implemented. I attached a proof of concept, which includes a couple
>> extra variables to achieve line number width behaviour similar to
>> linum/nlinum. What do you think?
>
> Looks okay, although I'd drop the # part in the below:
>
>   (add-hook 'pre-command-hook #'display-line-numbers-update-width nil t))

Is there a reason to drop it? I heard that the byte compiler uses #' to
check for existence of the function (and warns if it's not found), so it
seems like a nice default in these situations.

I've attached a patch below. I changed the menu bar to toggle the global
mode since the other toggles in the Show/Hide menu are also toggled
globally. Does it look alright for inclusion?


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: minor mode --]
[-- Type: text/x-diff, Size: 5765 bytes --]

From 283ac10f3601362c0b200f0b610047bec75d0a59 Mon Sep 17 00:00:00 2001
From: Alexander Gramiak <agrambot@gmail.com>
Date: Sun, 9 Jul 2017 16:40:52 -0600
Subject: [PATCH] Add minor mode interface for display-line-numbers

* lisp/display-line-numbers.el: New file.
* lisp/menu-bar (menu-bar-showhide-menu): Use global minor mode.
(toggle-display-line-numbers): Remove.
---
 lisp/display-line-numbers.el | 99 ++++++++++++++++++++++++++++++++++++++++++++
 lisp/menu-bar.el             | 14 ++-----
 2 files changed, 102 insertions(+), 11 deletions(-)
 create mode 100644 lisp/display-line-numbers.el

diff --git a/lisp/display-line-numbers.el b/lisp/display-line-numbers.el
new file mode 100644
index 0000000000..ebc3494f73
--- /dev/null
+++ b/lisp/display-line-numbers.el
@@ -0,0 +1,99 @@
+;;; display-line-numbers.el --- interface for display-line-numbers -*- lexical-binding: t -*-
+
+;; Copyright (C) 2017 Free Software Foundation, Inc.
+
+;; Maintainer: emacs-devel@gnu.org
+;; Keywords: convenience
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Provides a minor mode interface for `display-line-numbers'.
+;;
+;; Toggle display of line numbers with M-x display-line-numbers-mode.
+;; To enable line numbering in all buffers, use M-x
+;; global-display-line-numbers-mode.  To change the default type of
+;; line numbers displayed, customize display-line-number-type.
+
+;;; Code:
+
+(defgroup display-line-numbers nil
+  "Display line numbers in the buffer."
+  :group 'display)
+
+(defcustom display-line-number-type t
+  "Sets the type of line numbers to use in `display-line-number-mode'.
+See `display-line-numbers' for value options."
+  :group 'display-line-numbers
+  :type '(choice (const :tag "Relative line numbers" relative)
+                 (const :tag "Relative visual line numbers" visual)
+                 (other :tag "Regular line numbers" t))
+  :version "26.1")
+
+(defcustom display-line-number-inhibit-shrink nil
+  "If non-nil, do not shrink line number width."
+  :group 'display-line-numbers
+  :type 'boolean
+  :version "26.1")
+
+(defcustom display-line-number-width-start nil
+  "If non-nil, set initial line number width based on buffer contents.
+`display-line-number-width' is set to the minimum width necessary
+to display all line numbers in the buffer."
+  :group 'display-line-numbers
+  :type 'boolean
+  :version "26.1")
+
+(defun display-line-numbers-update-width ()
+  "Prevent the line number width from shrinking."
+  (setq display-line-number-width
+        (max (or display-line-number-width 1)
+             (line-number-display-width))))
+
+;;;###autoload
+(define-minor-mode display-line-numbers-mode
+  "Toggle display of line numbers in the buffer.
+This uses `display-line-numbers' internally.
+
+To change the type of line numbers displayed by default,
+customize `display-line-number-type'. To change the type while
+the mode is on, set `display-line-numbers' directly."
+  :lighter nil
+  (if display-line-numbers-mode
+      (progn
+        (when display-line-number-width-start
+          (setq display-line-number-width
+                (length (number-to-string
+                         (count-lines (point-min) (point-max))))))
+        (when display-line-number-inhibit-shrink
+          (add-hook 'pre-command-hook #'display-line-numbers-update-width nil t))
+        (setq display-line-numbers display-line-number-type))
+    (remove-hook 'pre-command-hook #'display-line-numbers-update-width t)
+    (setq display-line-numbers nil)))
+
+;;;###autoload
+(define-globalized-minor-mode global-display-line-numbers-mode
+  display-line-numbers-mode
+  (lambda ()
+    (unless (or (minibufferp)
+                ;; taken from linum.el
+                (and (daemonp) (null (frame-parameter nil 'client))))
+      (display-line-numbers-mode))))
+
+(provide 'display-line-numbers)
+
+;;; display-line-numbers.el ends here
diff --git a/lisp/menu-bar.el b/lisp/menu-bar.el
index 3ca7d1b5b3..434dd9b91f 100644
--- a/lisp/menu-bar.el
+++ b/lisp/menu-bar.el
@@ -1101,23 +1101,15 @@ menu-bar-showhide-tool-bar-menu-customize-enable-bottom
                     :button (:radio . (eq tool-bar-mode nil))))
       menu)))
 
-(defun toggle-display-line-numbers ()
-  (interactive)
-  (if display-line-numbers
-      (setq display-line-numbers nil)
-    (setq display-line-numbers t))
-  (force-mode-line-update))
-
 (defvar menu-bar-showhide-menu
   (let ((menu (make-sparse-keymap "Show/Hide")))
 
     (bindings--define-key menu [display-line-numbers]
       `(menu-item "Line Numbers for All Lines"
-                  ,(lambda ()
-                     (interactive)
-                     (toggle-display-line-numbers))
+                  global-display-line-numbers-mode
                   :help "Show the line number alongside each line"
-                  :button (:toggle . display-line-numbers)))
+                  :button (:toggle . (bound-and-true-p
+                                      global-display-line-numbers-mode))))
 
     (bindings--define-key menu [column-number-mode]
       (menu-bar-make-mm-toggle column-number-mode
-- 
2.11.0