grep error because of bad previous input

grep error because of bad previous input

[Sam Steingold]

GNU Emacs 22.0.50.3 (i686-pc-linux-gnu, X toolkit, Xaw3d scroll bars)
 of 2006-07-24 on quant8

M-x grep RET
foo *.lis[ RET                     ;; typo: "[" instead of "p"
M-x grep RET

==>

Debugger entered--Lisp error: (args-out-of-range "*.lis[" 6)
  wildcard-to-regexp("*.lis[")
  grep-default-command()
  (let ((default ...)) (list (read-from-minibuffer "Run grep (like this): " ... nil nil ... ...)))
  (progn (grep-compute-defaults) (let (...) (list ...)))
  call-interactively(grep)
  execute-extended-command(nil)
  call-interactively(execute-extended-command)


-- 
Sam Steingold (http://www.podval.org/~sds) on Fedora Core release 5 (Bordeaux)
http://palestinefacts.org http://thereligionofpeace.com http://truepeace.org
http://ffii.org http://mideasttruth.com http://pmw.org.il http://memri.org
The only thing worse than X Windows: (X Windows) - X

Re: grep error because of bad previous input

[Chong Yidong]

Sam Steingold <sds@podval.org> writes:

> GNU Emacs 22.0.50.3 (i686-pc-linux-gnu, X toolkit, Xaw3d scroll bars)
>  of 2006-07-24 on quant8
>
> M-x grep RET
> foo *.lis[ RET                     ;; typo: "[" instead of "p"
> M-x grep RET
>
> ==>
>
> Debugger entered--Lisp error: (args-out-of-range "*.lis[" 6)
>   wildcard-to-regexp("*.lis[")

I can't reproduce this.

Re: grep error because of bad previous input

[Sam Steingold]

> * Chong Yidong <plq@fghcvqpuvpxra.pbz> [2006-07-27 13:51:00 -0400]:
>
> Sam Steingold <sds@podval.org> writes:
>
>> GNU Emacs 22.0.50.3 (i686-pc-linux-gnu, X toolkit, Xaw3d scroll bars)
>>  of 2006-07-24 on quant8
>>
>> M-x grep RET
>> foo *.lis[ RET                     ;; typo: "[" instead of "p"
>> M-x grep RET
>>
>> ==>
>>
>> Debugger entered--Lisp error: (args-out-of-range "*.lis[" 6)
>>   wildcard-to-regexp("*.lis[")
>
> I can't reproduce this.

(setq grep-history '("grep -nH -e compute-discriminating-function *.lis["))
(let ((buffer-file-name "foo"))
  (grep-default-command))

i.e.,
1. last grep command must have a regexp-like wildcard for filenames
2. the current buffer must be named.

-- 
Sam Steingold (http://www.podval.org/~sds) on Fedora Core release 5 (Bordeaux)
http://camera.org http://thereligionofpeace.com http://ffii.org
http://dhimmi.com http://jihadwatch.org http://iris.org.il http://pmw.org.il
Vegetarians eat Vegetables, Humanitarians are scary.

Re: grep error because of bad previous input

[Richard Stallman]

Does this fix it?

*** grep.el	19 Jul 2006 17:19:19 -0400	1.62
--- grep.el	27 Jul 2006 19:15:01 -0400	
***************
*** 456,488 ****
  		 t)))))
  
  (defun grep-default-command ()
    (let ((tag-default
           (shell-quote-argument
            (or (funcall (or find-tag-default-function
                             (get major-mode 'find-tag-default-function)
                             'find-tag-default))
                "")))
  	(sh-arg-re "\\(\\(?:\"\\(?:[^\"]\\|\\\\\"\\)+\"\\|'[^']+'\\|[^\"' \t\n]\\)+\\)")
  	(grep-default (or (car grep-history) grep-command)))
!     ;; Replace the thing matching for with that around cursor.
      (when (or (string-match
  	       (concat "[^ ]+\\s +\\(?:-[^ ]+\\s +\\)*"
  		       sh-arg-re "\\(\\s +\\(\\S +\\)\\)?")
  	       grep-default)
  	      ;; If the string is not yet complete.
  	      (string-match "\\(\\)\\'" grep-default))
!       (unless (or (not (stringp buffer-file-name))
! 		  (when (match-beginning 2)
! 		    (save-match-data
! 		      (string-match
! 		       (wildcard-to-regexp
! 			(file-name-nondirectory
! 			 (match-string 3 grep-default)))
! 		       (file-name-nondirectory buffer-file-name)))))
! 	(setq grep-default (concat (substring grep-default
! 					      0 (match-beginning 2))
! 				   " *."
! 				   (file-name-extension buffer-file-name))))
        (replace-match tag-default t t grep-default 1))))
  
  
--- 456,499 ----
  		 t)))))
  
  (defun grep-default-command ()
+   "Compute the default grep command for C-u M-x grep to offer."
    (let ((tag-default
+ 	 ;; Find the tag in the buffer at point.
           (shell-quote-argument
            (or (funcall (or find-tag-default-function
                             (get major-mode 'find-tag-default-function)
                             'find-tag-default))
                "")))
+ 	;; Is this a regexp to match single shell arguments?
+ 	;; I guess so.  Does someone know?
  	(sh-arg-re "\\(\\(?:\"\\(?:[^\"]\\|\\\\\"\\)+\"\\|'[^']+'\\|[^\"' \t\n]\\)+\\)")
  	(grep-default (or (car grep-history) grep-command)))
!     ;; In the default command, find the arg that specifies the pattern.
      (when (or (string-match
  	       (concat "[^ ]+\\s +\\(?:-[^ ]+\\s +\\)*"
  		       sh-arg-re "\\(\\s +\\(\\S +\\)\\)?")
  	       grep-default)
  	      ;; If the string is not yet complete.
  	      (string-match "\\(\\)\\'" grep-default))
!       ;; Maybe we will replace the pattern with the default tag.
!       ;; But first, maybe replace the file name pattern.
!       (condition-case nil
! 	  (unless (or (not (stringp buffer-file-name))
! 		      (when (match-beginning 2)
! 			(save-match-data
! 			  (string-match
! 			   (wildcard-to-regexp
! 			    (file-name-nondirectory
! 			     (match-string 3 grep-default)))
! 			   (file-name-nondirectory buffer-file-name)))))
! 	    (setq grep-default (concat (substring grep-default
! 						  0 (match-beginning 2))
! 				       " *."
! 				       (file-name-extension buffer-file-name))))
! 	;; In case wildcard-to-regexp gets an error
! 	;; from invalid data.
! 	(error nil))
!       ;; Now replace the pattern with the default tag.
        (replace-match tag-default t t grep-default 1))))

Re: grep error because of bad previous input

[Stefan Monnier]

> + 	;; Is this a regexp to match single shell arguments?
> + 	;; I guess so.  Does someone know?
>   	(sh-arg-re "\\(\\(?:\"\\(?:[^\"]\\|\\\\\"\\)+\"\\|'[^']+'\\|[^\"' \t\n]\\)+\\)")

Yes, that's what it's intended to do.


        Stefan

Re: grep error because of bad previous input

[David Kastrup]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

>> + 	;; Is this a regexp to match single shell arguments?
>> + 	;; I guess so.  Does someone know?
>>   	(sh-arg-re "\\(\\(?:\"\\(?:[^\"]\\|\\\\\"\\)+\"\\|'[^']+'\\|[^\"' \t\n]\\)+\\)")
>
> Yes, that's what it's intended to do.

It would appear to make minced meat from
"\\" "\\"
as far as I can see.  Would probably need something like

(sh-arg-re "\\(\\(?:\"\\(?:[^\\\"]\\|\\\\[^\"]\\)+\"\\|'[^']+'\\|[^\"' \t\n]\\)+\\)")

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum