C-x C-c does nothing on frames created with "nowait" flag

C-x C-c does nothing on frames created with "nowait" flag

[Bo Lin]

Hi emacs-devel,

When connecting to a Emacs daemon using "emacsclient -n -c", pressing
C-x C-c in the newly created frame does nothing. It does not exit Emacs,
close the frame, or even give any visible feed-back, just nothing.
That's quite surprising, and at first I thought Emacs has hanged.

I think it should at least give a message, like so:

--- a/lisp/server.el
+++ b/lisp/server.el
@@ -1349,18 +1349,22 @@ With ARG non-nil, silently save all file-visiting buffers, then kill.
 
 If emacsclient was started with a list of filenames to edit, then
 only these files will be asked to be saved."
-  ;; save-buffers-kill-terminal occasionally calls us with proc set
-  ;; to `nowait' (comes from the value of the `client' frame parameter).
-  (when (processp proc)
-    (let ((buffers (process-get proc 'buffers)))
-      ;; If client is bufferless, emulate a normal Emacs session
-      ;; exit and offer to save all buffers.  Otherwise, offer to
-      ;; save only the buffers belonging to the client.
-      (save-some-buffers arg
-                         (if buffers
-                             (lambda () (memq (current-buffer) buffers))
-                           t))
-      (server-delete-client proc))))
+  (cond ((eq proc 'nowait)
+         ;; save-buffers-kill-terminal occasionally calls us with proc set
+         ;; to `nowait' (comes from the value of the `client' frame parameter).
+         (message "%s"
+                  (substitute-command-keys
+                   "No clients waiting. Type \\[save-buffers-kill-emacs] to kill Emacs or type \\[delete-frame] to delete this frame.")))
+        ((processp proc)
+          (let ((buffers (process-get proc 'buffers)))
+            ;; If client is bufferless, emulate a normal Emacs session
+            ;; exit and offer to save all buffers.  Otherwise, offer to
+            ;; save only the buffers belonging to the client.
+            (save-some-buffers arg
+                               (if buffers
+                                   (lambda () (memq (current-buffer) buffers))
+                                 t))
+            (server-delete-client proc)))))
 
 (define-key ctl-x-map "#" 'server-edit)
 

Re: C-x C-c does nothing on frames created with "nowait" flag

[Ulrich Mueller]

>>>>> On Sun, 11 Jan 2009, Bo Lin wrote:

> When connecting to a Emacs daemon using "emacsclient -n -c",
> pressing C-x C-c in the newly created frame does nothing. It does
> not exit Emacs, close the frame, or even give any visible feed-back,
> just nothing. That's quite surprising, and at first I thought Emacs
> has hanged.

I had reported this last month already, but somehow the issue got lost.
<http://lists.gnu.org/archive/html/emacs-devel/2008-12/msg01095.html>

> I think it should at least give a message,

... or save buffers and delete the frame (also sent the following
patch already):

--- lisp/files.el.~1.1030.~
+++ lisp/files.el
@@ -5733,9 +5733,14 @@
   (interactive "P")
   (let ((proc (frame-parameter (selected-frame) 'client))
 	(frame (selected-frame)))
-    (if (null proc)
-	(save-buffers-kill-emacs)
-      (server-save-buffers-kill-terminal proc arg))))
+    (cond
+     ((null proc)
+      (save-buffers-kill-emacs))
+     ((processp proc)
+      (server-save-buffers-kill-terminal proc arg))
+     (t
+      (save-some-buffers arg t)
+      (delete-frame)))))
 
 \f
 ;; We use /: as a prefix to "quote" a file name

Ulrich

Re: C-x C-c does nothing on frames created with "nowait" flag

[Bo Lin]

Ulrich Mueller <ulm@gentoo.org> writes:

>>>>>> On Sun, 11 Jan 2009, Bo Lin wrote:
>
>> When connecting to a Emacs daemon using "emacsclient -n -c",
>> pressing C-x C-c in the newly created frame does nothing. It does
>> not exit Emacs, close the frame, or even give any visible feed-back,
>> just nothing. That's quite surprising, and at first I thought Emacs
>> has hanged.
>
> I had reported this last month already, but somehow the issue got lost.
> <http://lists.gnu.org/archive/html/emacs-devel/2008-12/msg01095.html>
>

Ahh, I see. Sorry for the duplicate.

>> I think it should at least give a message,
>
> ... or save buffers and delete the frame 
>

Yes, that would obviously be better. I just wasn't sure whether that
behavior was an oversight or intentionally made so for some obscure
reason ;-)

Re: C-x C-c does nothing on frames created with "nowait" flag

[Chong Yidong]

Ulrich Mueller <ulm@gentoo.org> writes:

> ... or save buffers and delete the frame (also sent the following
> patch already):

Or, we could treat a `nowait' frame as though it were an ordinary
(non-client) frame on the server:

*** trunk/lisp/files.el.~1.1031.~	2009-01-11 08:23:10.000000000 -0500
--- trunk/lisp/files.el	2009-01-11 08:24:54.000000000 -0500
***************
*** 5733,5741 ****
    (interactive "P")
    (let ((proc (frame-parameter (selected-frame) 'client))
  	(frame (selected-frame)))
!     (if (null proc)
! 	(save-buffers-kill-emacs)
!       (server-save-buffers-kill-terminal proc arg))))
  
  \f
  ;; We use /: as a prefix to "quote" a file name
--- 5733,5741 ----
    (interactive "P")
    (let ((proc (frame-parameter (selected-frame) 'client))
  	(frame (selected-frame)))
!     (if (processp proc)
! 	(server-save-buffers-kill-terminal proc arg)
!       (save-buffers-kill-emacs arg))))
  
  \f
  ;; We use /: as a prefix to "quote" a file name

Re: C-x C-c does nothing on frames created with "nowait" flag

[Ulrich Mueller]

>>>>> On Sun, 11 Jan 2009, Chong Yidong wrote:

> Or, we could treat a `nowait' frame as though it were an ordinary
> (non-client) frame on the server:

Hm, I think this is not such a good idea if Emacs was started in
daemon mode.

Ulrich

Re: C-x C-c does nothing on frames created with "nowait" flag

[Bo Lin]

Ulrich Mueller <ulm@gentoo.org> writes:

>>>>>> On Sun, 11 Jan 2009, Chong Yidong wrote:
>
>> Or, we could treat a `nowait' frame as though it were an ordinary
>> (non-client) frame on the server:
>
> Hm, I think this is not such a good idea if Emacs was started in
> daemon mode.

Agreed. Frames created by emacsclient should behave consistently
regardless of the `nowait' flag. That is, they should not kill the
server when destroyed.

BTW if you want to make the change in files.el then I'd suggest also
delete the two line comment regarding `nowait' in
`server-save-buffers-kill-terminal', to reduce the potential for future
confusion.

 -Bo

Re: C-x C-c does nothing on frames created with "nowait" flag

[Stefan Monnier]

> --- lisp/files.el.~1.1030.~
> +++ lisp/files.el
> @@ -5733,9 +5733,14 @@
>    (interactive "P")
>    (let ((proc (frame-parameter (selected-frame) 'client))
>  	(frame (selected-frame)))
> -    (if (null proc)
> -	(save-buffers-kill-emacs)
> -      (server-save-buffers-kill-terminal proc arg))))
> +    (cond
> +     ((null proc)
> +      (save-buffers-kill-emacs))
> +     ((processp proc)
> +      (server-save-buffers-kill-terminal proc arg))
> +     (t
> +      (save-some-buffers arg t)
> +      (delete-frame)))))
 
Any idea why this patch hasn't been installed yet?


        Stefan

Re: C-x C-c does nothing on frames created with "nowait" flag

[Chong Yidong]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

> Any idea why this patch hasn't been installed yet?

One problem with the patch is that it raises an error if the nowait
emacsclient frame is the last frame alive.  I guess the right thing to
do in that situation is for C-x C-c to call save-buffers-kill-emacs.

I'll check in an appropriate fix shortly.

Re: C-x C-c does nothing on frames created with "nowait" flag

[Ulrich Mueller]

>>>>> On Sun, 11 Jan 2009, Chong Yidong wrote:

> One problem with the patch is that it raises an error if the nowait
> emacsclient frame is the last frame alive.

You are right. I think that I had only tested the patch with Emacs
started as a daemon, where it doesn't raise an error. (Still, raising
an error would be an improvement against the current behaviour, where
the command just does nothing.)

On a somewhat related issue: the "Exit Emacs" menu item always shows
C-x C-c, even if this doesn't correspond to the current key binding.
Probably its definition in menu-bar.el shouldn't use :keys to hardcode
"C-x C-c".

Ulrich

Re: C-x C-c does nothing on frames created with "nowait" flag

[Chong Yidong]

Ulrich Mueller <ulm@gentoo.org> writes:

> On a somewhat related issue: the "Exit Emacs" menu item always shows
> C-x C-c, even if this doesn't correspond to the current key binding.
> Probably its definition in menu-bar.el shouldn't use :keys to hardcode
> "C-x C-c".

Yes.  We should probably also change it to use
save-buffers-kill-terminal rather than save-buffers-kill-emacs.