Re: report-emacs-bug could also list current modes

Re: report-emacs-bug could also list current modes

[Kevin Rodgers]

Dan Jacobson wrote:

> report-emacs-bug in its report could also list the current major and minor modes in
> effect...
> 
> By the way, aside from blabberous describe-mode, and staring at the
> mode line, where is a concise list of the current modes in effect?
> There is no list-modes, show-modes, etc.


C-x C-b (list-buffers) shows each buffer's major mode.


> I do apropos modes, and see things like "minor-modes" with no
> explanation of what they are doing there on a separate line:
> (apropos "modes" nil)

Try: C-h a -mode\'

(The minor-modes line is telling you that the symbol is interned in the
standard obarray, but it has no value or function binding.)


-- 
Kevin Rodgers

stop rewriting Message-IDs

[Dan Jacobson]

Dear bug-gnu-emacs: again: for RFC compliant Message-IDs, there is no
reason for bug-gnu-emacs's mailman to rewrite them.

For instance, here reading from gmane.org NNTP, my message has
References: <mailman.443.1064004252.21628.bug-gnu-emacs@gnu.org>
	<3F6F155C.4010606@yahoo.com>

however mailman.443.1064004252.21628.bug-gnu-emacs@gnu.org is how my
article looks to Kevin, but that article can't be found on gmane. The article's
original rightful Message-ID is what is on gmane.

There is no justification for rewriting Message-IDs other than being
too lazy to use a regexp to see if the Message-IDs is RFC compliant.
And it's creating a big mess.

I sent a message to the maintainers last year.

Re: report-emacs-bug could also list current modes

[Dan Jacobson]

>> By the way, aside from blabberous describe-mode, and staring at the
>> mode line, where is a concise list of the current modes in effect?
>> There is no list-modes, show-modes, etc.

K> C-x C-b (list-buffers) shows each buffer's major mode.

I meant a list of all the modes in effect for this buffer.  Yes, there
they are mostly in the modeline, but how about a lisp list?

>> I do apropos modes, and see things like "minor-modes" with no
>> explanation of what they are doing there on a separate line:
>> (apropos "modes" nil)

K> Try: C-h a -mode\'

OK, C-h a -mode$
looks simpler for me.

Re: report-emacs-bug could also list current modes

[Kevin Rodgers]

Dan Jacobson wrote:

>>>By the way, aside from blabberous describe-mode, and staring at the
>>>mode line, where is a concise list of the current modes in effect?
>>>There is no list-modes, show-modes, etc.
> 
> K> C-x C-b (list-buffers) shows each buffer's major mode.
> 
> I meant a list of all the modes in effect for this buffer.  Yes, there
> they are mostly in the modeline, but how about a lisp list?


If you need it, you could write it yourself:

(defun buffer-mode-list ()
   "Return a list of the current buffer's major mode and minor modes."
   (interactive)
   (let ((modes (cons major-mode
                      (apply 'nconc
                             (mapcar (lambda (key-value)
                                       (let ((variable (car key-value)))
                                         (if (and (boundp variable)
                                                  (symbol-value variable))
                                             (list (symbol-name variable)))))
                                     minor-mode-alist)))))
     (if (interactive-p)
         (message "%s" modes)
       modes)))


>>>I do apropos modes, and see things like "minor-modes" with no
>>>explanation of what they are doing there on a separate line:
>>>(apropos "modes" nil)
>>>
> 
> K> Try: C-h a -mode\'
> 
> OK, C-h a -mode$
> looks simpler for me.

But won't return symbols with a newline in their name.  :-)


-- 
Kevin Rodgers

Re: report-emacs-bug could also list current modes

[Andreas Schwab]

Kevin Rodgers <ihs_4664@yahoo.com> writes:

> Dan Jacobson wrote:
>
>> K> Try: C-h a -mode\'
>> OK, C-h a -mode$
>> looks simpler for me.
>
> But won't return symbols with a newline in their name.  :-)

It will, and it may match even more than the first.

Andreas.

-- 
Andreas Schwab, SuSE Labs, schwab@suse.de
SuSE Linux AG, Deutschherrnstr. 15-19, D-90429 Nürnberg
Key fingerprint = 58CA 54C7 6D53 942B 1756  01D3 44D5 214B 8276 4ED5
"And now for something completely different."

describe-mode should first summarize all modes in effect

[Dan Jacobson]

Indeed, emacs lacks a command to show concisely what all those mode
abbreviations crammed in the modeline stand for.  There should be a
function explain-modeline-modes, that puts them in the minibuffer.
Kevin's function below could be enhanced to do that.

Better yet, have describe-mode output Kevin's  list at the top of its
output, before getting mired in detail.

K> Dan Jacobson wrote:
>>>> By the way, aside from blabberous describe-mode, and staring at the
>>>> mode line, where is a concise list of the current modes in effect?
>>>> There is no list-modes, show-modes, etc.
K> C-x C-b (list-buffers) shows each buffer's major mode.
>> I meant a list of all the modes in effect for this buffer.  Yes,
>> there
>> they are mostly in the modeline, but how about a lisp list?


K> If you need it, you could write it yourself:

K> (defun buffer-mode-list ()
K>    "Return a list of the current buffer's major mode and minor modes."
K>    (interactive)
K>    (let ((modes (cons major-mode
K>                       (apply 'nconc
K>                              (mapcar (lambda (key-value)
K>                                        (let ((variable (car key-value)))
K>                                          (if (and (boundp variable)
K>                                                   (symbol-value variable))
K>                                              (list (symbol-name variable)))))
K>                                      minor-mode-alist)))))
K>      (if (interactive-p)
K>          (message "%s" modes)
K>        modes)))

