Re: jit-lock timer etc.

[Chong Yidong <cyd@stupidchicken.com>]

Chong Yidong <cyd@stupidchicken.com> writes:

> I don't know what was wrong with this code since you didn't post it.
> It looks like you simply forgot to initialize jit-lock-stealth-repeat-timer,
> but I can't be sure.  However, the following patch, based on the last
> patch you posted to this list with minimal modifications, works fine
> for me.
>
> It applies to the current CVS tree, and uses `current-idle-time'.  It
> includes and uses the change to `timer-set-idle-time' which I
> previously posted, allowing it to accept the value returned by
> `current-idle-time'.

> I have verified that the idle timer triggers correctly, stops
> correctly when user input comes in, and resumes when Emacs becomes
> idle again.

There were a few mistakes in the code I posted, incurred during
cutting and pasting.  Please look at this patch instead; and sorry for
the noise.

*** emacs/lisp/jit-lock.el.~1.54.~	2006-08-17 11:49:36.000000000 -0400
--- emacs/lisp/jit-lock.el	2006-08-24 11:39:14.000000000 -0400
***************
*** 443,513 ****
  			   (t next))))
  	result))))
  
  
! (defun jit-lock-stealth-fontify ()
    "Fontify buffers stealthily.
! This functions is called after Emacs has been idle for
! `jit-lock-stealth-time' seconds."
!   ;; I used to check `inhibit-read-only' here, but I can't remember why.  -stef
    (unless (or executing-kbd-macro
  	      memory-full
! 	      (window-minibuffer-p (selected-window)))
!     (let ((buffers (buffer-list))
! 	  (outer-buffer (current-buffer))
  	  minibuffer-auto-raise
! 	  message-log-max)
!       (with-local-quit
! 	(while (and buffers (not (input-pending-p)))
! 	  (with-current-buffer (pop buffers)
! 	    (when jit-lock-mode
! 	      ;; This is funny.  Calling sit-for with 3rd arg non-nil
! 	      ;; so that it doesn't redisplay, internally calls
! 	      ;; wait_reading_process_input also with a parameter
! 	      ;; saying "don't redisplay."  Since this function here
! 	      ;; is called periodically, this effectively leads to
! 	      ;; process output not being redisplayed at all because
! 	      ;; redisplay_internal is never called.  (That didn't
! 	      ;; work in the old redisplay either.)  So, we learn that
! 	      ;; we mustn't call sit-for that way here.  But then, we
! 	      ;; have to be cautious not to call sit-for in a widened
! 	      ;; buffer, since this could display hidden parts of that
! 	      ;; buffer.  This explains the seemingly weird use of
! 	      ;; save-restriction/widen here.
! 
! 	      (with-temp-message (if jit-lock-stealth-verbose
! 				     (concat "JIT stealth lock "
! 					     (buffer-name)))
! 
! 		;; In the following code, the `sit-for' calls cause a
! 		;; redisplay, so it's required that the
! 		;; buffer-modified flag of a buffer that is displayed
! 		;; has the right value---otherwise the mode line of
! 		;; an unmodified buffer would show a `*'.
! 		(let (start
! 		      (nice (or jit-lock-stealth-nice 0))
! 		      (point (point-min)))
! 		  (while (and (setq start
! 				    (jit-lock-stealth-chunk-start point))
! 			      ;; In case sit-for runs any timers,
! 			      ;; give them the expected current buffer.
! 			      (with-current-buffer outer-buffer
! 				(sit-for nice)))
! 
! 		    ;; fontify a block.
! 		    (jit-lock-fontify-now start (+ start jit-lock-chunk-size))
! 		    ;; If stealth jit-locking is done backwards, this leads to
! 		    ;; excessive O(n^2) refontification.   -stef
! 		    ;; (when (>= jit-lock-context-unfontify-pos start)
! 		    ;;   (setq jit-lock-context-unfontify-pos end))
! 
! 		    ;; Wait a little if load is too high.
! 		    (when (and jit-lock-stealth-load
! 			       (> (car (load-average)) jit-lock-stealth-load))
! 		      ;; In case sit-for runs any timers,
! 		      ;; give them the expected current buffer.
! 		      (with-current-buffer outer-buffer
! 			(sit-for (or jit-lock-stealth-time 30))))))))))))))
! 
  
  \f
  ;;; Deferred fontification.
--- 443,512 ----
  			   (t next))))
  	result))))
  
+ (defvar jit-lock-stealth-buffers nil
+   "List of buffers that should be fontified stealthily.")
  
! (defvar jit-lock-stealth-repeat-timer nil
!   "Timer for repeated stealth fontification.")
! 
! (defun jit-lock-stealth-fontify (&optional repeat)
    "Fontify buffers stealthily.
! This function is called repeatedly after Emacs has become idle for
! `jit-lock-stealth-time' seconds.  Optional argument REPEAT is expected
! non-nil in a repeated invocation of this function."
    (unless (or executing-kbd-macro
  	      memory-full
! 	      (window-minibuffer-p (selected-window))
! 	      ;; For first invocation set up `jit-lock-stealth-buffers'.
! 	      ;; In repeated invocations it's already been set up.
! 	      (null (if repeat
! 			jit-lock-stealth-buffers
! 		      (setq jit-lock-stealth-buffers (buffer-list)))))
!     ;; Cancel timer for repeated invocations.
!     (when (timerp jit-lock-stealth-repeat-timer)
!       (cancel-timer jit-lock-stealth-repeat-timer))
!     (let ((buffer (car jit-lock-stealth-buffers))
! 	  (delay 0)
  	  minibuffer-auto-raise
! 	  message-log-max
! 	  start)
!       (if (and jit-lock-stealth-load
! 	       (> (car (load-average)) jit-lock-stealth-load))
! 	  ;; Wait a little if load is too high.
! 	  (setq delay jit-lock-stealth-time)
! 	(if (buffer-live-p buffer)
! 	    (with-current-buffer buffer
! 	      (if (and jit-lock-mode
! 		       (setq start (jit-lock-stealth-chunk-start (point))))
! 		  ;; Fontify one block of at most `jit-lock-chunk-size'
! 		  ;; characters.
! 		  (with-temp-message (if jit-lock-stealth-verbose
! 					 (concat "JIT stealth lock "
! 						 (buffer-name)))
! 		    (jit-lock-fontify-now start
! 					  (+ start jit-lock-chunk-size))
! 		    ;; Run again after `jit-lock-stealth-nice' seconds.
! 		    (setq delay (or jit-lock-stealth-nice 0)))
! 		;; Nothing to fontify here.  Remove this buffer from
! 		;; `jit-lock-stealth-buffers' and run again immediately.
! 		(setq jit-lock-stealth-buffers
! 		      (cdr jit-lock-stealth-buffers))))
! 	  ;; Buffer is no longer live.  Remove it from
! 	  ;; `jit-lock-stealth-buffers' and run again immediately.
! 	  (setq jit-lock-stealth-buffers
! 		(cdr jit-lock-stealth-buffers))))
!       ;; Call us again.
!       (when jit-lock-stealth-buffers
! 	(if repeat
! 	    (progn (timer-set-idle-time
! 		    jit-lock-stealth-repeat-timer (current-idle-time))
! 		   (timer-inc-time jit-lock-stealth-repeat-timer delay)
! 		   (timer-activate-when-idle
! 		    jit-lock-stealth-repeat-timer t))
! 	  (setq jit-lock-stealth-repeat-timer
! 		(run-with-idle-timer (current-idle-time) nil
! 				     'jit-lock-stealth-fontify t))
! 	  (timer-inc-time jit-lock-stealth-repeat-timer delay))))))
  
  \f
  ;;; Deferred fontification.
*** emacs/lisp/emacs-lisp/timer.el.~1.12.~	2006-08-20 09:55:37.000000000 -0400
--- emacs/lisp/emacs-lisp/timer.el	2006-08-24 11:37:18.000000000 -0400
***************
*** 60,73 ****
  
  (defun timer-set-idle-time (timer secs &optional repeat)
    "Set the trigger idle time of TIMER to SECS.
  If optional third argument REPEAT is non-nil, make the timer
  fire each time Emacs is idle for that many seconds."
    (or (timerp timer)
        (error "Invalid timer"))
!   (aset timer 1 0)
!   (aset timer 2 0)
!   (aset timer 3 0)
!   (timer-inc-time timer secs)
    (aset timer 4 repeat)
    timer)
  
--- 60,81 ----
  
  (defun timer-set-idle-time (timer secs &optional repeat)
    "Set the trigger idle time of TIMER to SECS.
+ SECS may be an integer, floating point number, or the internal
+ time format (HIGH LOW USECS) returned by, e.g., `current-idle-time'.
  If optional third argument REPEAT is non-nil, make the timer
  fire each time Emacs is idle for that many seconds."
    (or (timerp timer)
        (error "Invalid timer"))
!   (if (consp secs)
!       (progn (aset timer 1 (car secs))
! 	     (aset timer 2 (if (consp (cdr secs)) (car (cdr secs)) (cdr secs)))
! 	     (aset timer 3 (or (and (consp (cdr secs)) (consp (cdr (cdr secs)))
! 				    (nth 2 secs))
! 			       0)))
!     (aset timer 1 0)
!     (aset timer 2 0)
!     (aset timer 3 0)
!     (timer-inc-time timer secs))
    (aset timer 4 repeat)
    timer)
  
