Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Bodertz]

See this example plain list, where point is represented by <point>:


- list item
- Indent the empty list item below by pressing M-<right>
- <point>


After pressing M-<right> as asked, the list will look like this:


- list item
- Indent the empty list item below by pressing M-<right>
  - <point>


As you can see, point is after the dash.



Next see this example description list:


- list item  :: with description
- Indent the empty list item below by pressing M-<right> :: description
- <point> :: 


After pressing M-<right> as asked, the list will look like this:


- list item  :: with description
- Indent the empty list item below by pressing M-<right> :: description
<point> - ::


As you can see, point is at the beginning of the line.  I think it
should be after the dash, as is the case when indenting plain list
items.


Emacs  : GNU Emacs 28.0.50 (build 1, x86_64-pc-linux-gnu, GTK+ Version 3.24.24, cairo version 1.16.0)
Package: Org mode version 9.4.4 (release_9.4.4 @ /gnu/store/qbd7y4jm3lp1sgzyl6b8cqcf8hb3w1wz-emacs-pgtk-native-comp-28.0.50-203.92bc69e/share/emacs/28.0.50/lisp/org/)

Re: Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Bastien]

Hi,

Bodertz <bodertz@gmail.com> writes:

> After pressing M-<right> as asked, the list will look like this:
>
>
> - list item  :: with description
> - Indent the empty list item below by pressing M-<right> :: description
> <point> - ::
>
>
> As you can see, point is at the beginning of the line.  I think it
> should be after the dash, as is the case when indenting plain list
> items.

Confirmed, I'm adding this to updates.orgmode.org.

Thanks,

-- 
 Bastien

[PATCH] Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Ihor Radchenko]

[-- Attachment #1: Type: text/plain, Size: 219 bytes --]

Bodertz <bodertz@gmail.com> writes:

> As you can see, point is at the beginning of the line.  I think it
> should be after the dash, as is the case when indenting plain list
> items.

The fix is attached.

Best,
Ihor


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-org-list-Do-not-move-point-when-promoting-demoting-i.patch --]
[-- Type: text/x-diff, Size: 2107 bytes --]

From 63870bec28e59732cbbdf8b2534f6ece96e2d5d8 Mon Sep 17 00:00:00 2001
Message-Id: <63870bec28e59732cbbdf8b2534f6ece96e2d5d8.1633171544.git.yantar92@gmail.com>
From: Ihor Radchenko <yantar92@gmail.com>
Date: Sat, 2 Oct 2021 18:32:34 +0800
Subject: [PATCH] org-list: Do not move point when promoting/demoting items

* lisp/org-list.el (org-list-struct-apply-struct): Make sure the
origin marker is not moved to bol when promoting/demoting item in
special case:
- item
- <point> ::

* testing/lisp/test-org-list.el (test-org-list/indent-item): Add test

Fixes https://orgmode.org/list/87o88hlkvv.fsf@gmail.com
---
 lisp/org-list.el              |  5 ++++-
 testing/lisp/test-org-list.el | 10 +++++++++-
 2 files changed, 13 insertions(+), 2 deletions(-)

diff --git a/lisp/org-list.el b/lisp/org-list.el
index 2bd9dc4d9..b6ab14f84 100644
--- a/lisp/org-list.el
+++ b/lisp/org-list.el
@@ -1866,7 +1866,10 @@ (defun org-list-struct-apply-struct (struct old-struct)
 	      (looking-at org-list-full-item-re)
 	      ;; a.  Replace bullet
 	      (unless (equal old-bul new-bul)
-		(replace-match new-bul nil nil nil 1))
+                (save-excursion
+                  (replace-match "" nil nil nil 1)
+                  (goto-char (match-end 1))
+                  (insert-before-markers new-bul)))
 	      ;; b.  Replace checkbox.
 	      (cond
 	       ((equal (match-string 3) new-box))
diff --git a/testing/lisp/test-org-list.el b/testing/lisp/test-org-list.el
index 3689a172f..e3d904b1e 100644
--- a/testing/lisp/test-org-list.el
+++ b/testing/lisp/test-org-list.el
@@ -298,7 +298,15 @@ (ert-deftest test-org-list/indent-item ()
 	    (push-mark (point) t t)
 	    (goto-char (point-max))
 	    (let (org-list-demote-modify-bullet) (org-indent-item))
-	    (buffer-string)))))
+	    (buffer-string))))
+  ;; When point is right after empty item, do not move point.
+  (should
+   (= 13
+      (org-test-with-temp-text "
+- item
+- <point> ::"
+        (org-indent-item)
+        (point)))))
 
 (ert-deftest test-org-list/indent-item-tree ()
   "Test `org-indent-item-tree' specifications."
-- 
2.32.0

Re: [PATCH] Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Ihor Radchenko]

Ihor Radchenko <yantar92@gmail.com> writes:

> Bodertz <bodertz@gmail.com> writes:
>
>> As you can see, point is at the beginning of the line.  I think it
>> should be after the dash, as is the case when indenting plain list
>> items.
>
> The fix is attached.

Are you still seeing the issue with the proposed patch?

Best,
Ihor

Re: [PATCH] Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Bodertz]

Apologies, I wasn't aware you were asking for feedback.

The issue I described no longer occurs.

However, there is still a minor issue with the proposed fix.

After creating a new empty description list item by pressing {M-RET}
after a description list item, the item created is the following:

--8<---------------cut here---------------start------------->8---
- | ::
--8<---------------cut here---------------end--------------->8---


That is, "dash space <cursor> space colon colon".

After indenting, it becomes:

--8<---------------cut here---------------start------------->8---
- |::
--8<---------------cut here---------------end--------------->8---

That is, "dash space <cursor> colon colon".  The space before the colon
is no longer present.

[PATCH v2] Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Ihor Radchenko]

[-- Attachment #1: Type: text/plain, Size: 544 bytes --]

Bodertz <bodertz@gmail.com> writes:

> Apologies, I wasn't aware you were asking for feedback.
>
> The issue I described no longer occurs.
>
> However, there is still a minor issue with the proposed fix.
>
> After creating a new empty description list item by pressing {M-RET}
> after a description list item, the item created is the following:
>

Thanks for letting me know and sorry for the late reply. This patch has
been sunk in the depths of the todo list.

I have updated the patch to address your concern.
See the attached.

Best,
Ihor


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-org-list-Do-not-move-point-and-change-space-when-pro.patch --]
[-- Type: text/x-patch, Size: 3339 bytes --]

From 86f4e9b1bec488a420b28b91e3813a2cd74d586f Mon Sep 17 00:00:00 2001
Message-Id: <86f4e9b1bec488a420b28b91e3813a2cd74d586f.1654781017.git.yantar92@gmail.com>
From: Ihor Radchenko <yantar92@gmail.com>
Date: Sat, 2 Oct 2021 18:32:34 +0800
Subject: [PATCH] org-list: Do not move point and change space when
 promoting/demoting items

* lisp/org-list.el (org-list-struct-apply-struct): Make sure the
origin marker is not moved to bol when promoting/demoting item in
special case:
 - item
 - <point> ::
Do not remove the trailing space after point as well.
(org-insert-item): Do not expect point to remain at bol after writing
list struct.

* testing/lisp/test-org-list.el (test-org-list/indent-item): Add test

Fixes https://orgmode.org/list/87o88hlkvv.fsf@gmail.com
---
 lisp/org-list.el              | 15 ++++++++++++++-
 testing/lisp/test-org-list.el | 16 +++++++++++++++-
 2 files changed, 29 insertions(+), 2 deletions(-)

diff --git a/lisp/org-list.el b/lisp/org-list.el
index 515763036..97d856fc9 100644
--- a/lisp/org-list.el
+++ b/lisp/org-list.el
@@ -1940,7 +1940,19 @@ (defun org-list-struct-apply-struct (struct old-struct)
 	      (looking-at org-list-full-item-re)
 	      ;; a.  Replace bullet
 	      (unless (equal old-bul new-bul)
-		(replace-match new-bul nil nil nil 1))
+                (let ((keep-space ""))
+                  (save-excursion
+                    ;; If origin is inside the bullet, preserve the
+                    ;; spaces after origin.
+                    (when (<= (match-beginning 1) origin (match-end 1))
+                      (org-with-point-at origin
+                        (save-match-data
+                          (when (looking-at "[ \t]+")
+                            (setq keep-space (match-string 0))))))
+                    (replace-match "" nil nil nil 1)
+                    (goto-char (match-end 1))
+                    (insert-before-markers new-bul)
+                    (insert keep-space))))
 	      ;; b.  Replace checkbox.
 	      (cond
 	       ((equal (match-string 3) new-box))
@@ -2286,6 +2298,7 @@ (defun org-insert-item (&optional checkbox)
 	  (setq struct (org-list-insert-item pos struct prevs checkbox desc))
 	  (org-list-write-struct struct (org-list-parents-alist struct))
 	  (when checkbox (org-update-checkbox-count-maybe))
+          (beginning-of-line)
 	  (looking-at org-list-full-item-re)
 	  (goto-char (if (and (match-beginning 4)
 			      (save-match-data
diff --git a/testing/lisp/test-org-list.el b/testing/lisp/test-org-list.el
index bc8faa672..d3e6fc176 100644
--- a/testing/lisp/test-org-list.el
+++ b/testing/lisp/test-org-list.el
@@ -298,7 +298,21 @@ (ert-deftest test-org-list/indent-item ()
 	    (push-mark (point) t t)
 	    (goto-char (point-max))
 	    (let (org-list-demote-modify-bullet) (org-indent-item))
-	    (buffer-string)))))
+	    (buffer-string))))
+  ;; When point is right after empty item, do not move point.
+  (should
+   (= 13
+      (org-test-with-temp-text "
+- item
+- <point> ::"
+        (org-indent-item)
+        (point))))
+  ;; Preserve space after point upon promoting level.
+  (org-test-with-temp-text "
+- item
+- <point> 	::"
+    (org-indent-item)
+    (should (looking-at-p " \t"))))
 
 (ert-deftest test-org-list/indent-item-tree ()
   "Test `org-indent-item-tree' specifications."
-- 
2.35.1

Re: [PATCH v2] Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Bodertz]

After some quick testing, your patch seems to work as expected.  Thanks!

Re: [PATCH v2] Bug: Indenting empty description list item leaves point at beginning of line [9.4.4]

[Ihor Radchenko]

Bodertz <bodertz@gmail.com> writes:

> After some quick testing, your patch seems to work as expected.  Thanks!

Applied onto main via ed6f8dc67.

Best,
Ihor