Re: describe-mode should first summarize all modes in effect

[Richard Stallman]

What do you think of this version?

(defun describe-mode (&optional buffer)
  "Display documentation of current major mode and minor modes.
The major mode description comes first, followed by the minor modes,
each on a separate page.
For this to work correctly for a minor mode, the mode's indicator variable
\(listed in `minor-mode-alist') must also be a function whose documentation
describes the minor mode."
  (interactive)
  (help-setup-xref (list #'describe-mode (or buffer (current-buffer)))
		   (interactive-p))
  ;; For the sake of help-do-xref and help-xref-go-back,
  ;; don't switch buffers before calling `help-buffer'.
  (with-output-to-temp-buffer (help-buffer)
    (save-excursion
      (when buffer (set-buffer buffer))
      (let (minor-modes)
	;; Find enabled minor mode we will want to mention.
	(dolist (mode minor-mode-list)
	  ;; Document a minor mode if it is listed in minor-mode-alist,
	  ;; non-nil, and has a function definition.
	  (and (boundp mode) (symbol-value mode)
	       (fboundp mode)
	       (let ((pretty-minor-mode mode)
		     indicator)
		 (if (string-match "\\(-minor\\)?-mode\\'"
				   (symbol-name mode))
		     (setq pretty-minor-mode
			   (capitalize
			    (substring (symbol-name mode)
				       0 (match-beginning 0)))))
		 (setq indicator (cadr (assq mode minor-mode-alist)))
		 (while (and indicator (symbolp indicator)
			     (boundp indicator)
			     (not (eq indicator (symbol-value indicator))))
		   (setq indicator (symbol-value indicator)))
		 (push (list pretty-minor-mode mode indicator)
		       minor-modes))))
	(if auto-fill-function
	    (push '("Auto Fill" auto-fill-mode " Fill")
		  minor-modes))
	(setq minor-modes
	      (sort minor-modes
		    (lambda (a b) (string-lessp (car a) (car b)))))
	(when minor-modes
	  (princ "Summary of minor modes:\n")
	  (dolist (mode minor-modes)
	    (let ((pretty-minor-mode (nth 0 mode))
		  (indicator (nth 2 mode)))
	      (princ (format "  %s minor mode (%s):\n"
			     pretty-minor-mode
			     (if indicator
				 (format "indicator%s" indicator)
			       "no indicator")))))
	  (princ "\n(Full information about these minor modes
follows the description of the major mode.)\n\n"))
	;; Document the major mode.
	(princ mode-name)
	(princ " mode:\n")
	(princ (documentation major-mode))
	;; Document the minor modes fully.
	(dolist (mode minor-modes)
	  (let ((pretty-minor-mode (nth 0 mode))
		(mode-function (nth 1 mode))
		(indicator (nth 2 mode)))
	    (princ "\n\f\n")
	    (princ (format "%s minor mode (%s):\n"
			   pretty-minor-mode
			   (if indicator
			       (format "indicator%s" indicator)
			     "no indicator")))
	    (princ (documentation mode-function)))))
      (print-help-return-message))))

Re: describe-mode should first summarize all modes in effect

[Kevin Rodgers]

Dan Jacobson wrote:

 > Indeed, emacs lacks a command to show concisely what all those mode
 > abbreviations crammed in the modeline stand for.  There should be a
 > function explain-modeline-modes, that puts them in the minibuffer.
 > Kevin's function below could be enhanced to do that.
 >
 > Better yet, have describe-mode output Kevin's  list at the top of its
 > output, before getting mired in detail.

I don't think that's necessary.  Everything is explained in the "Mode
Line" and "Minor Modes" sections of the Emacs manual.  And `C-h m'
already lists each minor mode indicator:

| The major mode is described first.
| For minor modes, see following pages.
|
| Emacs-Lisp mode:
| Major mode for editing Lisp code to run in Emacs.
...
| \f
| Eldoc minor mode (indicator ElDoc):
| *Enable or disable eldoc mode.
...

-- 
Kevin Rodgers

Re: describe-mode should first summarize all modes in effect

[Dan Jacobson]

>> Better yet, have describe-mode output Kevin's  list at the top of its
>> output, before getting mired in detail.

K> I don't think that's necessary.  Everything is explained in the "Mode
K> Line" and "Minor Modes" sections of the Emacs manual.  

dusty manual can tell one what SC MML MC-w Fly ... expand to?

K> And `C-h m' already lists each minor mode indicator:

K> | The major mode is described first.
K> | For minor modes, see following pages.

_pages_... scattered miles and miles later, ^L or no ^L.
Why not summarize first?
RMS sent a probable improvement, but not to this list.

report-emacs-bug could also list current modes

[Dan Jacobson]

report-emacs-bug in its report could also list the current major and minor modes in
effect...

By the way, aside from blabberous describe-mode, and staring at the
mode line, where is a concise list of the current modes in effect?
There is no list-modes, show-modes, etc.
I do apropos modes, and see things like "minor-modes" with no
explanation of what they are doing there on a separate line:
(apropos "modes" nil)

mc-modes-alist
  Variable: Association list (indexed by major mode) of association lists
  Plist: variable-documentation
minor-modes
mmm-c-derived-modes
  Variable: (not documented)
...
mode-line-modes
  Plist: risky-local-variable
modes
modesym
nnmail-default-file-modes
  Variable: Set the mode bits of all new mail files to this integer.