This code won't match buffer names. Why not?

This code won't match buffer names. Why not?

[Chris Seberino]

When I cycle through buffers, I'd like to skip *scratch*, *Messages*
and *Whitespace Errors* buffers.

I wrote following code to skip one more buffer if I'm sitting in
either of those 3.

However, it never matches those buffers.  Why not?

(BTW, the (end-kbd-macro) is just a dummy function since "if" needs an
"else" command.
Is there a better dummy command I can add there?)


; Sets F10 to execute a function that moves to another buffer.
(global-set-key [f10] (lambda () (interactive)
                                 (next-buffer)
                                 (if (equal (current-buffer)
"*scratch*")
                                     (next-buffer)
                                     (end-kbd-macro))
                                 (if (equal (current-buffer)
"*Messages*")
                                     (next-buffer)
                                     (end-kbd-macro))
                                 (if (equal (current-buffer)
                                            "*Whitespace Errors*")
                                     (next-buffer)
                                     (end-kbd-macro))))

Re: This code won't match buffer names. Why not?

[Benjamin Andresen]

Chris Seberino <cseberino@gmail.com> writes:

> When I cycle through buffers, I'd like to skip *scratch*, *Messages*
> and *Whitespace Errors* buffers.
>
> I wrote following code to skip one more buffer if I'm sitting in
> either of those 3.
>
> However, it never matches those buffers.  Why not?

(current-buffer) returns an buffer and not the buffer-name.
You can check that with M-: (current-buffer)

Use (buffer-name (current-buffer)) and string-match. Or see below.

> (BTW, the (end-kbd-macro) is just a dummy function since "if" needs an
> "else" command.
> Is there a better dummy command I can add there?)

`if' also need an else part. Check C-h f if

> ; Sets F10 to execute a function that moves to another buffer.
> (global-set-key [f10] (lambda () (interactive)
>                                  (next-buffer)
>                                  (if (equal (current-buffer)
> "*scratch*")
>                                      (next-buffer)
>                                      (end-kbd-macro))
>                                  (if (equal (current-buffer)
> "*Messages*")
>                                      (next-buffer)
>                                      (end-kbd-macro))
>                                  (if (equal (current-buffer)
>                                             "*Whitespace Errors*")
>                                      (next-buffer)
>                                      (end-kbd-macro))))

The rewritten code would be better written like this:

(global-set-key (kbd "<f10>")
                '(lambda ()
                  (interactive)
                  (next-buffer)
                  (while (member (buffer-name (current-buffer))
                                 '("*scratch*" "*Messages*" "*Whitespace Errors*"))
                    (next-buffer))))

HTH,
benny

Re: This code won't match buffer names. Why not?

[Benjamin Andresen]

Benjamin Andresen <benny@in-ulm.de> writes:

> `if' also need an else part. Check C-h f if
           ^ doesn't

Re: This code won't match buffer names. Why not?

[Xah Lee]

On Aug 21, 5:31 pm, Chris Seberino <cseber...@gmail.com> wrote:
> When I cycle through buffers, I'd like to skip *scratch*, *Messages*
> and *Whitespace Errors* buffers.
>
> I wrote following code to skip one more buffer if I'm sitting in
> either of those 3.
>
> However, it never matches those buffers.  Why not?
>
> (BTW, the (end-kbd-macro) is just a dummy function since "if" needs an
> "else" command.
> Is there a better dummy command I can add there?)
>
> ; Sets F10 to execute a function that moves to another buffer.
> (global-set-key [f10] (lambda () (interactive)
>                                  (next-buffer)
>                                  (if (equal (current-buffer)
> "*scratch*")
>                                      (next-buffer)
>                                      (end-kbd-macro))
>                                  (if (equal (current-buffer)
> "*Messages*")
>                                      (next-buffer)
>                                      (end-kbd-macro))
>                                  (if (equal (current-buffer)
>                                             "*Whitespace Errors*")
>                                      (next-buffer)
>                                      (end-kbd-macro))))


Wee, the code to skip emacs buffers is in ergoemacs here:
http://code.google.com/p/ergoemacs/

by default it's Ctrl + Page up/down is the shortcut, similar to
Firefox et al for switching tabs.
With shift key down, it cycle among emacs's buffers.

here's the relevant code:

(defun next-user-buffer ()
  "Switch to the next user buffer.
User buffers are those whose name does not start with *."
  (interactive)
  (next-buffer)
  (let ((i 0))
    (while (and (string-match "^*" (buffer-name)) (< i 50))
      (setq i (1+ i)) (next-buffer) )))

  Xah
∑ http://xahlee.org/

☄

Re: This code won't match buffer names. Why not?

[Ivan Kanis]

Chris Seberino <cseberino@gmail.com> wrote:

> ; Sets F10 to execute a function that moves to another buffer.
> (global-set-key [f10] (lambda () (interactive)
>                                  (next-buffer)
>                                  (if (equal (current-buffer)
> "*scratch*")
>                                      (next-buffer)
>                                      (end-kbd-macro))

Try buffer-name instead of current-buffer and maybe string= instead of
equal. I am not sure why you call end-kbd-macro. Also there is no need
to put interactive because you won't call an anonymous function.
-- 
Ivan
Kanis http://kanis.fr

Deep Hack Mode--that mysterious and frightening state of
consciousness where Mortal Users fear to tread.
    -- Matt Welsh 

Re: This code won't match buffer names. Why not?

[David Kastrup]

Benjamin Andresen <benny@in-ulm.de> writes:

> The rewritten code would be better written like this:
>
> (global-set-key (kbd "<f10>")
>                 '(lambda ()
>                   (interactive)
>                   (next-buffer)
>                   (while (member (buffer-name (current-buffer))
>                                  '("*scratch*" "*Messages*" "*Whitespace Errors*"))
>                     (next-buffer))))

What if only *scratch* is left?

-- 
David Kastrup

Re: This code won't match buffer names. Why not?

[Pascal J. Bourguignon]

David Kastrup <dak@gnu.org> writes:

> Benjamin Andresen <benny@in-ulm.de> writes:
>
>> The rewritten code would be better written like this:
>>
>> (global-set-key (kbd "<f10>")
>>                 '(lambda ()
>>                   (interactive)
>>                   (next-buffer)
>>                   (while (member (buffer-name (current-buffer))
>>                                  '("*scratch*" "*Messages*" "*Whitespace Errors*"))
>>                     (next-buffer))))
>
> What if only *scratch* is left?

(defvar *bad-buffers* '("*scratch*" "*Messages*" "*Whitespace Errors*"))

(defun next-good-buffer ()
   (interactive)
   (unless (= 1 (length (buffer-list)))
      (next-buffer)
      (while (member (buffer-name (current-buffer)) *bad-buffers*)
          (next-buffer))))

(global-set-key (kbd "<f10>") 'next-good-buffer)

-- 
__Pascal Bourguignon__

Re: This code won't match buffer names. Why not?

[David Kastrup]

pjb@informatimago.com (Pascal J. Bourguignon) writes:

> David Kastrup <dak@gnu.org> writes:
>
>> Benjamin Andresen <benny@in-ulm.de> writes:
>>
>>> The rewritten code would be better written like this:
>>>
>>> (global-set-key (kbd "<f10>")
>>>                 '(lambda ()
>>>                   (interactive)
>>>                   (next-buffer)
>>>                   (while (member (buffer-name (current-buffer))
>>>                                  '("*scratch*" "*Messages*" "*Whitespace Errors*"))
>>>                     (next-buffer))))
>>
>> What if only *scratch* is left?
>
> (defvar *bad-buffers* '("*scratch*" "*Messages*" "*Whitespace Errors*"))
>
> (defun next-good-buffer ()
>    (interactive)
>    (unless (= 1 (length (buffer-list)))
>       (next-buffer)
>       (while (member (buffer-name (current-buffer)) *bad-buffers*)
>           (next-buffer))))
>
> (global-set-key (kbd "<f10>") 'next-good-buffer)

What if both *scratch* and *Messages* are left?

I mean, think before you post.

Something like
(defun next-good-buffer ()
  (interactive)
  (let ((old-buffer (current-buffer)))
    (while (and (not (eq old-buffer (progn (next-buffer) (current-buffer))))
                (member (buffer-name (current-buffer)) *bad-buffers*)))))

I am not sure whether next-buffer is supposed to revisit a hidden buffer
when starting out from it, so this is not completely fool-proof.  But I
am short of time right now...

-- 
David Kastrup