***************
*** 104,110 ****
  
  (defun timer-relative-time (time secs &optional usecs)
    "Advance TIME by SECS seconds and optionally USECS microseconds.
! SECS may be a fraction."
    (let ((high (car time))
  	(low (if (consp (cdr time)) (nth 1 time) (cdr time)))
  	(micro (if (numberp (car-safe (cdr-safe (cdr time))))
--- 112,118 ----
  
  (defun timer-relative-time (time secs &optional usecs)
    "Advance TIME by SECS seconds and optionally USECS microseconds.
! SECS may be either an integer or a floating point number."
    (let ((high (car time))
  	(low (if (consp (cdr time)) (nth 1 time) (cdr time)))
  	(micro (if (numberp (car-safe (cdr-safe (cdr time))))
***************
*** 412,418 ****
  (defun run-with-idle-timer (secs repeat function &rest args)
    "Perform an action the next time Emacs is idle for SECS seconds.
  The action is to call FUNCTION with arguments ARGS.
! SECS may be an integer or a floating point number.
  If Emacs is currently idle, and has been idle for N seconds (N < SECS),
  then it will call FUNCTION in SECS - N seconds from now.
  
--- 420,427 ----
  (defun run-with-idle-timer (secs repeat function &rest args)
    "Perform an action the next time Emacs is idle for SECS seconds.
  The action is to call FUNCTION with arguments ARGS.
! SECS may be an integer, a floating point number, or the internal
! time format (HIGH LOW USECS) returned by, e.g., `current-idle-time'.
  If Emacs is currently idle, and has been idle for N seconds (N < SECS),
  then it will call FUNCTION in SECS - N seconds from now.