bug#35285: 27.0.50; Bug in image--set-property; setf

["Basil L. Contovounesios" <contovob@tcd.ie>]

[-- Attachment #1: Type: text/plain, Size: 23 bytes --]

tags 35285 patch
quit


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-Fix-off-by-one-link-error-in-image-set-property.patch --]
[-- Type: text/x-diff, Size: 3229 bytes --]

From b611408fe29e3e15e002d799dbaf98f813aa7530 Mon Sep 17 00:00:00 2001
From: "Basil L. Contovounesios" <contovob@tcd.ie>
Date: Wed, 17 Apr 2019 14:24:31 +0100
Subject: [PATCH] Fix off-by-one-link error in image--set-property

* lisp/image.el (image--set-property): Ensure new value is set even
in the unlikely case that the plist is empty.  Fix off-by-one-link
error when deleting a property. (bug#35285)
* test/lisp/image-tests.el: New file.
(image--set-property): New test.
---
 lisp/image.el            |  4 ++--
 test/lisp/image-tests.el | 45 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+), 2 deletions(-)
 create mode 100644 test/lisp/image-tests.el

diff --git a/lisp/image.el b/lisp/image.el
index 6da3a0b6cd..ba87d7f785 100644
--- a/lisp/image.el
+++ b/lisp/image.el
@@ -454,10 +454,10 @@ image--set-property
         ;; plist.  Decouple plist entries where the key matches
         ;; the property.
         (if (eq (cadr image) property)
-            (setcdr image (cddr image))
+            (setcdr image (cdddr image))
           (setq image (cddr image))))
     ;; Just enter the new value.
-    (plist-put (cdr image) property value))
+    (setcdr image (plist-put (cdr image) property value)))
   value)
 
 (defun image-property (image property)
diff --git a/test/lisp/image-tests.el b/test/lisp/image-tests.el
new file mode 100644
index 0000000000..89b926e629
--- /dev/null
+++ b/test/lisp/image-tests.el
@@ -0,0 +1,45 @@
+;;; image-tests.el --- tests for image.el -*- lexical-binding: t -*-
+
+;; Copyright (C) 2019 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'image)
+
+(ert-deftest image--set-property ()
+  "Test `image--set-property' behavior."
+  (let ((image (list 'image)))
+    ;; Add properties.
+    (setf (image-property image :scale) 1)
+    (should (equal image '(image :scale 1)))
+    (setf (image-property image :width) 8)
+    (should (equal image '(image :scale 1 :width 8)))
+    (setf (image-property image :height) 16)
+    (should (equal image '(image :scale 1 :width 8 :height 16)))
+    ;; Delete properties.
+    (setf (image-property image :type) nil)
+    (should (equal image '(image :scale 1 :width 8 :height 16)))
+    (setf (image-property image :scale) nil)
+    (should (equal image '(image :width 8 :height 16)))
+    (setf (image-property image :height) nil)
+    (should (equal image '(image :width 8)))
+    (setf (image-property image :width) nil)
+    (should (equal image '(image)))))
+
+;;; image-tests.el ends here
-- 
2.20.1


[-- Attachment #3: Type: text/plain, Size: 440 bytes --]


Adam Sjøgren <asjo@koldfront.dk> writes:

> Xu Chunyang analysed the problem with setf I presented on
> emacs.stackexchange.com¹ as so:
>
>   There is a bug in image--set-property, (setcdr image (cddr image))
>   should be (setcdr image (cdddr image)), i.e., change cddr into cdddr

I agree that this is the problem, and the attached patch should fix
that.  Eli, should this go to emacs-26 or master?

Thanks,

-- 
Basil